Delphi TPair 异常

Question

我有这个尖峰来测试 TPair。您可以在新的 Delphi XE Con​​sole 应用程序上复制+粘贴。我已经标记了该行，但有例外：

项目 Project1.exe 引发异常 带有消息的 EAccessViolation 类 '地址 0045042D 处发生访问冲突 在模块“Project1.exe”中。读过 地址A9032D0C。

有什么想法吗？

谢谢。

program Project1;

{$APPTYPE CONSOLE}

uses
  SysUtils,
  Generics.Defaults,
  Generics.Collections;

type
  TProduct = class
  private
    FName: string;
    procedure SetName(const Value: string);
  published
  public
    property Name: string read FName write SetName;
  end;

type
  TListOfProducts = TObjectDictionary<TProduct, Integer>;

{ TProduct }

procedure TProduct.SetName(const Value: string);
begin
  FName := Value;
end;


var
  MyDict: TListOfProducts;
  MyProduct1: TProduct;
  MyProduct2: TProduct;
  MyProduct3: TProduct;
  APair: TPair<TProduct, Integer>;
  aKey: string;

begin
  try
    MyDict := TListOfProducts.Create([doOwnsKeys]);
    MyProduct1 := TProduct.Create;
    MyProduct1.Name := 'P1';
    MyProduct2 := TProduct.Create;
    MyProduct2.Name := 'P2';
    MyProduct3 := TProduct.Create;
    MyProduct3.Name := 'P3';

    MyDict.Add(MyProduct1, 1);
    MyDict.Add(MyProduct2, 2);
    MyDict.Add(MyProduct3, 3);

    APair := MyDict.ExtractPair(MyProduct1);
    Writeln(APair.Key.Name);   // <--- Error is Here.
    Writeln(IntToStr(APair.Value));

    Readln(aKey);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Answer 1

这是一个 Delphi 错误。 TDictionary.ExtractPair 不会分配 Result。

RRUZ 找到了QC 中的错误。

代码如下：

function TDictionary<TKey,TValue>.ExtractPair(const Key: TKey): TPair<TKey,TValue>;
var
  hc, index: Integer;
begin
  hc := Hash(Key);
  index := GetBucketIndex(Key, hc);
  if index < 0 then
    Exit(TPair<TKey,TValue>.Create(Key, Default(TValue)));

  DoRemove(Key, hc, cnExtracted);
end;

在调用 DoRemove 时，应分配 Result。

解决这个错误非常困难。 ExtractPair 是在不破坏密钥的情况下从字典中获取项目的唯一方法，因此您必须调用它。但由于它不会返回提取的项目，因此您需要首先读取该项目，记住该值，然后调用 ExtractPair。