从另一个传递参数调用批处理文件

Question

我有以下批处理文件，运行时要求用户输入。这很好用。

@REM Sample batch file
SET PARAM1=""
SET PARAM2=""
SET /P PARAM1=Enter param1: %=%
SET /P PARAM2=Enter param2: %=%
@REM Process the params

我现在希望能够从另一个批处理文件调用此批处理文件并将参数值传递到上面的批处理文件，并且不会要求用户输入。我怎样才能实现这个目标？

Answer 1

我相信你想要这样的东西？

@echo off

:: Fetch param1
set "param1=%~1"
goto :param1Check
:param1Prompt
set /p "param1=Enter parameter 1: "
:param1Check
if "%param1%"=="" goto :param1Prompt

:: Fetch param2    
set "param2=%~2"
goto :param2Check
:param2Prompt
set /p "param2=Enter parameter 2: "
:param2Check
if "%param2%"=="" goto :param2Prompt

:: Process the params
echo param1=%param1%
echo param2=%param2%

Test.bat 不带参数运行：

>>test.bat
Enter parameter 1: foo
Enter parameter 2: bar
param1=foo
param2=bar

Test.bat 带参数运行：

>>test.bat foo bar
param1=foo
param2=bar

---

替代方案，使用环境变量而不是命令行参数（另请参阅 ppumkin 的回答）：

@echo off  

:: Fetch param1  
**set "param1=%globalparam1%"**  
goto :param1Check  
:param1Prompt  
set /p "param1=Enter parameter 1: "  
:param1Check  
if "%param1%"=="" goto :param1Prompt  

:: Fetch param2    
**set "param2=%globalparam2%"**  
goto :param2Check  
:param2Prompt  
set /p "param2=Enter parameter 2: "  
:param2Check  
if "%param2%"=="" goto :param2Prompt  

:: Process the params  
echo param1=%param1%  
echo param2=%param2%

只需设置环境变量 globalparam1 并globalparam2 在您的环境或您调用的批处理文件中抑制提示：

Test.bat run withoutsettingenvironmentvariables:

>>test.bat
Enter parameter 1: foo
Enter parameter 2: bar
param1=foo
param2=bar

Test.batrunwithsettingenvironmentvariables:

>>set globalparam1=foo

>>set globalparam2=bar

>>test
param1=foo
param2=bar

注意：设置环境变量也可以在例如调用批处理脚本。

Answer 2

在 main.cmd 中：

set param1=%~1
set param2=%~2
echo %param1% - %param2%

在 caller.cmd 中：

call main.cmd hello world

输出：

hello - world

批处理脚本参数参考

Answer 3

caller.bat /.cmd

@echo off
cls
set vara="Hello There"
set varb=67890

echo Variables set in caller.bat:
echo %vara%
echo %varb%

echo Calling passTo.bat
call passTo.bat %vara% %varb%

passTo.bat /.cmd

@echo off
echo.
echo Inside passTo.bat
set vara=%1
set varb=%2

echo vara: %vara%
echo varb: %varb%

从 dos 或命令窗口或任何其他应用程序/快捷方式单独调用 passTo.bat

call passTo.bat PARAM1 PARAM2

---

在另一个批处理中使用 caller.bat 中的设置变量

@echo off
echo.
echo Inside another.bat
echo -- You can start another batch here that sets the environment variables

set varOne=%vara% <- This gets the Environments Variable set in the nested batch bat using SET
set varTwo=%varb%

echo vara: %varOne% 
echo Is the same as
echo %vara%

echo varb: %varTwo%
echo is again the same as
echo %varb$

您可能必须使用 SETX