列表中的 Prolog 元素替换

Question

您好，我想知道您是否可以帮我解决这个问题

：从 Prolog 中编程：编写 Prolog 脚本，用另一个给定元素替换列表中的任何给定元素。例如：

replace( 3, a,[1,2,3,4,3,5], [1,2,a,4,a,5])=true

提前非常感谢

Answer 1

在Prolog中，大多数列表处理是通过处理头部然后递归处理列表的其余部分来完成的。当然，您不能忘记基本情况，它是一个空列表。

用空列表中的任何内容替换任何内容会再次产生空列表。如果列表头与要替换的元素相同，则替换它，否则，保持原样。在这两种情况下，都会递归处理列表的其余部分。从英文翻译成 Prolog：

replace(_, _, [], []).
replace(O, R, [O|T], [R|T2]) :- replace(O, R, T, T2).
replace(O, R, [H|T], [H|T2]) :- H \= O, replace(O, R, T, T2).

Answer 2

到目前为止，其他答案中提出的所有实现在与非基础术语一起使用时在逻辑上都是不合理的。考虑原始查询和一个轻微的变体：

?- replace(3,three,[1,2,3],Xs).
Xs = [1,2,three] ;                 % OK: correct
false

?- A=3, replace(A,B,[1,2,3],Xs).   % OK: correct
Xs = [1,2,B], A = 3 ;
false

它有效！让我们问一些非常相似的问题：

?- replace(A,B,[1,2,3],Xs).        % FAIL: should succeed more than once...
Xs = [B,2,3], A = 1 ;              %       ... but the other solutions are missing 
false

?- replace(A,B,[1,2,3],Xs), A=3.   % FAIL: this query _should_ succeed ...
false                              %       ... it does not!

---

发生了什么？将归咎于元逻辑内置函数 (!)/0 和 (\=)/2，它们很难正确使用，并且常常使代码变得脆弱、不纯粹且逻辑上不健全。

为了保持逻辑的健全性，坚持逻辑的纯粹性并尽可能避免使用元逻辑“特征”！幸运的是，大多数 Prolog 实现都支持 dif/2 作为 (\=)/2 的逻辑替代。让我们使用它：

% code by @svick, modified to use dif/2 instead of (\=)/2
replaceP(_, _, [], []).
replaceP(O, R, [O|T], [R|T2]) :- replaceP(O, R, T, T2).
replaceP(O, R, [H|T], [H|T2]) :- dif(H,O), replaceP(O, R, T, T2).

让我们再次运行上面的查询，这次使用改进的 replaceP/4：

?- replaceP(3,three,[1,2,3],Xs).
Xs = [1,2,three] ;                 % OK: correct, like before
false

?- replaceP(A,B,[1,2,3],Xs).       % OK: four solutions, not just one
Xs = [B,2,3], A = 1 ;         
Xs = [1,B,3], A = 2 ;
Xs = [1,2,B], A = 3 ;
Xs = [1,2,3], dif(A,1),dif(A,2),dif(A,3) ;
false

?- replaceP(A,B,[1,2,3],Xs), A=3.  % OK (succeeds now)
Xs = [1,2,B], A = 3 ;                 
false
?- A=3, replaceP(A,B,[1,2,3],Xs).  % OK (same as before)
Xs = [1,2,B], A = 3 ;
false

Answer 3

replace(_, _ , [], []).

replace(X, Y, [ X | Z ], [ Y | ZZ]):- ! , replace( X, Y, Z, ZZ).

replace(X, Y, [ W | Z], [ W | ZZ] :- replace(X, Y, Z, ZZ). 

不过，人们通常会将 3.arg 安排为第一个。严格来说，上面并没有替换列表中的任何内容，它只是回答第四个参数是否与第三个参数类似，但用 Y' 而不是 X'。

Answer 4

replace(E,S,[],[]).
replace(E,S,[E|T1],[S|T2]):-replace(E,S,T1,T2).
replace(E,S,[H|T1],[H|T2]):-E\=H, replace(E,S,T1,T2).

想法很简单，如果元素匹配，则更改它，如果不匹配，则继续，直到为空。

Answer 5

domains
I=integer*
K=integer*
Z=integer
A=integer
predicates
nondeterm  rep(I,Z,A,K)
clauses
rep([],_,_,[]).
rep([Z|T1],Z,A,[A|T2]):- rep(T1,Z,A,T2).
rep([H|T1],Z,A,[H|T2]) :- rep(T1,Z,A,T2).
goal
rep([1,2,3],2,4,X).