GORM 中的树结构（grails）

Question

我正在尝试在 GORM 中定义树结构。这是我的模型：

class Tree {
    String name
    Level rootLevel

    static hasOne = [rootLevel: Level]
    static hasMany = [levels: Level]
    static mappedBy = [levels:"parentTree"]
}

class Level {
    String name
    Tree parentTree
    Level parentLevel
    Set<Level> subLevels

    static belongsTo = [parentTree: Tree]
    static hasMany = [subLevels: Level]
}

插入似乎工作正常，但是当我无法加载具有许多级别和子级别的树时。 我想我错过了关系中的一些东西： - 树应该有一个对 rootLevel 的引用（以及可选的所有子级别） - 一个关卡应该有一个对其父关卡、子关卡和全局父树的引用，

你能指出我获得这样的树结构的正确方向吗？ 谢谢

Answer 1

我不喜欢你的树结构，所以我创建了自己的:)

Class TreeNode {
    String name
    TreeNode parent

    static hasMany = [children: TreeNode]

    //returns the root node, and by extension, the entire tree!
    TreeNode getRootNode(){
       if(parent){
          //if parent is not null then by definition this node is a child node of the tree.
          return parent.getRootNode()
       }else{
          //if parent is null then by definition it is the root node.
          return this
       }
    }

    //you might not need this function, but ill add it as it is common in tree structures
    boolean isLeaf(){
       //determines if this node is a leaf node. a leaf is a node with zero childrens
       return children.isEmpty()
    }
}

至于确保加载所有树节点，你总是可以对每个树节点（父节点和子节点）使用急切/非延迟获取。但是，如果您的树结构非常大，则可能会造成性能损失......

至于急切/惰性获取。看一下这里： ​​在 Grails / Gorm 中使用惰性属性获取< /a>

Answer 2

问题是级别填充了父树 id，但是当您加载树时，级别类会出现以下错误“找到具有给定标识符的多于一行”。

您的问题似乎是每棵树都有多个根节点。这是一种不寻常的方法。要使其正常工作，您必须将实体 Tree 中的 Level rootLevel 替换为 Set根。

Answer 3

我最终得到了这个解决方案（感谢一位朋友）：

class Tree {
   String name
   Level rootLevel

   static hasMany = [levels: Level]
   static mappedBy = [rootLevel: "parentTree", levels: "owningTree"]

   static constraints = {rootLevel(nullable: true)}
}

并且

class Level {
   String name
   Tree parentTree
   Tree owningTree
   Level parentLevel
   Set<Level> subLevels

   static belongsTo = [owningTree: Tree, parentLevel: Level]
   static hasMany = [subLevels: Level]
   static mappedBy = [parentTree: "rootLevel", owningTree: "levels", subLevels: "parentLevel"]

   static constraints = {
       parentTree(nullable: true)
       parentLevel(nullable: true)
   }
}

我缺少树和级别（owningTree和parentTree）之间的两种关系以及一些有助于休眠的mappedBy配置。