如何检查xsl中的字符串长度，如果未达到目标长度则需要替换为空格

Question

hii every body

<Table>
    <COSTUMER_NAME>praveen</COSTUMER_NAME>
</Table>

praveen（字符串长度）= 7

我们不知道 COSTUMER_NAME 的字符串长度，有时它可能小于 35 或者它恰好是 35

如果字符串长度小于 35 那么我们需要替换为空格而不是剩余的字符串长度部分

输出：如果我收到的字符串为 praveen

字符串长度为“7”

因此剩余的 28 个字符应替换为空格

Answer 1

我认为应该这样做：

<xsl:template match="/">
    <xsl:variable name="CUSTOMER_NAME">thestring</xsl:variable>
    <xsl:value-of 
         select="substring(
                    concat(
                       $CUSTOMER_NAME,
                       '                                   '
                    ),
                    1,
                    35
                 )"/>
</xsl:template>

有 35 个空白字符作为 concat 函数的参数。因此，它将字符串和 35 个空格字符连接起来，然后从中取出前 35 个字符的子字符串，因此多余的空格会丢失

Answer 2

XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:my="my:my" >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  '<xsl:sequence select=
   "my:pad(/*/*, 35, ' ')"/>'
 </xsl:template>

 <xsl:function name="my:pad" as="xs:string">
  <xsl:param name="pString" as="xs:string"/>
  <xsl:param name="pLength" as="xs:integer"/>
  <xsl:param name="pPadChar" as="xs:string"/>

  <xsl:sequence select=
   "concat($pString,
           string-join(
                   for $i in 1 to $pLength - string-length($pString)
                    return $pPadChar
                    ,
                    ''
                    )
           )
   "/>
 </xsl:function>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<Table>
    <COSTUMER_NAME>praveen</COSTUMER_NAME>
</Table>

生成所需结果：

  'praveen                            '

请注意：

1. <使用 p>，这确保了完全的可重用性。

2. 完全参数化为我们提供了最通用、最适用、最可复用的解决方案。

3. 这样的函数几乎可以用同样的方式定义，在 XQuery 中或者作为纯 XPath 3.0 中的函数项。