如何在 XSLT 中排除字段？

Question

我正在从表中获取信息：

<xsl:template match="table1">
  <xsl:element name="ApplicantAddress">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:element>
</xsl:template>

并且我想确保不包含该表中的字段。这可能吗？

Answer 1

推式：

<xsl:template match="table1">
   <ApplicantAddress>
     <xsl:apply-templates select="@* | node()[not(self::unwanted-element)]"/>
   </ApplicantAddress>
</xsl:template>

拉式：

<xsl:template match="table1">
   <ApplicantAddress>
     <xsl:apply-templates select="@* | node()"/>
   </ApplicantAddress>
</xsl:template>

<xsl:template match="table1/unwanted-element"/>

Answer 2

此转换：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
  <xsl:copy>
   <xsl:apply-templates select="node()|@*"/>
  </xsl:copy>
 </xsl:template>

 <xsl:template match="table1">
  <ApplicantAddress>
   <xsl:apply-templates select="node()|@*"/>
  </ApplicantAddress>
 </xsl:template>

 <xsl:template match="c"/>
</xsl:stylesheet>

应用于此 XML 文档时（您错过了提供）：

<table1>
 <a/>
 <b/>
 <c/>
 <d/>
</table1>

产生所需的结果（元素 b未复制）：

<ApplicantAddress>
  <a />
  <b />
  <d />
</ApplicantAddress>

解释：使用和覆盖身份规则/template是最基本的XSLT设计模式。在这里，我们使用匹配 c 的空主体模板覆盖身份规则，这确保了该元素被忽略（“删除”/不复制）。