通过数据步连接 SAS 变量

Question

我正在寻找一种方法来创建包含数据集某些值的字符串变量，同时执行数据步骤。

示例数据集 work.test：

AddToStringYN    Value
     Y           One
     Y           Two
     N           Three
     Y           Four
     N           Five

所以最终，变量将如下所示：OneTwoFour（或者更好的 FourTwoOne）。 这看起来很简单，但我似乎找不到办法。 我还尝试使用这样的宏变量：

%let stringvar=;
Data _null_;
  set work.test;
  if AddToStringYN = "Y" then do;
    call symput('stringvar',"&stringvar" || strip(value));
  end;
Run;

但这给出：

GLOBAL STRINGVAR Four

所以我只得到最后一个值。我知道这一定是因为我对这个宏设施的一些误解，但我不明白为什么变量中只有最后一个值。 我以为只有最后一次调用 symput 时它才实际执行或其他什么，但是当我将代码调整为：

%let stringvar=;
Data _null_;
  set work.test;
  if AddToStringYN = "Y" then do;
    call symput('stringvar'||strip(value),"&stringvar" || strip(value));
  end;
Run;

然后我确实得到了它们全部：

GLOBAL STRINGVARONE  One
GLOBAL STRINGVARTWO  Two
GLOBAL STRINGVARFOUR  Four

所以我最后的猜测是，通过数据步骤，' call symput...' 行实际上被添加到宏处理器中，其中“&stringvar”已被替换，并且只有在最终语句之后它们才会全部执行。
这是一个很好的假设还是有其他解释？ 回到最初的问题：有没有一种简单的方法可以实现这一点（拥有所需的变量）？

Answer 1

以下是我对 您在 RunSubmit.com 上的相同问题的回答。我认为你和@Fabio可能过度设计了解决方案，它根本不需要任何迭代数据步骤代码......

首先，做你想做的事情的简单方法是这样的：

proc sql;
  select Value into :StringVar separated by ''
    from work.test
    where AddToStringYN='Y'
    ;
quit;

在这里，你可以使用 select into 语法利用 SAS/MACRO 的 SQL 接口。您甚至可以添加 order by 子句来获取您要查找的特定订单。

其次，由于您已经了解了 SAS 宏的工作方式，并且您很想了解它：在第一个示例中，编译器在执行代码之前所做的第一件事是解析 & 的值。 stringvar，此时它是空的。因此，编译后，替换此标记后，您的代码在 SAS 中看起来像这样...

%let stringvar=;
Data _null_;
  set work.test;
  if AddToStringYN = "Y" then do;
    call symput('stringvar',"" || strip(value));
  end;
Run;

...然后 SAS 继续运行该代码（这恰好是有效代码，但将一个空字符串连接到某些内容的开头） 。由于数据步骤的工作方式，数据步骤的每次迭代实际上都会替换 StringVar 的值，这就是为什么在数据步骤结束时，留下了最后一个值被读入。

Answer 2

问候
看起来很简单，这是我的解决方案：

data a;
set test end=eof;
length cat $100.;
retain cat;
if AddToStringYN = "Y" then do;
   cat=trim(left(cat))||trim(left(value));
end;
if eof then do;
   call symput("VAR",cat);
   output;
end;
run;

%put VAR=&VAR;

在这个示例中，您在“CAT”列的 A 数据集中有变量的串联，并且您有一个具有相同列表的宏变量 VAR