类型/类实例上的开关/大小写？

Question

我有一组不同的 MovieClip：

Pink
Yellow
Red

并且我创建了一个项目

item = new Pink();
item = new Red();

等...

我如何编写一个 switch case 来查看我拥有哪个 MovieClip？

switch (item) {
 case Pink:
 // do something
 break;

 case Red:
 // do something
 break;
}

我只知道如何为字符串编写 switch case...

Answer 1

您可以获取字符串形式的类名，然后像通常使用此方法一样对其进行切换...

switch (getQualifiedClassName(item)) {
 case "Pink":
 // do something
 break;

 case "Red":
 // do something
 break;
}

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/utils/package.html#getQualifiedClassName()< /a>

Answer 2

简单的回答：不。

Pink和Red都是Color，所以让Color有一个功能：

interface IColor
{
  public function doSomething():void;
}

并且有Pink code> 和 Red 扩展了函数：

class Pink extends MovieClip implements IColor
{
  ...
  public override function doSomething():void
  {
    //different code
  }
}

class Red extends MovieClip implements IColor
{
  ...
  public override function doSomething():void
  {
    //more different code
  }
}

然后在你的代码中你可以调用：

item.doSomething();

它会为任何一种情况做正确的事情。

Answer 3

这个问题已经有了答案，但对于任何有兴趣的人，您也可以这样做：

package 
{
    import flash.display.Sprite;
    import flash.events.Event;

    public class Main extends Sprite 
    {
        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);

        }// end function

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);

            var cat:Cat = new Cat();

            switch(Class(Object(cat).constructor))
            {
                case Cat : trace("instance of " + Cat); break;
                case Dog : trace("instance of " + Dog); break;

            }// end switch

            // output: 

        }// end function

    }// end class

}// end package

internal class Cat
{ 
    public function Cat() { }

}// end class

internal class Dog
{ 
    public function Dog() { }

}// end class

Answer 4

使用“is”关键字：

if (item is Pink) // do something

在 case 语句中使用“is”看起来像这样：

switch(true)
{
    case item is Pink :
        // do something
        break;

    case item is Red :
        // do something
        break;
}

“is”语句的强大之处在于它适用于继承类型。因此，举例来说，如果我想检查 MovieClip、Sprite 或 SimpleButton，我可以这样写：

if (item is DisplayObject) // do something

因为所有这些类型都继承自 DisplayObject。

另一个好处是没有不必要的内省（例如使用 getQualifiedClassName）。因此，“is”关键字具有更好的性能，并且不需要额外的代码。