根据 array.length 动态创建多个 TextField

Question

我一整天都在四处寻找，但没有找到解决方案。

我想做的是根据我的 array.length 动态创建 TextFields。因此，如果我的数组中有 3 个字符串，则需要创建 3 个包含数组文本的文本字段。

我已经成功地根据 array.length 创建了 TextFields - 但是之后我不知道如何单独引用它们，比如说重新定位 array[1] 的 x, y 。 我尝试通过 .push 方法将文本字段保存在另一个数组中，但似乎无法正确引用它们。

有什么建议吗？

//Create textfields based on data in Array - in this case 3 textfields
var textArray:Array = new Array('First TextField','TextField Two','Anything, really');

//Array to .push "save" created textfields
var referenceArray:Array = new Array();

// Creating font instance
var garageInstance:Font = new garage();

var myFormat:TextFormat = new TextFormat();

//Embedding font
myFormat.font = garageInstance.fontName;
myFormat.color = 0xFFFFFF;
myFormat.size = 46;
myFormat.align = TextFormatAlign.CENTER;

for (var i:int; i < textArray.length; i++)
{
//Creating the textfield object and naming it "myTextField2"
var myTextField2:TextField = new TextField();

myTextField2.defaultTextFormat = myFormat;
myTextField2.width = 930;
myTextField2.embedFonts = true;
myTextField2.multiline = true;
myTextField2.wordWrap = true;
myTextField2.selectable = false;
myTextField2.htmlText = textArray[i];

myTextField2.autoSize = TextFieldAutoSize.CENTER;

//Here we add the new textfield instance to the stage with addchild()
addChild(myTextField2);

//Saving textfield into array   
referenceArray.push(myTextField2);

}

Answer 1

我没有看到你的代码有任何奇怪的地方，一切都运行得很好。如果您没有看到任何结果，可能您的背景设置为白色，或者您已经将白色对象添加到舞台中。在这种情况下，您将看不到任何内容，因为文本的颜色设置为白色 (0xffffff)。例如，如果将其设置为黑色（0x000000），那么您将看到不错的结果。

如果不是这种情况，您是否正确引用了您的字体？如果使用 Adob​​e IDE，请右键单击库中的字体，然后选择“导出为 ActionScript”。

您使用的数组引用是完美的。将此代码放在脚本后面：

trace(referenceArray[0], referenceArray[0].text);

您将看到，它跟踪结果：

[object TextField] First TextField

所以输出很好，您的代码可以看到实例，因此它可以读取它的文本属性并且它是正确的。

如果您想动态设置文本字段的坐标，只需放入

myTextField2.y = i * 50;

for 循环即可。这将按如下方式放置每个文本字段：0、50、100 等。

您还可以使用 x 坐标。

Answer 2

可以尝试用一个数组填充定义每个文本字段属性的对象。

您的对象可以定义您喜欢的任何属性 - 内置或自定义（如果您使用自己的类扩展 TextField 并添加它）。

示例：数组：

var ar:Array = [
{
    text: "text field 1",
    y: 100,
    x: 20
},
{
    text: "text field 2",
    y: 200,
    x: 10,
    alpha: 0.5 // demonstrating that you can define any properties in the object
}];

以及创建字段的 for 循环：

/**
 * Iterate through ar and create textfields with defined properties
 */
var i:Object;
for each(i in ar)
{
    var t:TextField = new TextField();

    /**
     * Text format things here
     */

    var j:String;
    for(j in i)
    {
        t[j] = i[j];
    }

    addChild(t);
}