如何在评估时删除输入单元格？

Question

我想完成以下任务：在评估输入单元格时，它应该自毁（即删除自身）。我尝试与 SelectionMove 和 NotebookDelete 一起破解一些东西，但没有完全得到我想要的东西。

以下是潜在的用例：

• 该命令可能是将动态生成并插入笔记本中的一系列其他命令的简写

• 该命令可能仅用于副作用（例如设置笔记本选项或打开新笔记本）；评估后将命令留在笔记本中没有任何作用，并且会造成混乱

编辑：根据向导先生，答案是 SelectionMove[EvaluationNotebook[], Previous, Cell]； NotebookDelete[];。我不知道为什么它以前对我不起作用。下面是一些使用这个习惯用法的代码。

writeAndEval[nb_, boxExpr_] := (NotebookWrite[nb, 
    CellGroupData[{Cell[BoxData[boxExpr], "Input"]}]];
   SelectionMove[nb, Previous, Cell];
   SelectionMove[nb, Next, Cell];
   SelectionEvaluate[nb]);

addTwoAndTwo[] := Module[{boxExpr},
  boxExpr = RowBox[{"2", "+", "2"}];
  SelectionMove[EvaluationNotebook[], Previous, Cell];
  NotebookDelete[];
  writeAndEval[EvaluationNotebook[], boxExpr];
  ]

现在，运行 addTwoAndTwo[] 会删除原始输入，并使它看起来好像您已经计算了“2+2”。当然，您可以做各种各样的事情，而不必打印到笔记本上。

编辑2：Sasha 的抽象相当优雅。如果您对它的“现实世界”用法感到好奇，请查看我在“工具包中有什么”问题中发布的代码：您的 Mathematica 工具包中有什么？

Answer 1

要影响所有输入单元格，请评估笔记本：

SetOptions[EvaluationNotebook[], CellEvaluationFunction -> 
  ( (
    SelectionMove[EvaluationNotebook[], All, EvaluationCell]; NotebookDelete[];
    ToExpression@#
  )&)
]

如果您只想影响一个单元格，请选择该单元格并使用选项检查器按上述方式设置 CellEvaluationFunction。

Answer 2

或者，以先生为基础。向导的解决方案，您可以创建一个函数SelfDestruct，如果您只想偶尔这样做，它将删除输入单元格：

SetAttributes[SelfDestruct, HoldAllComplete];
SelfDestruct[e_] := (If[$FrontEnd =!= $Failed,
   SelectionMove[EvaluationNotebook[], All, EvaluationCell]; 
   NotebookDelete[]]; e)

然后评估2+3//SelfDestruct 输出 5 并删除输入单元格。这种使用场景对我来说似乎更有吸引力。