在 const 数组中传递通用记录

Question

是否可以以任何方式将 const 参数数组中的通用记录传递给函数调用？

我想在一种自制的 ORM 中使用 Allen Bauer 的 Nullable 记录，使用“普通旧 Delphi 对象”来映射数据库行：

type
  Nullable<T> = record
    ...
  end;

  TMyTableObject = class(TDbOject)
  private
    FId: Integer;
    FOptionalField: Nullable<string>;
  protected
    procedure InternalSave; override;
  public
    property Id: Integer read FId write SetId;
    property OptionalField: Nullable<string> read FOptionalField write SetOptionalField;
  end;

  ...

  implementation

  procedure TMyTableObject.InternalSave;
  begin
    { FDbController is declared and managed in TDbObject, it contains fonction to run queries
      on the database }

    FDbController.Execute(
      'update or insert into MY_TABLE(TABLE_ID, OPTIONAL_FIELD) ' +
      'values (?, ?) ' + 
      'matching(TABLE_ID) returning TABLE_ID', [FId, FOptionalField],
      procedure (Fields: TSQLResult)
      begin
        FId := Fields.AsInteger[0];
      end;
    end;      
  end;

上面的代码会导致错误：“E2250：无法使用这些参数调用“执行”函数的重写版本”（翻译自法语） ：E2250 Aucune 版本 surchargée de 'Execute' ne peut être appelée avec ces argument)

我可以显式地将 FOptionalField 转换为字符串或其他任何内容，因为 Nullable 覆盖临时运算符，但我确实必须知道 Nullable 是否有值，直到我将 const 数组映射到数据库查询对象的 Params 字段：

procedure TDbContext.MapParams(Q: TUIBQuery; Params: TConstArray);
const
  BOOL_STR: array[Boolean] of string = ('F', 'V');
var
  i: Integer;
begin
  for i := 0 to High(Params) do
    case Params[i].VType of
      vtInteger :      Q.Params.AsInteger[i]       := Params[i].VInteger;
      vtInt64   :      Q.Params.AsInt64[i]         := Params[i].VInt64^;
      vtBoolean :      Q.Params.AsString[i]        := BOOL_STR[Params[i].VBoolean];
      vtChar    :      Q.Params.AsAnsiString[i]    := Params[i].VChar;
      vtWideChar:      Q.Params.AsString[i]        := Params[i].VWideChar;
      vtExtended:      Q.Params.AsDouble[i]        := Params[i].VExtended^;
      vtCurrency:      Q.Params.AsCurrency[i]      := Params[i].VCurrency^;
      vtString  :      Q.Params.AsString[i]        := string(Params[i].VString^);
      vtPChar   :      Q.Params.AsAnsiString[i]    := Params[i].VPChar^;
      vtAnsiString:    Q.Params.AsAnsiString[i]    := AnsiString(Params[i].VAnsiString);
      vtWideString:    Q.Params.AsUnicodeString[i] := PWideChar(Params[i].VWideString);
      vtVariant   :    Q.Params.AsVariant[i]       := Params[i].VVariant^;
      vtUnicodeString: Q.Params.AsUnicodeString[i] := string(Params[i].VUnicodeString);
      vtPointer :
      begin
        if Params[i].VPointer = nil then
          Q.Params.IsNull[i] := True
        else
          Assert(False, 'not nil pointer is not supported');
      end
    else
      Assert(False, 'not supported');
    end;
end;

您知道如何使这种构造成为可能吗？我找到了一种方法，通过使用 RTTI 在 Nullable 中向 Variant 添加显式强制转换运算符覆盖，但这有点棘手，因为它需要在 const 调用数组中显式强制转换为 Variant ：

class operator Nullable<T>.Explicit(Value: Nullable<T>): Variant;
begin
  if Value.HasValue then
    Result := TValue.From<T>(Value.Value).AsVariant
  else
    Result := Null;
end;

