继续For循环

Question

我有以下代码：

For x = LBound(arr) To UBound(arr)
  
    sname = arr(x)  
    If InStr(sname, "Configuration item") Then  
        '**(here I want to go to next x in loop and not complete the code below)**  
    End If

    '// other code to copy past and do various stuff

Next x  

我以为我可以简单地使用语句 Then Next x，但这给出了“没有声明 for 语句”错误。

我可以在 If InStr(sname, "Configuration item") Then 之后放置什么以使其继续执行 x 的下一个值？

Answer 1

您可以使用 GoTo：

Do

    '... do stuff your loop will be doing

    ' skip to the end of the loop if necessary:
    If <condition-to-go-to-next-iteration> Then GoTo ContinueLoop 

    '... do other stuff if the condition is not met

ContinueLoop:
Loop

Answer 2

您正在考虑 continue 语句，例如 Java 的 或 Python的，但是VBA没有这样的原生语句，你不能使用VBA 的 Next 就是这样。

您可以使用 GoTo 语句来实现类似您想要做的事情，但实际上，GoTo 应该保留用于替代方案是人为且不切实际的情况。

对于只有一个“继续”条件的情况，有一个非常简单、干净且可读的替代方案：

    If Not InStr(sname, "Configuration item") Then
        '// other code to copy paste and do various stuff
    End If

Answer 3

For i=1 To 10
    Do 
        'Do everything in here and

        If I_Dont_Want_Finish_This_Loop Then
            Exit Do
        End If 

        'Of course, if I do want to finish it,
        'I put more stuff here, and then...

    Loop While False 'quit after one loop
Next i

Answer 4

很多年后......我喜欢这个：

For x = LBound(arr) To UBound(arr): Do

    sname = arr(x)  
    If instr(sname, "Configuration item") Then Exit Do 

    '// other code to copy past and do various stuff

Loop While False: Next x

Answer 5

晚了几年，但这里有另一种选择。

For x = LBound(arr) To UBound(arr)
    sname = arr(x)  
    If InStr(sname, "Configuration item") Then  
        'Do nothing here, which automatically go to the next iteration
    Else
        'Code to perform the required action
    End If
Next x

Answer 6

许多年后：DI 使用“select”语句作为一个简单的示例：

  For Each zThisRow In zRowRange
    zRowNum = zThisRow.Row
    Select Case zRowNum
      Case 1 '- Skip header row and any other rows to skip -----
             '- no need to put anything here -----

      Case Else '- Rows to process -----
             '- Process for stuff to do something here -----
    End Select
  Next zThisRow

您可以通过将每个“if”结果转换为一个值来使其变得像您希望的那样复杂（也许一些过于复杂的代码将有助于解释：D） :

zSkip = 0
If 'condition1 = skip' Then zSkip = zSkip + 1
If 'condition2 = skip' Then zSkip = zSkip + 1
If 'condition3 = skip' Then zSkip = zSkip + 1
Select Case zRowNum
  Case 0 '- Stuff to do -----
  Case Else '- Stuff to skip -----
End Select

这只是一个建议；祝圣诞快乐！

Answer 7

这也可以使用布尔值来解决。

For Each rngCol In rngAll.Columns
    doCol = False '<==== Resets to False at top of each column
    For Each cell In Selection
        If cell.row = 1 Then
            If thisColumnShouldBeProcessed Then doCol = True
        End If
        If doCol Then
            'Do what you want to do to each cell in this column
        End If
    Next cell
Next rngCol

例如，以下是完整示例：
(1) 识别工作表上使用的单元格范围
(2) 循环遍历每一列
(3) IF 列标题是可接受的标题，循环遍历列中的所有单元格

Sub HowToSkipForLoopIfConditionNotMet()
    Dim rngCol, rngAll, cell As Range, cnt As Long, doCol, cellValType As Boolean
    Set rngAll = Range("A1").CurrentRegion
    'MsgBox R.Address(0, 0), , "All data"
    cnt = 0
    For Each rngCol In rngAll.Columns
        rngCol.Select
        doCol = False
        For Each cell In Selection
            If cell.row = 1 Then
                If cell.Value = "AnAllowedColumnTitle" Then doCol = True
            End If
            If doCol Then '<============== THIS LINE ==========
                cnt = cnt + 1
                Debug.Print ("[" & cell.Value & "]" & " / " & cell.Address & " / " & cell.Column & " / " & cell.row)
                If cnt > 5 Then End '<=== NOT NEEDED. Just prevents too much demo output.
            End If
        Next cell
    Next rngCol
End Sub

注意：如果您没有立即抓住它，则 If docol Then 行是您的倒置 CONTINUE。也就是说，如果 doCol 保持为 False，则脚本将继续到下一个单元格并且不执行任何操作。

当然不如正确的 continue 或 next for 语句那么快/高效，但最终结果是我所能得到的最接近的结果。

Answer 8

您可以通过简单的方法来做到这一点，只需将 for 循环中使用的变量值更改为最终值，如示例所示

Sub TEST_ONLY()
    For i = 1 To 10
        ActiveSheet.Cells(i, 1).Value = i
        If i = 5 Then
            i = 10
        End If
    Next i
End Sub

Answer 9

抱歉迟到了，但在我看来，使用 GOTO 是最易读、最明显的事情。您编写的代码可能需要由经验比您少得多的人来维护。哎呀，我曾经写过如此多的 VBA 代码（在 CS 和 IT 还很流行之前），我什至无法意识到我是其中一些代码的编写者。不过，感谢 25 年后的智力锻炼，谢谢！

Answer 10

我有时会做一个双 do 循环：

Do

    Do

        If I_Don't_Want_to_Finish_This_Loop Then Exit Do

        Exit Do

    Loop

Loop Until Done

这可以避免出现“goto spaghetti”