tcl lsearch 在列表列表中

Question

Tcl中有一个list列表。

set somelist {{aaa 1} {bbb 2} {ccc 1}}

如何搜索列表中第一项是“bbb”的元素？

我尝试了这种方法，但它不起作用。

lsearch $somelist "{bbb *}"

谢谢。

Answer 1

使用-index，它正是针对这种情况而设计的。正如拉曼曼指出的那样，当你有一个列表时，请使用列表过程。你有没有想过如果你有多个匹配会发生什么？

在你的情况下，我会这样做：

% lsearch -index 0 -all -inline $somelist bbb
{bbb 2}
% lsearch -index 0 -all $somelist "bbb"
1
% lsearch -index 0 -all $somelist "ccc"
2

你使用 0 的 -index 来指定你对外部列表的第一个索引感兴趣。 -all 返回所有结果。如果你只想要匹配的列表元素的值，你可以使用 -inline ，如果你只想要匹配元素的索引，则省略它。

Answer 2

如果您要搜索每个列表成员的第一个子列表，则 -index 选项适合您：

set pos [lsearch -index 0 -exact $somelist "bbb"]

-index 0 选项告诉 lsearch 比较引擎在执行任何其他比较操作之前获取每个项目的第一个元素（即，非常类似于 lindex $item 0）（在我的示例中为 -exact 比较） 。您甚至可以提供一个索引列表来深入到特定的子子列表等。

（注意：lsearch 不做的事情不要做的是通过列表的所有子列表执行递归搜索，问题是正式无法知道何时到达叶子。）

---

编辑：< br>
如果您使用旧版本的 Tcl，则可能没有 -index 选项。在这种情况下，您可以使用手动迭代：（

proc findElement {lst idx value} {
    set i 0
    foreach sublist $lst {
        if {[string equal [lindex $sublist $idx] $value]} {
            return $i
        }
        incr i
    }
    return -1
}
set pos [findElement $somelist 0 "bbb"]

我不喜欢对此类事情使用全局匹配。当您查找不是列表中第一个或最后一个的元素时，它也不能很好地工作.)

Answer 3

在 Tcl 8.5 中，但不在 Tcl 8.4 中：

set somelist {{aaa 1} {bbb 2} {ccc 1}}
lsearch -index 0 $somelist bbb; # Returns either the index if found, or -1 if not

-index 标志指定要搜索的子列表的索引： 0 搜索 aaa、bbb... 而 1 搜索 1、2、1...

在 Tcl 8.4 中，使用 Tclx 包中的 keylget 命令：

package require Tclx

set somelist {{aaa 1} {bbb 2} {ccc 1}}
set searchTerm "bbb"
if {[keylget somelist $searchTerm myvar]} {
    puts "Found instance of $searchTerm, value is: $myvar"
}

此语法中的 keylget 命令如果找到则返回 1，如果没有则返回 0。然后将 bbb (2) 旁边的值放入变量 myvar 中。请注意，keylget 命令中 somelist 前面不应有美元符号 ($)。

更新

事实上，-index 标志允许搜索任意深度，如以下代码所示：

package require Tcl 8.5 

# For each sub-list:
# - index 0 = the user's name
# - index 1 = a list of {home value}
# - index 2 = a list of {id value}
# - index 3 = a list of {shell value}
set users {
    {john {home /users/john} {id 501} {shell bash}}
    {alex {home /users/alex} {id 502} {shell csh}}
    {neil {home /users/neil} {id 503} {shell zsh}}
}   

# Search for user name == neil
set term neil
puts "Search for name=$term returns: [lsearch -index 0 $users $term]"; # 2

# Search for user with id = 502. That means we first looks at index
# 2 for {id value}, then index 1 for the value
set term 502
puts "Search for id=$term returns: [lsearch -index {2 1} $users $term]"; # 1

# Search for shell == sh (should return -1, not found)
set term sh
puts "Search for shell=$term returns: [lsearch -index {3 1} $users $term]"; # -1

Answer 4

使用 [lsearch] 的“-index”选项。

Answer 5

如果你想按照你想要的方式搜索它，你可以使用 glob 选项：

lsearch -glob $somelist "{bbb *}"

你这些确实是列表列表，并且你正在寻找与 bbb 的第一个元素匹配的第一个子列表，你也可以这样做：

foreach sublist $somelist {   
  foreach {name value} $sublist {
    if {[string eq $name "bbb"]} {
      #do interesting stuff here
    }
  }
}

如果 当然，其详细信息取决于列表列表的详细信息（如果您的嵌套列表实际上只有两个元素，或者它是否可以嵌套得更深）。