带有计时器对象和前进或后退选项的 Flash 幻灯片放映

Question

我刚开始使用 Flash，但通过一些有用的 YouTube 教程和各种 Google 搜索，我能够创建一个幻灯片放映，并在 6 秒后自动转换到下一个。我还认为，如果我能让用户能够后退、前进或专门跳转到某个幻灯片，那就太好了。但我的问题是，点击按钮后，计时器似乎关闭了。

这是我的动作脚本代码：

import flash.events.MouseEvent;
import flash.utils.*;

// Stop initial picture fading from looping
stop()

// New timer object set to 6 seconds (1000 milliseconds/second)
var myTimer:Timer = new Timer(6000, 1);

myTimer.addEventListener ("timer", timerHandler);
myTimer.reset();
myTimer.start();

function timerHandler(event:TimerEvent): void {
if(currentFrame == 4){
     myTimer.reset();
     myTimer.start();
     gotoAndStop("pajNtaub");
 }else{
     myTimer.reset();
     myTimer.start();
     nextFrame();
     }
}

// Move to next state
function onNextClick(event:MouseEvent):void{
    if(currentFrame == 4){
        myTimer.reset();
        myTimer.start();
        gotoAndStop("pajNtaub");
    }else{
        myTimer.reset();
        myTimer.start();
        nextFrame();
    }
}
forwardArrow.addEventListener(MouseEvent.CLICK, onNextClick);

// Move to previous state
function onPrevClick(event:MouseEvent):void{
    if(currentFrame == 1){
        myTimer.reset();
        myTimer.start();
        gotoAndStop("posHuab");
    }else{
        myTimer.reset();
        myTimer.start();
        prevFrame();
    }
}
backArrow.addEventListener(MouseEvent.CLICK, onPrevClick);

// First button
function play0(event:MouseEvent):void{
    myTimer.reset();
    myTimer.start();
    gotoAndStop("pajNtaub");
}
button0.addEventListener(MouseEvent.CLICK,play0);

// Second button
function play1(event:MouseEvent):void{
    myTimer.reset();
    myTimer.start();
    gotoAndStop("kabTab");
}
button1.addEventListener(MouseEvent.CLICK,play1);

// Third button
function play2(event:MouseEvent):void{
    myTimer.reset();
    myTimer.start();
    gotoAndStop("nroog");
}
button2.addEventListener(MouseEvent.CLICK,play2);

// Fourth button
function play3(event:MouseEvent):void{
    myTimer.reset();
    myTimer.start();
    gotoAndStop("posHuab");
}
button3.addEventListener(MouseEvent.CLICK,play3);

Answer 1

我不喜欢计时器 - 我会考虑使用 ENTER_FRAME 并使用一个变量来存储下一张幻灯片之前的时间，以便更容易管理。

以下是我的做法。

stop();

// vars
var nextTimer:int = 200;
var maxTimer:int = nextTimer;

// ENTER_FRAME
addEventListener(Event.ENTER_FRAME, _slideshow);
function _slideshow(e:Event):void
{
    nextTimer --;
    if(nextTimer < 1)
    {
        nextSlide();
    }
}


/**
 * Go to the next slide in the slideshow
 */
function nextSlide(e:MouseEvent=null):void
{
    nextTimer = maxTimer;

    if(currentFrame + 1 > totalFrames) gotoAndStop(1);
    else gotoAndStop(currentFrame + 1);
}

/**
 * Go to the previous slide in the slideshow
 */
function prevSlide(e:MouseEvent=null):void
{
    nextTimer = maxTimer;

    if(currentFrame - 1 < 1) gotoAndStop(totalFrames);
    else gotoAndStop(currentFrame - 1);
}


// listeners for next and prev buttons
nextbtn.addEventListener(MouseEvent.CLICK, nextSlide);
prevbtn.addEventListener(MouseEvent.CLICK, prevSlide);