带括号表达式的 ANTLR 语法问题

Question

我正在使用 ANTLRWorks 1.4.2 创建一个简单的语法，以便将用户提供的表达式评估为布尔结果。这最终将成为更大语法的一部分，但我对当前的片段有一些疑问。我希望用户能够使用以下表达式：

1. 2 > 1
2. 2 > 1和3＜ 1
3. (2 > 1 或 1 < 3) 且 4 > 1
4. (2 > 1 or 1 < 3) and (4 > 1 or (2 < 1 and 3 > 1))

前两个表达式在我的代码中是合法的语法，但最后两个不是，我不知道为什么。另外，ANTLRworks似乎建议输入诸如 ((((1 > 2) 与不匹配的括号)是合法的，我不知道为什么。所以，我似乎错过了一些见解 如何更改

语法以正确处理括号？

我的语法如下：

grammar conditional_test;

boolean
    :   boolean_value_expression
        EOF
    ;

boolean_value_expression
    :   boolean_term (OR boolean_term)*
        EOF
    ;

boolean_term
    :   boolean_factor (AND boolean_factor)*
    ;

boolean_factor
    :   (NOT)?  boolean_test
    ;

boolean_test
    :   predicate
    ;

predicate
    :   expression relational_operator expression
    |   LPAREN boolean_value_expression RPAREN
    ;

relational_operator
    :   EQ
    |   LT
    |   GT
    ;   

expression
    :   NUMBER
    ;


LPAREN      :   '(';
RPAREN      :   ')';
NUMBER      :   '0'..'9'+;

EQ          :   '=';
GT          :   '>';
LT          :   '<';

AND         :   'and';
OR          :   'or' ;
NOT         :   'not';

Answer 1

克里斯·法默写道：

前两个表达式在我的语法中是合法的，但后两个不是，我不确定为什么。 ...

您应该从以下位置删除 EOF 标记：

boolean_value_expression
    :   boolean_term (OR boolean_term)*
        EOF
    ;

您通常只在语法入口点之后使用 EOF （在您的情况下为 boolean ）。请注意 boolean 是 Java 中的保留字，因此不能用作解析器规则！

因此，前两条规则应该如下所示：

bool
    :   boolean_value_expression
        EOF
    ;

boolean_value_expression
    :   boolean_term (OR boolean_term)*
    ;

您可能还想通过添加以下词法分析器规则来忽略文字空格：（

SPACE : ' ' {$channel=HIDDEN;};

当然，您可以包含制表符和换行符）

现在所有示例输入都正确匹配（使用 ANTLRWorks 1.4 进行测试） .2 也是如此）。

克里斯·法默写道：

此外，ANTLRworks 似乎建议输入诸如 ((((1 > 2) 且括号不匹配）的输入是合法的，...

不，ANTLRWorks 确实如此产生错误，也许不是很明显的错误。 ANTLRWorks 生成的解析树有一个 NoViableAltException 作为叶子，并且“Console”选项卡上有一些错误。