从 plsql 过程读取 xml 时出错

Question

我正在尝试使用 xmlparser 包从 plsql 过程中读取 xml，但收到此错误

ORA-31020: The operation is not allowed, Reason: Not supported
ORA-06512: at "XDB.DBMS_XMLPARSER", line 395
ORA-06512: at "SYS.DOMSAMPLE", line 75
ORA-06512: at line 2

DOMSAMPLE 是我的过程名称，第 75 行没有语句，下一行包含 p := xmlparser.newParser。

有人可以帮我解决这个问题吗？或者建议一种在plsql中读取xml的简单方法。

Answer 1

您提供的关于您实际在做什么的细节很少，所以恐怕我只能猜测。

我无法重现您收到的错误消息，但我只尝试了一些操作。也许您错误地调用了 Oracle XML API？也许您尝试解析的 XML 文档有些奇怪？恐怕我不知道，因为您没有向我们提供您的 DOMSAMPLE 过程的源代码，也没有向我们提供您尝试解析的 XML 文档。

我不敢相信你的程序的第 75 行是一个空行。这是该过程的第 75 行，还是包含该过程的文件的第 75 行？

以下是使用 DBMS_XMLPARSER 和 DBMS_XMLDOM 的示例。它只是读出给定 XML 字符串的根元素的名称：

SET SERVEROUTPUT ON;

DECLARE
   p    dbms_xmlparser.parser;
   d    dbms_xmldom.domdocument;
   e    dbms_xmldom.domelement;
BEGIN
   p := dbms_xmlparser.newParser;
   dbms_xmlparser.parseBuffer(p, '<thisIsATest />');
   d := dbms_xmlparser.getDocument(p);
   e := dbms_xmldom.getDocumentElement(d);
   dbms_output.put_line('Tag name is ' || dbms_xmldom.getTagName(e));
END;
/

当我运行它时，它给出输出 Tag name is thisIsATest。

至于读取 XML 的更简单方法，我之前回答的问题中有一个。我不知道这是否会对你有帮助，因为我对你想要实现的目标知之甚少。

最后，请不要在 SYS 模式中创建对象。

编辑：在您的评论中，您提到您正在使用dbms_xmlparser.parse而不是dbms_xmlparser.parseBuffer。我尝试了 dbms_xmlparser.parse 并多次遇到相同的“无效资源句柄或路径名”错误，最后才找到有效的方法。以下是我设法完成的工作；很可能有比这更好的解决方案来满足您的需求。

在使用 Oracle 执行任何文件 I/O（包括使用 dbms_xmlparser.parse）之前，您必须首先创建一个 Oracle“目录”。 Oracle 中的目录对应于文件系统上的目录。请注意，这是运行 Oracle 数据库的计算机上的文件系统。如果 XML 文件不在同一文件系统上（例如，Oracle 数据库位于服务器上，而您的 XML 文件位于开发 PC 上），您将无法使用 dbms_xmlparser.parse，除非您首先将此文件传输到数据库服务器文件系统上的目录。

我将首先创建一个与我的文件系统上的目录相对应的 Oracle 目录：

SQL> create or replace directory ora_dir as '/home/luke/ora_dir';

Directory created.

我在这里使用 Linux。如果您使用的是 Windows，请随意反转斜杠的方向。

在继续之前，让我们快速浏览一下我们将读入的 XML 文件：

SQL> host cat /home/luke/ora_dir/example.xml
<?xml version="1.0" ?>
<root>
  <child />
</root>

在 SQL*Plus 中，host 将行的其余部分发送到 shell 或 cmd。 Windows 上的 exe。在 Windows 上，您还可以使用 type 而不是 cat。

最后，这是一个读取此 XML 文件的 PL/SQL 块：

SQL> set serveroutput on
SQL> DECLARE
  2     p    dbms_xmlparser.parser;
  3     d    dbms_xmldom.domdocument;
  4     e    dbms_xmldom.domelement;
  5  BEGIN
  6     p := dbms_xmlparser.newParser;
  7     dbms_xmlparser.setBaseDir(p, 'ORA_DIR');
  8     dbms_xmlparser.parse(p, 'example.xml');
  9     d := dbms_xmlparser.getDocument(p);
 10     e := dbms_xmldom.getDocumentElement(d);
 11     dbms_output.put_line('Tag name is ' || dbms_xmldom.getTagName(e));
 12  END;
 13  /
Tag name is root

PL/SQL procedure successfully completed.

SQL>

该块与上面的块之间的唯一区别是调用 dbms_xmlparser.parseBuffer 的行已替换为两行。这两行中的第一行调用dbms_xmlparser.setBaseDir来设置解析器的基目录，第二行使用相对于该目录的文件名调用dbms_xmlparser.parse。

编辑2：您的代码并没有像您希望的那样工作，并且您将其编辑到我的答案中，如下所示：

create or replace procedure printElements(doc xmldom.DOMDocument) is
nl xmldom.DOMNodeList;
len number;
n xmldom.DOMNode;
e xmldom.DOMElement;
nodeval varchar2(100);
begin
   -- get all elements
   nl := xmldom.getElementsByTagName(doc, '*');
   len := xmldom.getLength(nl);   
   -- loop through elements
   for i in 0..len-1 loop
      n := xmldom.item(nl, i);
      e := xmldom.makeElement(n => n);
      dbms_output.put(xmldom.getNodeName(n) || ' ');
      nodeval := xmldom.getNodeValue(n);
      -- here nodeval i am getting as null, what mistake am doing?
      dbms_output.put_line('  Value: '|| nodeval );

   end loop;

   dbms_output.put_line('');
end printElements;

这显然将所有值返回为空，正如三个评论中的最后一个。

引用我之前的回答类似的问题：

在 XML DOM 中，元素没有任何“值”可言。元素节点包含文本节点作为子节点，正是这些节点包含您想要的值。

因此，尝试将该行替换

      nodeval := xmldom.getNodeValue(n);

为

      nodeval := xmldom.getNodeValue(xmldom.getFirstChild(n));