使用 XSLT 反转数据和属性

Question

使用 XSLT 我想将此 XML: 转换

<exchangeRates>
    <rate country="aud">0.97</rate>
</exchangeRates>

为此 XML:

<xchgRates>
    <entry xrate="0.97">aud</entry>
</xchgRates>

编辑：exchangeRates 需要变为 xchgRates。将 xRate 更改为 xrate 以匹配正确的解决方案。

感谢大家的帮助！

Answer 1

我还没有尝试过这个，但类似这样的东西应该有效：

<xsl:template match="exchangeRates/rate">
    <entry>
         <xsl:attribute name="xRate"><xsl:value-of select="." /></xsl:attribute>
         <xsl:value-of select="@country" />
    </entry>
</xsl:template>

Answer 2

完整而简短的解决方案：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>


 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="exchangeRates">
  <xchgRates>
   <xsl:apply-templates select="node()|@*"/>
  </xchgRates>
 </xsl:template>

 <xsl:template match="rate">
  <entry xrate="{.}">
   <xsl:value-of select="@country"/>
  </entry>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<exchangeRates>
    <rate country="aud">0.97</rate>
</exchangeRates>

生成所需的正确结果：

<xchgRates>
   <entry xrate="0.97">aud</entry>
</xchgRates>

解释：

1. 使用和覆盖身份规则/template

2. 使用 AVT (属性值模板）是推荐的，因为它需要更少的输入，并且可以生成更短、更易于理解和维护的代码。

除了少数例外（特别是 select 属性）之外，XSLT 指令的几乎所有属性都允许 AVT。