如何更改 TTabSheets 的背景颜色？

Question

我正在使用 Delphi 2009 设计表单，并且正在尝试找出 TPageControl 元素。我试图为每个选项卡创建单独的对话框。我可以制作 TTabSheets，并且可以将元素放置在 TabSheets 上，但我的问题是它们是大麦可见的，因为 TTabSheet 的默认背景似乎是白色。我尝试在 TabSheet 上放置一个面板，但无论出于何种原因，该面板总是出现在 TabSheet 后面。所以我的问题是：有没有办法将标签页的颜色更改为标准的 Windows 米色，或者他们是否可以在标签页上放置 TPanel 来实现相同的目标？

Answer 1

将样式属性设置为 tsFlatButtons
背景〜颜色〜将恢复为美丽的clBtnFace

Answer 2

选项卡的标准 Windows 颜色是白色。该标准是在 XP 主题推出时应运而生的。如果用户切换回 Windows Classic，他们将看到灰色背景。 [你的意思是灰色而不是米色，不是吗？米色真的很卑鄙！]

选项卡内的面板永远不能位于页面后面，因为它位于页面内部。实际发生的情况是，面板被透明绘制，以便标准选项卡颜色占主导地位。

Answer 3

在您的表单中的界面中使用此单位：

unit MSCtrlsStyleHook;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ComCtrls, Vcl.ExtCtrls, Vcl.Themes,
  Winapi.CommCtrl;

type
  TTabSheet = class(Vcl.ComCtrls.TTabSheet)
  private
    procedure WMEraseBkgnd(var Message: TWMEraseBkgnd); message WM_ERASEBKGND;
  end;

  TPageControl = class(Vcl.ComCtrls.TPageControl)
  private
    procedure TCMAdjustRect(var Msg: TMessage); message TCM_ADJUSTRECT;
  end;

implementation

{ TPageControl }

procedure TPageControl.TCMAdjustRect(var Msg: TMessage);
begin
  inherited;
  if Msg.WParam = 0 then
    InflateRect(PRect(Msg.LParam)^, 3, 3)
  else
    InflateRect(PRect(Msg.LParam)^, -3, -3);
end;

{ TTabSheet }

procedure TTabSheet.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var
  LRect  : TRect;
  LCanvas: TCanvas;
begin
  if (PageControl <> nil) and StyleServices.Enabled and
     ((PageControl.Style = tsTabs) or TStyleManager.IsCustomStyleActive) then
  begin
    //Get the bounds of the Tabsheet
    GetWindowRect(Handle, LRect);
    OffsetRect(LRect, -LRect.Left, -LRect.Top);
    //create a TCanvas for erase the background, using the DC of the message
    LCanvas := TCanvas.Create;
    try
      LCanvas.Handle := Message.DC;
      LCanvas.Brush.Color:= $fafafa;// Color You need;
      LCanvas.FillRect(LRect);
    finally
      LCanvas.Handle := 0;
      LCanvas.Free;
    end;

    Message.Result := 1;
  end
  else
    inherited;
end;

end.

Answer 4

不太喜欢这两种解决方案，这就是我正在做的事情来阻止您遇到的问题。您不需要牺牲 Windows 主题来使其工作：

只需检查：

if ThemeServices.ThemesEnabled then
  FormBGColor := clBtnHighlight
else
  FormBGColor := clBtnFace;

并设置表单的颜色，然后再将其显示在选项卡上。

（就我个人而言，我从来不喜欢这个解决方案，但这就是我在开始之前编写的程序的主要部分是如何编程的，因此为了使它在我的计算机异或终端服务器上看起来不像垃圾，这就是我必须做的）

---

ThemeServices 是在主题.pas中

Answer 5

如果您希望将 PageControl Style 属性保留为 tsTabs，那么您需要破解 TTabSheet 类...

在表单的类型声明上方添加以下内容...

  TTabSheet = class(ComCtrls.TTabSheet)
  protected
    procedure PaintWindow(DC: HDC); override;
  end;

然后在单元的实现部分...

  var brushBtnFace: HBrush;

  procedure TTabSheet.PaintWindow(DC: HDC);
  var
    rec: TRect;
  begin
    rec := ClientRect;
    windows.FillRect(DC, rec, brushBtnFace);
  end;

最后创建和销毁你在单元的初始化和完成部分刷...

  initialization
    brushBtnFace := CreateSolidBrush(GetSysColor(COLOR_BTNFACE));
  finalization
    DeleteObject(brushBtnFace);