用于给定 XML 结构的 XSLT（对于 CSV）

Question

我不知道如何制作 XML 的 XSLT 将其转换为 CSV。请为给定的 XML 结构编写 XSLT 代码，并尝试验证并考虑所有原始逗号和引号等。

<DROPSHIPITEMS>
  <CREATED value="Thu Apr 21 23:17:39 BST 2011">
    <PRODUCT ITEM='8101'>
      <MODEL>FY316A</MODEL>
      <EAN>5055071647109</EAN>
      <NAME>Enchanted Twilight Flower Fairy 'Amethyst'</NAME>
      <DESCRIPTION><![CDATA[<p> Twilight Fairy 'Amethyst'</p><p>This, Fairy.</p>]]></DESCRIPTION>
      <DIMENSION><![CDATA[Height 31 - 32cm Width, 16 - 18.5cm Depth 12 - 13.5cm]]></DIMENSION>
      <PRICE>16.63</PRICE>
      <DELIVERY>I</DELIVERY>
      <QUANTITY>224</QUANTITY>
      <MIN_ORDER_QTY>1</MIN_ORDER_QTY>
      <URL>http://www.abc-dropship.co.uk/gifts/product_info.php?products_id=8101</URL>
      <IMAGE_URL>http://www.abc-dropship.co.uk/gifts/images/FY316A_001.jpg</IMAGE_URL>
      <CATEGORIES>9003|100297</CATEGORIES>
      <OPTIONS><![CDATA[B - Hand on Dress|A - Flower in Hand|Any]]></OPTIONS>
    </PRODUCT>
</CREATED>
</DROPSHIPITEMS>

谢谢

Answer 1

试试这个：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text"/>

  <xsl:template match="/">
    <xsl:for-each select="*/*/*[1]/*">
      <xsl:value-of select="name()" />
      <xsl:if test="not(position() = last())">,</xsl:if>
    </xsl:for-each>
    <xsl:text>
</xsl:text>
    <xsl:apply-templates select="*/*/*" mode="row"/>
  </xsl:template>

  <xsl:template match="*" mode="row">
    <xsl:apply-templates select="*" mode="data" />
    <xsl:text>
</xsl:text>
  </xsl:template>

  <xsl:template match="*" mode="data">
    <xsl:choose>
      <xsl:when test="contains(text(),',')">
        <xsl:text>"</xsl:text>
        <xsl:call-template name="doublequotes">
          <xsl:with-param name="text" select="text()" />
        </xsl:call-template>
        <xsl:text>"</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="." />
      </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="position() != last()">,</xsl:if>
  </xsl:template>

  <xsl:template name="doublequotes">
    <xsl:param name="text" />
    <xsl:choose>
      <xsl:when test="contains($text,'"')">
        <xsl:value-of select="concat(substring-before($text,'"'),'""')" />
        <xsl:call-template name="doublequotes">
          <xsl:with-param name="text" select="substring-after($text,'"')" />
        </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of select="$text" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>

它可以正确处理带逗号的字段和带双引号的字段。

编辑：差点忘了；该模板添加了一个带有字段名称的标题行。如果您不需要，第一个模板只需

  <xsl:template match="/">
    <xsl:apply-templates select="*/*/*" mode="row"/>
  </xsl:template>

Answer 2

将 XML 转换为逗号分隔与任何其他转换相同。以下按原样重现字段，除非它们在您仍然需要处理的每个产品中的顺序相同。该示例将帮助您入门：

  <xsl:output method="text"/>

  <xsl:template match="//PRODUCT">
        <xsl:value-of select="@ITEM" />
    <xsl:text>,</xsl:text>
    <xsl:apply-templates select="./*" />
    <xsl:text>
</xsl:text>
  </xsl:template>

  <xsl:template match="PRODUCT/*">
        <xsl:value-of select="translate(text(), ',', '@')" />
    <xsl:text>,</xsl:text>
  </xsl:template>

顺便说一句，�A; 添加换行符，对于 dos/windows，您可能还需要添加 �D;。

更新：值中的逗号可以通过使用 translate() 函数将其替换为另一个字符来转义。