Erlang：通过主管启动时 gen_server 崩溃

Question

所以，我花了很多时间，仍然没有找到答案。

我在 gen_server 中有一个简单的 tcp 服务器，它通过 telnet 接受消息并在控制台中打印它们：

-module(st_server).

-behaviour(gen_server).
%% --------------------------------------------------------------------
%% Include files
%% --------------------------------------------------------------------

%% --------------------------------------------------------------------
%% External exports
-export([start_link/0, start_link/1, stop/0]).

%% gen_server callbacks
-export([init/1, handle_call/3, handle_cast/2, handle_info/2, terminate/2, code_change/3]).

-define(SERVER, ?MODULE).
-define(DEFAULT_PORT, 1055).

-record(state, {lsock, port}).

%% ====================================================================
%% External functions
%% ====================================================================

%%--------------------------------------------------------------------
%% @doc Starts the server.
%%
%% @spec start_link(Port::integer()) -> {ok, Pid}
%% where
%%  Pid = pid()
%% @end
%%--------------------------------------------------------------------
start_link(Port) ->
    gen_server:start_link({local, ?SERVER}, ?MODULE, [Port], []),
    io:format("Server name: ~w, port: ~w.~n", [?SERVER, Port]).

%% @spec start_link() -> {ok, Pid}
%% @doc Calls `start_link(Port)' using the default port.
start_link() -> start_link(?DEFAULT_PORT).

%%-------------------------------------------------------------------- 
%% @doc Stops the server. 
%% @spec stop() -> ok 
%% @end 
%%-------------------------------------------------------------------- 
stop() ->
    gen_server:cast(?SERVER, stop).

%% ====================================================================
%% Server functions
%% ====================================================================

%% --------------------------------------------------------------------
%% Function: init/1
%% Description: Initiates the server
%% Returns: {ok, State}          |
%%          {ok, State, Timeout} |
%%          ignore               |
%%          {stop, Reason}
%% --------------------------------------------------------------------
init([Port]) ->
    {ok, LSock} = gen_tcp:listen(Port, [{active, true}]),
    {ok, #state{lsock = LSock, port = Port}, 0}.

%% --------------------------------------------------------------------
%% Function: handle_cast/2
%% Description: Handling cast messages
%% Returns: {noreply, State}          |
%%          {noreply, State, Timeout} |
%%          {stop, Reason, State}            (terminate/2 is called)
%% --------------------------------------------------------------------
handle_cast(stop, State) ->
    {stop, normal, State}.

handle_call(_Request, _From, State) ->
    {reply, ok, State}.

%% --------------------------------------------------------------------
%% Function: handle_info/2
%% Description: Handling all non call/cast messages
%% Returns: {noreply, State}          |
%%          {noreply, State, Timeout} |
%%          {stop, Reason, State}            (terminate/2 is called)
%% --------------------------------------------------------------------


handle_info({tcp, _Socket, Data}, State) ->
    io:format("Incoming info: ~s", [Data]),
    {noreply, State};

handle_info({tcp_closed, _Socket}, #state{lsock = LSock} = State) ->
    {ok, _Sock} = gen_tcp:accept(LSock),
    {noreply, State};

handle_info(timeout, #state{lsock = LSock} = State) ->
    {ok, _Sock} = gen_tcp:accept(LSock),
    {noreply, State}.

%% --------------------------------------------------------------------
%% Function: terminate/2
%% Description: Shutdown the server
%% Returns: any (ignored by gen_server)
%% --------------------------------------------------------------------
terminate(Reason, _State) ->
    io:format("~nServer shutdown. Reason: ~s.~n", [Reason]),
    ok.

%% --------------------------------------------------------------------
%% Func: code_change/3
%% Purpose: Convert process state when code is changed
%% Returns: {ok, NewState}
%% --------------------------------------------------------------------
code_change(_OldVsn, _State, _Extra) ->
    {ok, _State}.

%% --------------------------------------------------------------------
%%% Internal functions
%% --------------------------------------------------------------------

主管：

-module(st_sup).

-behaviour(supervisor).
%% --------------------------------------------------------------------
%% Include files
%% --------------------------------------------------------------------

%% --------------------------------------------------------------------
%% External exports
%% --------------------------------------------------------------------
-export([]).

%% --------------------------------------------------------------------
%% Internal exports
%% --------------------------------------------------------------------
-export([
     init/1,
     start_link/0
        ]).

%% --------------------------------------------------------------------
%% Macros
%% --------------------------------------------------------------------
-define(SERVER, ?MODULE).

%% --------------------------------------------------------------------
%% Records
%% --------------------------------------------------------------------

%% ====================================================================
%% External functions
%% ====================================================================

start_link() ->
    supervisor:start_link({local, ?SERVER}, ?MODULE, []).

%% ====================================================================
%% Server functions
%% ====================================================================
%% --------------------------------------------------------------------
%% Func: init/1
%% Returns: {ok,  {SupFlags,  [ChildSpec]}} |
%%          ignore                          |
%%          {error, Reason}
%% --------------------------------------------------------------------
init([]) ->
    Server = {st_server, {st_server, start_link, []},
                permanent, 2000, worker, [st_server]},
    Children = [Server],
    RestartStrategy = {one_for_one, 0, 1},
    {ok, {RestartStrategy, Children}}.

%% ====================================================================
%% Internal functions
%% ====================================================================

我在 erlang 控制台中启动它：

st_sup:start_link().

得到这个：

Server name: st_server, port: 1055.
** exception exit: shutdown

这意味着主管因某种原因关闭了服务器。 如果我自己启动服务器（st_server：start_link。）它工作得很好。

那么，问题是如何在不停机的情况下使其工作？

Answer 1

乍一看，可能是因为st_server:start_link/1的返回值是调用io:format/2的返回值。

当您直接在 REPL 中调用 st_server:start_link() 时，这很好，但主管可能期望返回值更像 {ok, Pid}。

您只需交换 st_server:start_link/1 中的两行即可解决此问题，以便它返回对 gen_server:start_link/4 的调用值：

start_link(Port) ->    
    io:format("Server name: ~w, port: ~w.~n", [?SERVER, Port]),
    gen_server:start_link({local, ?SERVER}, ?MODULE, [Port], []).

Answer 2

主管的 RestartStrategy 也是一个奇怪的值，它设置为 {one_for_one,0,1}。这意味着主管将在 1 秒内重新启动超过 0 次后放弃，实际上它将在子进程第一次崩溃后放弃。这通常不是您希望主管做的事情。