可以使用 Delphi 在 W7 中禁用任务切换键盘快捷键吗？

Question

我的应用程序多年来一直有一种模式，客户可以“禁用对操作系统的访问”。显然，这个功能违背了原则（至少就 Windows 而言），但在某些安装中，我的应用程序是机器操作员应该可见的唯一程序，在这种情况下，这样的功能很有用。

我使用的技术是由几个“层”构建的：

1. 隐藏任务栏和按钮。
2. 禁用任务切换。
3. 禁用我的主窗体系统图标。

要禁用任务栏，我使用了：

// Get a handle to the taskbar and its button..
Taskbar := FindWindow('Shell_TrayWnd', Nil);
StartButton := FindWindow('Button', Nil);

// Hide the taskbar and button
if Taskbar <> 0 then
  ShowWindow( Taskbar, SW_HIDE );
if StartButton <> 0 then
  ShowWindow( StartButton, SW_HIDE );

// Set the work area to the whole screen
R := Rect( 0,0,Screen.Width,Screen.Height );
SystemParametersInfo(
  SPI_SETWORKAREA,
  0,
  @R,
  0 );

这效果很好，并且在 W7 上看起来仍然很好。 几年前研究如何禁用任务切换发现了“假装”您的应用程序是屏幕保护程序的唯一技术（除了将应用程序重命名为“explorer.exe”并启动到它等可怕的事情之外）：

procedure EnableTaskSwitching( AState : boolean );
// Enables / disables task switching
begin
  SystemParametersInfo(
    SPI_SCREENSAVERRUNNING,
    Cardinal( not AState),
    nil,
    0 );
end;

毫不奇怪这似乎在 W7 中没有效果（我认为它在 XP 等中有效）。 有谁知道另一种更好的方法来启用/禁用 Alt-Tab （和其他特殊的 Windows 键）工作？

Answer 1

如果找到解决方案：

function LowLevelKeyboardProc(nCode: integer; wParam: WPARAM; lParam: LPARAM):
  LRESULT; stdcall;
type
  PKBDLLHOOKSTRUCT = ^TKBDLLHOOKSTRUCT;
  TKBDLLHOOKSTRUCT = record
    vkCode: cardinal;
    scanCode: cardinal;
    flags: cardinal;
    time: cardinal;
    dwExtraInfo: Cardinal;
  end;

  PKeyboardLowLevelHookStruct = ^TKeyboardLowLevelHookStruct;
  TKeyboardLowLevelHookStruct = TKBDLLHOOKSTRUCT;
const
  LLKHF_ALTDOWN = $20;
var
  hs: PKeyboardLowLevelHookStruct;
  ctrlDown: boolean;
begin

  if nCode = HC_ACTION then
  begin

    hs := PKeyboardLowLevelHookStruct(lParam);
    ctrlDown := GetAsyncKeyState(VK_CONTROL) and $8000 <> 0;
    if (hs^.vkCode = VK_ESCAPE) and ctrlDown then
      Exit(1);
    if (hs^.vkCode = VK_TAB) and ((hs^.flags and LLKHF_ALTDOWN) <> 0) then
      Exit(1);
    if (hs^.vkCode = VK_ESCAPE) and ((hs^.flags and LLKHF_ALTDOWN) <> 0) then
      Exit(1);
    if (hs^.vkCode = VK_LWIN) or (hs^.vkCode = VK_RWIN) then
      Exit(1);

  end;

  result := CallNextHookEx(0, nCode, wParam, lParam);

end;

procedure TForm1.FormShow(Sender: TObject);
begin
  SetWindowsHookEx(WH_KEYBOARD_LL, @LowLevelKeyboardProc, 0, 0);
end;

这会禁用（如您所见！）

• Ctrl+Esc（显示开始菜单）
• Alt+Tab（任务切换）
• Alt+Esc（任务切换）
• Win（显示开始菜单）
• Win+Tab（3D 任务切换）
• Win+D、Win+M、Win+Space、Win+Arrows、Win+P、Win+U、Win+E、Win+F、Win+Digit...
• 几乎任何组合，包括 Windows 键（但不是全部） ，例如Win+L)

Answer 2

正如大卫所指出的，这称为“信息亭模式”。几篇好文章（第 1 部分 和 第 2 部分）可在 About.com 上找到。

Answer 3

有 Windows Embedded Standard 7您可以以具有真正的信息亭模式的方式进行打包。

Answer 4

dWinLock也提供了解决方案。 IIRC，他们安装了一个可以停止 Ctrl+Alt+Del 的服务。