在 MacOS X 上的 GHCi 中工作的 Haskell 图形库

Question

是否存在满足以下要求的 Haskell 图形库或绑定到外部库：

1. 可以从 ghci 使用，即我不必链接并重新启动程序。
2. 适用于 MacOS X。（与 1 结合使用很棘手！）
3. 可以制作简单的矢量图形（线条、多边形、简单的填充和描边）。
4. 可以将位图图像放在屏幕上。示例：blit 17x12 .bmp 图像。

？

请包含一个最小的源代码示例或对其的引用（只是屏幕上的一个窗口，可能在里面画了一条绿线），以便我可以特别检查第 1 点和第 2 点。另外，如果这些功能请求之一更详细（例如 OpenGL + 4），请提供一份很好的参考。

PS：关于1和2，我知道enableGUI技巧并且我愿意使用它。但是，大多数库都存在无法多次运行 main 函数的问题，因此不符合资格。

编辑：为了避免浪费您的时间，这里列出了我尝试过的软件包：

• wx - ghci 在 libstdc++ 上被阻塞
• sdl - 重新定义main 是一个宏。仅编译时。
• GLFW (OpenGL) - 无法运行 main 两次，关于“失败，因为它无法安装鼠标事件处理程序”。

Answer 1

您是否看到过引用的 GLFW http://plucky.cs.yale.edu/soe/软件1.htm

Answer 2

有关 Haskell+GUI+OpenGL 的更多信息可在此讨论中找到：
http://www.haskell.org/pipermail/haskell-cafe /2011年5月/091991.html

Answer 3

编辑：实际上，我不再确定。几个版本之后，GLFW 似乎不再适用于 OS X 上的 GHCi。

事实证明，GLFW+OpenGL 满足了所有四个要求！

1. 您需要使用 ghci -framework Carbon 调用 ghci。
2. 您需要 EnableGUI.hs 文件，您可以通过 此处。请注意，您无法将其直接加载到 GHCi 中，您必须首先对其进行编译。
3. OpenGL 有一个 2D 投影模式，您可以在其中绘制直线和多边形。
4. 位图可以作为纹理加载并放置在多边形上。

这是一个将位图放到屏幕上的小示例。位图有一些限制：其尺寸必须是 2 的幂（此处为 256）并且必须是 .tga 文件（此处为 "Bitmap.tga"） 。但由于支持透明度，所以这不是什么大问题。

您应该能够毫无问题地多次调用 main 。关键点是您不应该调用GLFW.terminate。

import Graphics.Rendering.OpenGL as GL
import qualified Graphics.UI.GLFW as GLFW
import Graphics.Rendering.OpenGL (($=))

import Control.Monad
import EnableGUI

main = do
    enableGUI
    GLFW.initialize
    -- open window
    GLFW.openWindow (GL.Size 400 400) [GLFW.DisplayAlphaBits 8] GLFW.Window
    GLFW.windowTitle $= "Bitmap Test"

    -- enable alpha channel
    GL.blend         $= GL.Enabled
    GL.blendFunc     $= (GL.SrcAlpha, GL.OneMinusSrcAlpha)
    -- set the color to clear background
    GL.clearColor    $= GL.Color4 0.8 0.8 0.8 0

    -- set 2D orthogonal view inside windowSizeCallback because
    -- any change to the Window size should result in different
    -- OpenGL Viewport.
    GLFW.windowSizeCallback $= \ size@(GL.Size w h) ->
      do
        GL.viewport   $= (GL.Position 0 0, size)
        GL.matrixMode $= GL.Projection
        GL.loadIdentity
        GL.ortho2D 0 (realToFrac w) (realToFrac h) 0

    render <- initialize
    loop render

    GLFW.closeWindow

loop render = do
    -- draw the entire screen
    render
    -- swap buffer
    GLFW.swapBuffers
    -- check whether ESC is pressed for termination
    p <- GLFW.getKey GLFW.ESC
    unless (p == GLFW.Press) $ do
        -- sleep for 1ms to yield CPU to other applications
        GLFW.sleep 0.001
        -- only continue when the window is not closed
        windowOpenStatus <- GLFW.getParam GLFW.Opened
        unless (windowOpenStatus == False) $
            loop render

-- rendering
initialize = do
    -- load texture from file
    GL.texture GL.Texture2D $= Enabled
    [textureName] <- GL.genObjectNames 1
    GL.textureBinding GL.Texture2D $= Just textureName
    GL.textureFilter  GL.Texture2D $= ((GL.Nearest, Nothing), GL.Nearest)
    GLFW.loadTexture2D "Bitmap.tga" []

    return $ do
        GL.clear [GL.ColorBuffer]
        GL.renderPrimitive GL.Quads $ do
            GL.texCoord $ texCoord2 0 0
            GL.vertex   $ vertex3 (0) 256 0
            GL.texCoord $ texCoord2 0 1
            GL.vertex   $ vertex3 (0) (0) 0
            GL.texCoord $ texCoord2 1 1
            GL.vertex   $ vertex3 256 (0) 0
            GL.texCoord $ texCoord2 1 0
            GL.vertex   $ vertex3 256 256 0

-- type signatures to avoid ambiguity
vertex3 :: GLfloat -> GLfloat -> GLfloat -> GL.Vertex3 GLfloat
vertex3 = GL.Vertex3

texCoord2 :: GLfloat -> GLfloat -> GL.TexCoord2 GLfloat
texCoord2 = GL.TexCoord2

color3 :: GLfloat -> GLfloat -> GLfloat -> GL.Color3 GLfloat
color3 = GL.Color3

这是一个示例位图（您需要将其转换为 .tga）。

Answer 4

如果您使用 X11 版本的 gtk2 框架，Gtk2Hs 库可以满足所有要求。

关于要求：

1. 使用X11可以避免很多问题。
2. 通过 MacPorts 安装 gtk2 并使用 +x11 选项（默认）。 （也就是说，我过去在安装 gtk2 时遇到了很多问题，但这一次似乎有效。）
3. 如果 GTK+ 不能做到这一点，我会感到惊讶。
4. 同上。

这是一个最小的例子

import Graphics.UI.Gtk

hello :: (ButtonClass o) => o -> IO ()
hello b = set b [buttonLabel := "Hello World"]

main :: IO ()
main = do
    initGUI
    window <- windowNew
    button <- buttonNew
    set window [windowDefaultWidth := 200, windowDefaultHeight := 200,
              containerChild := button, containerBorderWidth := 10]
    onClicked button (hello button)
    onDestroy window mainQuit
    widgetShowAll window
    mainGUI

Answer 5

截至 2014 年初，我无法在 Mac OS X 中使用 @heinrich-apfelmus 答案。这个 GLFW-b 示例 (链接）但是有效。

因此，请确保您拥有：

$ cabal install glfw-b

并且，如果您尝试了 Apfelmus 的答案，您可能需要

$ ghc-pkg list
$ ghc-pkg unregister GLFW-x.x.x.x

提供 Graphics.UI.GLFW，并且您将得到一个“不明确的模块名称 'Graphics.UI.GLFW” ’”来自 ghc。然后我尝试了上面的示例程序并且它有效（Mac OS X，10.9，Mavericks）