文件夹中新文件的打印请求

Question

我遇到以下问题：

我需要做一些检查以查看文件是否已添加到特定文件夹，如果是，则需要打印该文件。我听说 Windows 可能内置了类似的东西？

*Program constantly checks whether a file has been added*
File has been added 
File gets printed immediately

我已经找到了解决方案，但你需要付费。

更新

"Code supplied by Vik"
:start
set SECONDS=60
SET FILENAME=*.jpg
IF EXIST %FILENAME% MSPAINT /p %FILENAME%
choice /C a /T %SECONDS% /D a
DEL /Q %FILENAME%
goto :start
"Edits: COPY *.JPG file to a different folder (E.G. ImageHistory)"
"Edits: DELETE local *.JPG file leaving the monitor folder empty"

欢迎任何提示或帮助！

Answer 1

该批处理文件将每 60 秒检查一次 printme.jpg 文件是否存在。如果存在，它将使用内置的 MSPAINT 程序来打印它。请随意配置 SECONDS 和 FILENAME 以适合您的环境。

:start
set SECONDS=60
SET FILENAME=printme.jpg
IF EXIST %FILENAME% MSPAINT /p %FILENAME%
choice /C a /T %SECONDS% /D a
goto :start

您可能想要制作的其他模组：

1. 如果您使用的是旧版本的 Windows（例如 XP），您可能没有 CHOICE 命令。在这种情况下，使用 ping 模拟睡眠： PING 1.1.1.1 -n 1 -w 60000 >NUL
2. 您可以添加一行以在打印后删除文件： DEL /Q % FILENAME%

编辑（下）：添加多文件、移动和删除功能

set SECONDS=20
set FILEFOLDER=C:\dropfolder
set TEMPFOLDER=%FILEFOLDER%\TEMPFOLDER
set FILEWILDCARD=*.jpg

if not exist "%FILEFOLDER%" ECHO %FILEFOLDER% NOT FOUND ... CTRL-C TO EXIT && PAUSE
if not exist "%TEMPFOLDER%" ECHO %TEMPFOLDER% NOT FOUND ... CTRL-C TO EXIT && PAUSE

:start
cd "%FILEFOLDER%"
dir /b "%FILEWILDCARD%" > filelist.txt
for %%A in (filelist.txt) do if not %%~zA==0 goto printfiles
choice /C a /T %SECONDS% /D a
goto :start

:printfiles
echo FILE(s) FOUND!
del /q "%TEMPFOLDER%\%FILEWILDCARD%"
move "%FILEWILDCARD%" "%TEMPFOLDER%"
cd "%TEMPFOLDER%"
for %%A in ("%FILEWILDCARD%") do MSPAINT /p "%%A"
goto :start

Answer 2

在后台运行 VB.Net 并使用 FileSystemWatcher获取该文件夹中每个更改的事件。收到事件后，检查文件/操作并使用可以打印文件的任何应用程序打印文件。批处理文件在这里可能不起作用。