使用正则表达式将不同的文本插入另一个文本？

Question

我有两个文本文件。我想从 标记之间的第一个文本中获取文本，并将其插入到 {} 之间的另一个文本文件中。

更好的例子（比如字典）

Text1:

<sup>1</sup>dog
<sup>2</sup>cat
<sup>3</sup>lion
<sup>1</sup>flower
<sup>2</sup>tree
.
.

Text2:

\chapter1
\pkt{1}{}{labrador retirever is..}
\pkt{2}{}{home pets..}
\pkt{3}{}{wild cats..}
\chapter2
\pkt{1}{}{red rose}
\pkt{2}{}{lemon tree}
.
.

What I want:

Text3:

\chapter1
\pkt{1}{dog}{labrador retirever is..}
\pkt{2}{cat}{home pets..}
\pkt{3}{lion}{wild cats..}
\chapter2
\pkt{1}{flower}{red rose}
\pkt{2}{tree}{lemon tree}

文本是随机的，但你可以看到我想要的。 Perl 会是最好的。

因此，按顺序获取

</sup>**text**<sup>

并将其粘贴到

\pkt{nr}{**here**}{this is translation of this word already stored in text2}.

文本 A 和 B 中，因此，如果我可以从文本 A 中首先读取 text ，将其保存在 temp 中，请从文本中删除此行A，将其放在文本 B 中的第一个空闲 {} 插槽中，然后重新开始，那就太好了。数字将匹配，因为订单已保存。 对不起我的英语:) 谢谢！

Answer 1

此代码将所有字典项按照它们出现的顺序放入一个数组中。然后循环 tex 文件，每次点击 \pkt{num}{} 时都会插入数组中的一项。

字典中的换行符被处理并替换为空格（如果您不希望这种行为，只需在地图中删除此替换）。只要 \pkt{num}{} 部分不跨越多行，就应该找到 \pkt。否则，我认为最简单的解决方案是 undef $/ （输入记录分隔符）并将整个文件读入字符串中，然后循环替换（尽管可能有点占用内存）。

#!/usr/bin/perl -wT

use strict;

my $dict_filename = 'text1';
my $tex_filename = 'text2';
my $out_filename = 'text3';

open(DICT, $dict_filename);
my @dict;
{
    # Set newline separator to <sup>
    local $/ = '<sup>';
    # Throw away first "line", it will be empty
    <DICT>;
    # Extract string and throw away newlines
    @dict = map { $_ =~ m@</sup>\s*(.*?)\s*(?:<sup>|$)@s; $_ = $1; $_ =~ s/\n/ /g; $_; } <DICT>;
}
close(DICT);

open(TEX, $tex_filename);
open(OUT, ">$out_filename");

my $tex_line;
my $dict_pos = 0;
while($tex_line = <TEX>)
{
    # Replace any \pkt{num}{} with \pkt{num}{text}
    $tex_line =~ s|(\\pkt\{\d+\}\{)(\})|$1$dict[$dict_pos++]$2|g;

    print OUT $tex_line;
}

close(TEX);
close(OUT);