如何从 Haskell 中的字符串列表中获取搜索匹配项？

Question

如何从 Haskell 中的字符串列表中获取搜索匹配项？

module Main
    where
import List
import IO
import Monad

getLines = liftM lines . readFile

main = do
    putStrLn "Please enter your name: "
    name <- getLine
    list <- getLines "list.txt"
   -- mapM_ putStrLn list -- this part is to list out the input of lists 

Answer 1

首先要做的事情，也是最重要的首要原则，是尽可能多地从 main 或 IO 中获取思想。 main 应尽可能包含所有 IO，也许除了用您在模块中其他地方定义的纯术语装饰的 IO 之外什么也不包含。您的 getLines 不必要地混合了它们。

因此，为了解决这个问题，我们应该有一个类似的 main

main = 
   do putStrLn "What is your name?"
      name <- getContents
      names <- readFile "names.txt"
      putStrLn (frankJ name names)

，或者可能是 IO 与我们获得的所有其他内容的更严格的隔离：

main = 
   do putStrLn greeting
      name <- getContents
      names <- readFile nameFile
      putStrLn (frankJ name names) 

与“纯”术语一起：

greeting, nameFile :: String
greeting = "What is your name?"
nameFile = "names.txt"

无论哪种方式，我们现在都真正进入了 Haskell 领域：现在的问题是弄清楚纯函数：

 frankJ :: String -> String -> String

应该是什么。

我们可以从一个简单的匹配函数开始：当第一个字符串出现在字符串列表中时，我们得到一个匹配：

 match :: String -> [String] -> Bool
 match name namelist = name `elem` namelist  
 -- pretty clever, that!

或者我们可能想要规范化一点，以便我们给出的名称的开头和结尾处有空格，并且列表中的名称不会影响匹配。这是一种相当简陋的方法：

 clean :: String -> String
 clean =  reverse . omitSpaces . reverse . omitSpaces
   where omitSpaces = dropWhile (== ' ')

然后我们可以改进旧的 match，即 elem：

 matchClean :: String -> [String] -> Bool
 matchClean name namelist = match (clean name) (map clean namelist)

现在我们需要遵循类型，弄清楚如何适应类型比如说 matchClean:: String -> [字符串] -> Bool 与 frankJ :: String ->字符串 ->字符串。我们希望将其放入 frankJ 的定义中。

因此，为了为 matchClean '提供输入'，我们需要一个函数来将我们从带有换行符的长字符串带到 matchClean 需要的字符串（名称）列表：这就是 Prelude 函数 lines。

但我们还需要决定如何处理 matchClean 生成的 Bool 作为值；正如我们所知，frankJ 返回一个String。让我们继续简单地分解问题：

response :: Bool -> String
response False = "We're sorry, your name does not appear on the list, please leave."
response True = "Hey, you're on the A-list, welcome!"

现在我们有了可以组合成函数 frankJ :: String ->; 的合理候选者的材料。字符串 ->我们要输入到 main 中定义的 IO 机器的字符串：

frankJ name nametext = response (matchClean name (lines nametext))

-- or maybe the fancier:  
-- frankJ name = response . matchClean name . lines
-- given a name, this 
--     - pipes the nametext through the lines function, splitting it,
--     - decides whether the given name matches, and then 
--     - calculates the 'response' string

所以在这里，几乎所有事情都是纯函数的问题，很容易看出如何修正事物以进一步完善。例如，也许输入的名称和文本文件的行应该进一步规范化。在比较之前，内部空间应限制为一个空间。或者列表中的行中可能有一个逗号，因为人们被列为“姓氏，名字”等。或者也许我们希望响应函数使用该人的名字：

personalResponse :: String -> Bool -> String
personalResponse name False = name ++ " is a loser, as far as I can tell, get out!"
personalResponse name True  = "Ah, our old friend " ++ name ++ "! Welcome!"

连同

frankJpersonal name = personalResponse name . matchClean name . lines

当然有一百万种方法关于这个。例如，有regex库。 Hackage 中优秀且简单的 Data.List.Split 也可能有用，但我不确定它是否可以被 Hugs 使用，您可能正在使用 Hugs。

我注意到您对导入的模块使用旧式名称。我编写的内容仅使用 Prelude，因此不需要导入，但其他模块现在根据分层命名系统称为“System.IO”、“Data.List”和“Control.Monad”。我想知道您是否使用旧的教程或手册。也许令人愉快的“Learn You a Haskell”网站会更好？他确认他正在使用 ghc，但我认为这不会产生太大影响。

Answer 2

如果您不需要 list.txt 中包含该名称的所有行的列表，
您可以简单地使用

filter (isInfixOf name) list

，但我不确定我是否正确理解您的问题。