我怎样才能到达超类的文本元素？

Question

我有以下场景：

我有一个 MovieClip，我为其创建了一个名为 A 的链接。

class A extends B{

}

class B extends C {
}

class C extends MovieClip {

  public function C() {
  // from the constructor of C i want to be able to reach the elements in Class a.
  // for example I have some text elements that I want to change.
  //  super.super is not allowed. 

  }

}

允许什么？我该如何解决这个问题？

更新

好吧，这是一个确切的场景，但一个更简单的场景，我仍然无法解决。

最初的场景是，我有一个名为 user_bg_me 的 MovieClip，它有一个名为 user_bg_me 的链接，该链接扩展了 user_bg_generic，该链接扩展了

内部的 “MovieClip” user_bg_generic 类我希望能够修改影片剪辑本身内的元素。使用 super.element_name 会出现找不到该属性的错误。

有什么想法吗？

Answer 1

我认为您可能对继承的工作原理感到困惑；特别是父类和子类之间的关系。

父类可以以子类可以使用的方法和属性的形式公开行为，这是一个非常简单的实际示例：

public class Parent {
    // Constructor for the Parent Class.
    public function Parent() {
    }

    protected function sayHello() : void {
        trace("Hello!");
    }
}

我们现在可以创建此父类的子类这将获得父类的可见行为（函数和属性）：

public class Child extends Parent {
    // Constructor for the Child Class.
    public function Child() {
        // Call the 'parent' classes constructor.
        super();

        // This child class does not define a function called "sayHello" but
        // the Parent class which this Child class extends does, and as a result
        // we can make a call to it here.  This is an example of how the child Class
        // gains the behaviours of the Parent class.
        this.sayHello();
    }

    public function sayGoodbye() : void {
        trace("Goodbye!");
    }
}

现在，这种关系（子类可以访问它们扩展的父类的函数和属性）仅以一种方式起作用。也就是说，父类不知道其子类可能选择声明的函数和属性，因此，以下代码将不起作用：

public class Parent {
    public function Parent() {
        // Trying to call the sayGoodbye() method will cause a compilation Error.
        // Although the "sayGoodbye" method was declared in the Child class, the
        // Parent Class has no knowledge of it.
        this.sayGoodbye();
    }
}

现在，让我们看看如何解决您尝试的问题从父类访问属于 FLA 中实例的 TextField：

// it is important to note that by extending the MovieClip class, this Parent Class now
// has access to all the behaviours defined by MovieClip, such as getChildByName().
public class Parent extends MovieClip {
    // This is a TextField that we are going to use.
    private var txtName : TextField;

    public function Parent() {
        // Here we are retrieving a TextField that has an instance name of txtName
        // from the DisplayList.  Although this Parent Class does not have  a TextField
        // with such an instance name, we expect the children that extend it to declare
        // one.
        txtName = this.getChildByName("txtName") as TextField;

        // Check to see if the Child class did have an TextField instance called 
        //txtName.  If it did not, we will throw an Error as we can not continue.
        if (txtName == null) {
            throw new Error("You must have a TextField with an instance name of 'txtName' for this Parent Class to use.");
        }

        // Now we can make use of this TextField in the Parent Class.
        txtName.text = "Hi my name is Jonny!";
    }
}

现在，您的 FLA 中可以有任意多个实例，其中链接扩展了该父类。您只需确保它们有一个实例名称为“txtName”的 TextField，以便父类可以执行其操作。

希望这有帮助:)

Answer 2

你的层次结构倒退了。 C 类无法访问 A 的成员，因为 A 是 C 的子类，而不是相反。 C 类中的“super.super”即使有效也不会得到您想要的，因为它会引用 MovieClip 扩展的 Sprite 类。

雪碧 ->影片剪辑 -> C-> B-> A 是您的层次结构，

但更重要的是，您通常不需要 super 关键字来访问超类成员。仅当您使用同名的子类成员覆盖超类成员并且需要区分时，才需要关键字。如果不存在任何命名冲突，则无需使用 super 或类名限定符即可访问超类的公共和受保护成员。如果你真的认为你需要 super.super，你需要重新考虑你的继承设计。