...

    FDbController.Execute(
      'update or insert into MY_TABLE(TABLE_ID, OPTIONAL_FIELD) ' +
      'values (?, ?) ' + 
      'matching(TABLE_ID) returning TABLE_ID', [FId, Variant(FOptionalField)],
      procedure (Fields: TSQLResult)
      begin
        FId := Fields.AsInteger[0];
      end;
    end;  

Answer 1

正如您所说，在编译器的当前状态下，const 参数数组中不允许有记录。

事实上，TVarRec.VType 值没有任何 vtRecord。

而且 Variant 类型本身没有 Delphi 处理的 varRecord 类型。 Windows 世界中存在这样一种变体类型（例如，DotNet 结构体在 COM 中映射为 vt_Record 类型），但 Delphi 不处理这种变体。

可能的方法是将指针传递给记录的类型信息，然后传递给记录：

case Params[i].VType of
  vtPointer:
  if (i<high(Params)) and (Params[i+1].VType=vtPointer) then
    if Params[i].VPointer = TypeInfo(MyRecord) then begin
      ...
    end;

也许这不是一个很好的答案，因为您使用的是泛型......但至少是一个开始......在所有情况下，这就是我可以使用的方式这与预通用 Delphi 编译器有关。 TypeInfo() 关键字已经非常强大，并且比“新”RTTI 实现更快。

另一种可能性（与泛型兼容）应该是在记录内容中添加一些记录类型 ID。然后将记录作为指针传递，读取 ID，并按预期操作：

case Params[i].VType of
  vtPointer:
  if Params[i].VPointer <> nil then
  case PRecordType(Params[i].VPointer)^ of
  aRecordType: ...
      ...
  end;

这可以通过初始 Nullable 定义的简单扩展来实现。

Post-Scriptum：

在 ORM 中使用记录可能不是最好的解决方案...

class 模型比 record/object 更先进Delphi 中的模型，并且由于 ORM 是关于对象建模的，因此您应该使用可用的最佳 OOP 模型，恕我直言。通过依赖类而不是记录，您可以拥有继承、嵌入类型信息（通过 Class 方法或仅通过 PPointer(aObject)^ ）、可为 null 的值和虚拟方法（这对于 ORM 来说非常方便）。即使是 const 参数数组问题也将允许直接处理此类 vtObject 类型和专用的类虚拟方法。基于记录的 ORM 只是序列化表行的一种方式，而不是使用 OOP 最佳实践来设计应用程序。关于性能，与复制记录的潜在问题（_CopyRecord RTL 函数 - 由编译器以隐藏方式调用，例如对于函数参数 - 可能会非常慢）。

例如，在我们的 ORM 中，我们处理动态数组属性，甚至是属性中记录的动态数组< /a> （Delphi 不会为记录的已发布属性生成 RTTI，这是当前类实现的另一个不一致行为）。我们使用“旧”RTTI 将记录和动态数组序列化为 JSON 或二进制文件，而且效果很好。两个对象世界中最好的。

Answer 2

感谢 Robert Love 的想法，我在 Nullable 上向 TValue 添加了隐式转换，并将所有 Params: array of const 替换为 const Params: array of TValue。

我现在可以在不进行变体转换的情况下传递参数：

procedure TMyTableObject.InternalSave;
begin
  { FDbController is declared and managed in TDbObject, it contains fonction to run queries
    on the database }

  FDbController.Execute(
    'update or insert into MY_TABLE(TABLE_ID, OPTIONAL_FIELD) ' +
    'values (?, ?) ' + 
    'matching(TABLE_ID) returning TABLE_ID', [FId, FOptionalField],
    procedure (Fields: TSQLResult)
    begin
      FId := Fields.AsInteger[0];
    end;
  end;      
end;

MapParams 方法已变为：

procedure TDbContext.MapParams(Q: TUIBQuery; const Params: array of TValue);
const
  { maps to CREATE DOMAIN BOOLEAN AS CHAR(1) DEFAULT 'F' NOT NULL CHECK (VALUE IN ('V', 'F')) }
  BOOL_STR: array[Boolean] of string = ('F', 'V'); 
var
  I: Integer;
begin
  Q.Prepare(True);
  for I := 0 to Q.Params.ParamCount - 1 do
  begin
    if Params[I].IsEmpty then
      Q.Params.IsNull[I] := True
    else
      case Q.Params.FieldType[I] of
      uftChar,
      uftVarchar,
      uftCstring:
      begin
        { Delphi Booleans are tkEnumeration in TValue }
        if Params[I].Kind = tkEnumeration then
          Q.Params.AsString[I] := BOOL_STR[Params[I].AsBoolean]
        else
          Q.Params.AsString[I] := Params[I].ToString;
      end;
      uftSmallint,
      uftInteger:          Q.Params.AsSmallint[I] := Params[I].AsInteger;
      uftFloat,
      uftDoublePrecision : Q.Params.AsDouble[I]   := Params[I].AsExtended;
      uftNumeric:          Q.Params.AsCurrency[I] := Params[I].AsCurrency;
      uftTimestamp:        Q.Params.AsDateTime[I] := Params[I].AsExtended;
      uftDate:             Q.Params.AsDate[I]     := Params[I].AsInteger;
      uftTime:             Q.Params.AsDateTime[I] := Params[I].AsInteger;
      uftInt64:            Q.Params.AsInt64[I]    := Params[I].AsInt64;

      uftUnKnown, uftQuad, uftBlob, uftBlobId, uftArray
    {$IFDEF IB7_UP}
     ,uftBoolean
    {$ENDIF}
    {$IFDEF FB25_UP}
     ,uftNull
    {$ENDIF}:       Assert(False, 'type de données non supporté');
     end;
  end;
end;

请注意，我通过要求数据库描述并强制输入参数的类型来强制执行类型检查，并且我反转了访问参数的方式，优先考虑查询参数，因此它会引发无法进行转换时的例外：数据库 World 中可用的数据类型比 Delphi World 中的可用数据类型少得多。