如何用VBA删除Word中的单元格内容？

Question

我查看了 VBA 中表格单元格对象和选择对象的文档，但没有看到任何方法可以在保留单元格本身的同时删除 Word 中的单元格内容。看起来在 Excel 中这样做很容易，但在 Word 中几乎不可能。

我需要执行此操作的某些单元格将包含文本，其他单元格将包含文本表单字段。有什么想法吗？

Answer 1

这是有效的：

ActiveDocument.Tables(1).Cell(1, 2).Select
Selection.Delete

这会删除单元格内容，但留下空单元格。

操作不一样

ActiveDocument.Tables(1).Cell(1, 2).Delete

我理解您的沮丧，因为奇怪的是，上面的操作与删除整个单元格的

！前者相当于选择一个单元格并按Delete键（这会清除内容但将单元格保留在原位）。后者相当于右键单击单元格并选择“删除单元格...”（这将删除单元格）。

Answer 2

很抱歉挖掘出这样一个老问题，但希望有人会发现这很有用。如果您希望避免使用 Select 方法，那么您需要的是以下内容：

ActiveDocument.Tables(1).Cell(1, 1).Range.Text = ""

它还会删除图像和内容控件。

Answer 3

我从互联网的各个部分拼凑了这个......包括 VBA Express 的 Fumei。运作良好。选择表格中的任何单元格并运行宏 deleteTableCells

Sub deleteTableCells()
Dim selectedRange As Range

On Error GoTo Errorhandler
Set selectedRange = SelectionInfo

selectedRange.Delete

Errorhandler:
Exit Sub
End Sub

Function SelectionInfo() As Range
     '
    Dim iSelectionRowEnd As Integer
    Dim iSelectionRowStart As Integer
    Dim iSelectionColumnEnd As Integer
    Dim iSelectionColumnStart As Integer
    Dim lngStart As Long
    Dim lngEnd As Long
     
     ' Check if Selection IS in a table
     ' if not, exit Sub after message
    If Selection.Information(wdWithInTable) = False Then
        Err.Raise (2022)
    Else
        lngStart = Selection.Range.Start
        lngEnd = Selection.Range.End
         
         ' get the numbers for the END of the selection range
        iSelectionRowEnd = Selection.Information(wdEndOfRangeRowNumber)
        iSelectionColumnEnd = Selection.Information(wdEndOfRangeColumnNumber)
         
         ' collapse the selection range
        Selection.Collapse Direction:=wdCollapseStart
         
         ' get the numbers for the END of the selection range
         ' now of course the START of the previous selection
        iSelectionRowStart = Selection.Information(wdEndOfRangeRowNumber)
        iSelectionColumnStart = Selection.Information(wdEndOfRangeColumnNumber)
         
         ' RESELECT the same range
        Selection.MoveEnd Unit:=wdCharacter, Count:=lngEnd - lngStart
         
         ' set the range of cells for consumption
        With ActiveDocument
            Set SelectionInfo = .Range(Start:=.Tables(1).cell(iSelectionRowStart, iSelectionColumnStart).Range.Start, _
                            End:=.Tables(1).cell(iSelectionRowEnd, iSelectionColumnEnd).Range.End)
        
        End With
    End If
End Function

Answer 4

Private Sub cbClearTable_Click()  
'mouse cursor must be in the table for clearing  
Dim cell_BhBp As Cell  
For Each cell_BhBp In Selection.Tables(1).Range.Cells  
cell_BhBp.Range = ""  
Next  
End Sub

上面的代码清除当前表格/鼠标光标所在的表格中的所有单元格中的内容

另一种清除文档中第一个表格的所有表格单元格的方法是

ActiveDocument.Tables(1).Range.Delete

或者对于当前表格/光标所在的位置/

Selection.Tables(1).Range.Delete

    Private Sub CommandButton40_Click()
    Application.Activate
    SendKeys ("{DEL}")
    End Sub

代码上面清除了所有选定单元格的内容。在这种情况下，所选单元格可能不相邻。单击用户表单的按钮时会触发此代码。