如何整合 isearch 模式中发生的任何事情

发布于 2024-11-04 20:50:06 字数 999 浏览 1 评论 0原文

我非常喜欢 anything.el 。一切 UI 都很棒。

我也经常使用 isearch，它提供了键绑定 Ms o 以使用 isearch 输入字符串调用 occurr 。但本机发生模式还不够强大。

在occurr-mode中，您无法再次过滤结果。跳跃功能也是基本的。

我发现 anything-occur 比 < code>occurr，你可以过滤结果，以任何方式跳转一个位置。

但有一个问题，如何集成anything-occurr？我的最后一次尝试是：

(defun occur-in-isearch ()
  (interactive)
  (let ((case-fold-search isearch-case-fold-search))
    (occur (if isearch-regexp isearch-string (regexp-quote isearch-string)))))

我用 anything-occurr 替换 occurr，但没有用。 anything-occurr 是一个不带参数的 defun。我无法将 isearch 字符串传递给 anything-occurr。

我如何集成anything-occurr？或者是否有更好的方法在isearch-mode 中使用anything-occurr？

原文

I like anything.el a lot. The anything UI is wonderful.

I also use isearch very often, and it provides the keybinding M-s o to invoke occur using the isearch input string. But native occur mode is not powerful enough.

In occur-mode you cannot filter result again. And jumping function is basic too.

I find anything-occur is more powerful than occur, you can filter result, jump a position in anything style.

But there is a problem , How to integrate anything-occur? My last attempt is:

(defun occur-in-isearch ()
  (interactive)
  (let ((case-fold-search isearch-case-fold-search))
    (occur (if isearch-regexp isearch-string (regexp-quote isearch-string)))))

I replace occur with anything-occur, but it is no use. anything-occur is a defun which takes no parameters. I cannot pass the isearch string to anything-occur.

How might I integrate anything-occur? Or is there a better way to use anything-occur within isearch-mode?

分享到QQ

分享到微博

如果你对这篇内容有疑问，欢迎到本站社区发帖提问参与讨论，获取更多帮助，或者扫码二维码加入 Web 技术交流群。

发布评论

需要登录才能够评论，你可以免费注册一个本站的账号。

孤城病女 2024-11-11 20:50:06

我不是任何东西的用户，但是这段代码可以完成你想要的 99% 的事情。唯一需要注意的是，当您键入 backspace 时，初始输入字符串不会正确更新。我不知道为什么会这样。其他一切似乎都按预期工作。

(eval-after-load "isearch"
  '(define-key isearch-mode-map (kbd "M-s o") 'isearch-anything-occur))

(defun isearch-anything-occur (regexp &optional nlines)
  "isearch anything occur"
  (interactive
   ;; from isearch-occur
   (list
    (cond
     (isearch-word (concat "\\b" (replace-regexp-in-string
                                  "\\W+" "\\W+"
                                  (replace-regexp-in-string
                                   "^\\W+\\|\\W+$" "" isearch-string)
                                  nil t)
                           "\\b"))
     (isearch-regexp isearch-string)
     (t (regexp-quote isearch-string)))
    (if current-prefix-arg (prefix-numeric-value current-prefix-arg))))
  ;; from occur-anything
  (let ((anything-compile-source-functions
         ;; rule out anything-match-plugin because the input is one regexp.
         (delq 'anything-compile-source--match-plugin
               (copy-sequence anything-compile-source-functions))))
    (anything :sources 'anything-c-source-occur
              :input regexp
              :buffer "*Anything Occur*")))

I'm not a user of anything, but this code does 99% of what you want. The only caveat is that the initial input string doesn't get properly updated when you type backspace. I don't know why that is. Everything else works seems to work as expected.

(eval-after-load "isearch"
  '(define-key isearch-mode-map (kbd "M-s o") 'isearch-anything-occur))

(defun isearch-anything-occur (regexp &optional nlines)
  "isearch anything occur"
  (interactive
   ;; from isearch-occur
   (list
    (cond
     (isearch-word (concat "\\b" (replace-regexp-in-string
                                  "\\W+" "\\W+"
                                  (replace-regexp-in-string
                                   "^\\W+\\|\\W+$" "" isearch-string)
                                  nil t)
                           "\\b"))
     (isearch-regexp isearch-string)
     (t (regexp-quote isearch-string)))
    (if current-prefix-arg (prefix-numeric-value current-prefix-arg))))
  ;; from occur-anything
  (let ((anything-compile-source-functions
         ;; rule out anything-match-plugin because the input is one regexp.
         (delq 'anything-compile-source--match-plugin
               (copy-sequence anything-compile-source-functions))))
    (anything :sources 'anything-c-source-occur
              :input regexp
              :buffer "*Anything Occur*")))

回复收藏 0 原文