从列表创建 Compojure 路由

Question

我最近刚刚开始使用 Compojure，并且有一个小型的基本网络应用程序。对于我的 HTML 模板，我使用 Enlive，并且我有一个包含所有简单静态页面的命名空间。这些页面的 defroute 调用如下所示：

(defroutes public-routes
  (GET "/" []
    (info/index-template))
  (GET "/about" []
    (info/about-template))
  (GET "/contact" []
    (info/contact-template)))

实际上我还有更多的页面，但这应该可以让我了解我正在做什么。

现在，我想，这实际上只是我的一堆重复，所以我想我会尝试以下操作：

(defroutes info-routes
  (map #(GET (str "/" %) [] (ns-resolve 'webapp.pages.info
                                        (symbol (str % "-template"))))
       '("about" "contact")))

当然，这不起作用，因为映射返回一个惰性序列而不是函数体（？） 。 有人知道我需要做什么才能让这个想法发挥作用吗？

或者我应该使用完全不同的方法来减少重复？

Answer 1

您始终可以使用 defroutes 使用的 routes 函数：

(defroutes info-routes
  (apply routes
    (map #(GET (str "/" %) [] 
               (ns-resolve 'webapp.pages.info
                           (symbol (str % "-template"))))
         '("about" "contact"))))

但这仍然很无聊，让我们给它加点趣味！ ;-)

(defn templates-for [& nss]
  (->> nss
       (map ns-publics)
       (apply concat)
       (filter #(->> % first str
                     (re-seq #"-template$")))
       (map second)))

(defn template-uri [template]
  (->> template meta :name name
       (re-seq  #"(.*)-template$")
       first second (str "/")))

(defn template->route [template]
  (GET (template-uri template) [] template))

(defroutes public-routes
  (GET "/" [] "foo")
  (apply routes (map template->route
                     (templates-for 'webapp.pages.info))))

使用此代码，templates-for 函数将在给定的命名空间中查找以“-template”结尾的任何函数，并用它们编写适当的路由。看看我没有使用任何宏，而是使用了大量的组合。

Answer 2

defroutes 是一个宏 所以不幸的是你无法将它传递给像map这样的函数。您需要编写一个宏来扩展为对 defroutes 的调用。或者查看它扩展成的函数并直接调用它们。

在 defroutes 调用中创建路由列表是行不通的，这样

(defroutes public-routes
  (make-list-of-routes)

会扩展为路由列表：

(defroutes public-routes
  ( (GET "/" [] (info/index-template)) 
    (GET "/about" [] (info/about-template))
    (GET "/contact" [] (info/contact-template))) )

如果 defroutes 是一个普通函数，您可以使用 apply 解决这个问题

(apply defroutes (conj 'public-routes (make-list-of-routes)))

因为 defroutes 是一个宏，所以在 apply 运行之前它就已经完全完成了，并且结果没有多大意义。您确实无法将宏组合为函数。宏不是 clojure（或我所知道的任何 lisp）中的一等公民
当一些 Clojurian 人（通常不是我）说“宏是邪恶的”时，他们经常会想到这样的情况：当你试图编写某个东西却无法编写它时，你会遇到这样一个事实：某个东西是宏。

解决方案是不使用defroutes宏并直接调用routes函数。