将 org.w3c.dom.NodeList 转换为 Clojure ISeq

Question

我正在尝试获取新的 defprotocol、reify 等的句柄。

我有一个从XPath 调用，我想将其“转换”为 ISeq。

在Scala中，我实现了一个隐式转换方法：

implicit def nodeList2Traversable(nodeList: NodeList): Traversable[Node] = {
  new Traversable[Node] {
    def foreach[A](process: (Node) => A) {
      for (index <- 0 until nodeList.getLength) {
        process(nodeList.item(index))
      }
    }
  }
}

NodeList包括方法int getLength()和Node item(int index)。

我如何在 Clojure 中做同样的事情？我预计我需要使用 defprotocol。我需要定义哪些函数来创建 seq？

如果我使用loop和recur对列表进行简单、天真的转换，我最终会得到一个非惰性结构。

Answer 1

大多数 Clojure 的序列处理函数都会返回惰性序列，包括 map 和 range 函数：

(defn node-list-seq [^org.w3c.dom.NodeList node-list]
  (map (fn [index] (.item node-list index))
       (range (.getLength node-list))))

请注意，上面的 NodeList 类型提示不是必需的，但可以提高性能。

现在您可以像这样使用该函数：

(map #(.getLocalName %) (node-list-seq your-node-list))

Answer 2

使用进行理解，这些会产生惰性序列。

这是适合您的代码。我花了一些时间让它可以在命令行上运行；您只需替换已解析的 XML 文件的名称。

注意事项 1：避免定义变量。请改用局部变量。

注意事项 2：这是用于 XML 的 Java API，因此对象是可变的；由于您有一个惰性序列，因此如果在迭代时可变 DOM 树发生任何更改，您可能会遇到令人不快的竞争更改。

警告 3：即使这是一个惰性结构，整个 DOM 树已经在内存中了（不过，我不太确定最后一条评论。我认为 API 试图推迟读取内存中的树直到需要时，但不能保证）。因此，如果您在处理大型 XML 文档时遇到麻烦，请尽量避免使用 DOM 方法。

(require ['clojure.java.io :as 'io])
(import [javax.xml.parsers DocumentBuilderFactory])
(import [org.xml.sax InputSource])

(def dbf (DocumentBuilderFactory/newInstance))
(doto dbf
  (.setValidating false)
  (.setNamespaceAware true)
  (.setIgnoringElementContentWhitespace true))
(def builder (.newDocumentBuilder dbf))
(def doc (.parse builder (InputSource. (io/reader "C:/workspace/myproject/pom.xml"))))

(defn lazy-child-list [element]
  (let [nodelist (.getChildNodes element)
        len (.getLength nodelist)]
    (for [i (range len)]
      (.item nodelist i))))

;; To print the children of an element
(-> doc
    (.getDocumentElement)
    (lazy-child-list)
    (println))

;; Prints clojure.lang.LazySeq
(-> doc
    (.getDocumentElement)
    (lazy-child-list)
    (class)
    (println))