AppleScript 参考对象 - 帮助我理解它们

Question

为什么这些甚至存在？这似乎很荒谬。与大多数动态语言一样，AppleScript 类型似乎是不可变的原始类型，例如整数和实数，它们将按值传递，并且不会产生任何影响。与引用或类似对象类型（例如应用程序、脚本或记录）一起使用的意义s，它们已经通过引用传递。 对的引用为何不完全多余？以下是摘自 Apple 的 AppleScript 语言指南 ( https://developer.apple.com/library/archive/documentation/AppleScript/Conceptual/AppleScriptLangGuide/introduction/ASLR_intro.html）：

tell app "Finder" to set diskRef to a ref to startup disk
--result: startup disk of application "Finder"

所以你的意思是告诉我，如果我这样做，

tell app "Finder" to set diskObj to startup disk
--result: startup disk of application "Finder"

applescript运行时将向 Finder 进程发送一个苹果事件，告诉它，“嘿 - 有人刚刚要求你将 /dev/disks01 的八位字节流返回给我！哈哈！我想他应该要求 参考 让我们开始吧！”

我正在用 Python 编程，我这样做：

m = fileHandle.read( 1000000000 ) #and then wait a little while
n = m 

我是否刚刚在内存中复制了一大堆数据？当然不是。但 AppleScript 中引用的存在意味着将对象分配给新变量是一种按值操作。如果是这样的话，复制命令是怎么回事？

这是怎么回事？

更新：好吧，就当我是一个困惑的 Python 程序员吧。为了让这一点更清楚，我仍然认为

tell app "Finder" to set diskRef to a ref to startup disk
--result: startup disk of application "Finder"

这是一个糟糕的例子（取自 applescript 语言指南）。但 @Chuck 的对属性本身的引用的示例持有一个可以重新分配的原始类型，这是一个更好的例子。 IOW，引用对象实际上是一个变量/属性，它保存指向另一个变量或属性的指针。

Answer 1

AppleScript 中的两个变量（与 Python 中一样）可以共享相同的值。每个变量都有对其值的引用，但“引用”一词还有其他含义。字符串 "https://stackoverflow.com/" 是对网站的引用；整数 42 引用了 Douglas Adams 的作品； AppleScript 中 reference 类的对象是一种不同类型的引用。

reference 类的对象推迟对某个对象的元素或属性的访问。它几乎就像 Python 中的 lambda，因为 AppleScript 的

set v to {11, 22, 33}
set r to a reference to item 2 of v

行为与 Python 类似

v = [11, 22, 33]
r = lambda: v[1]

，推迟对列表第二项的访问。然后 AppleScript 中的 r 内容或 Python 中的 r() 内容将获取该项目。 AppleScript 还可以通过将 r 的内容设置为 99 来设置该项目； Python 无法使用此 lambda 设置项目。 Python 的 lambda 表达式可以做许多 AppleScript 引用无法做的事情。

对运算符的引用

AppleScript 语言指南描述了对运算符的引用，但遗漏了一些重要的细节。运算符只有一个操作数；编译器还接受引用OPERAND或ref OPERAND，然后将它们重写为对OPERAND的引用。

如果操作数是 A of B 或 B's A 形式的表达式，则运算符将表达式包装在 reference 类的对象中。该表达式可以是一个元素，例如 q 的第 2 项，也可以是一个属性，例如 q 的长度。

如果操作数是变量，则运算符附加隐式my或of me。例如，运行处理程序中对 q 的引用与对 my q 的引用相同。在 q 和 my q 不同的范围内，这会变得令人困惑。

对于其他操作数，则运算符仅返回操作数。例如，对 3 的引用返回 3，它不是引用类的对象。

运算符捕获变量的当前值。例如，对 q 的项 i 的引用捕获 i 和 q 的值。相比之下，对 q 的引用不会捕获 q 的值，因为它与对我的 q 的引用相同，因此它将 q 视为属性，不是一个变量。

to demo()
    set q to {11, 22, 33}
    set rq to a reference to q
    set i to 2
    set ri to a reference to item i of q
    set i to 3
    set item 2 of q to 55
    set q to {77, 88, 99}
    {contents of rq, contents of ri}
end demo

set q to "a string"
demo()

该脚本的结果是 {"a string", 55}。引用 rq 忽略本地 q 并使用运行处理程序中的 my q 。引用 ri 捕获了 i 和 q 的局部值，忽略了后来对 i 和 q 的赋值，但没有忽略对 q 的第 2 项的赋值。

对大列表使用引用

AppleScript 语言指南还提供了使用引用运算符来提高访问大列表速度的示例。 指南使用

set bigListRef to a reference to bigList

但未能解释该引用隐式对我的bigList的引用，因此访问是通过脚本对象me进行的。它之所以有效，是因为代码位于运行处理程序中，其中 bigList 和 my bigList 是相同的列表。

事实证明，如果引用经过任何脚本对象，则对大列表的访问会很快。其他访问速度很慢。下一个脚本通过使用快速访问创建包含 7000 个项目的列表，然后使用慢速和快速访问读取该列表来显示这一点。

to bench(what)
    set start to current date
    repeat with i from 1 to 7000
        if item i of what is not 42 then
            error "wrong value"
        end if
    end repeat
    (current date) - start
end bench

to bench2()
    script box
        property nums : {}
    end script
    repeat 7000 times
        set end of box's nums to 42
    end repeat
    {bench(box's nums), bench(a reference to box's nums)}
end bench2

bench2()

我在运行 PowerPC Mac OS X 10.4.11 的旧机器上运行了这个脚本。结果是{19, 0}，所以慢速访问用了19秒，快速访问用了0秒。

set end of box's nums to 42 行无需使用引用运算符即可进行快速访问。它速度很快，因为访问是通过脚本对象 box 进行的。

Answer 2

我的理解是，您可以将引用视为指针。

set x = 5
set y to reference to x
set contents of y to 10
log x -- 10

通常，您不会手动创建引用。 AppleScript 库和字典可能会返回它们，但随后您将使用返回项的属性（例如启动磁盘的名称）。

老实说，我会忽略他们。在使用 AppleScript 的二十年中，我可能不得不查找一次文档以获取参考资料。如果您尝试在 AppleScript 中执行某些操作并认为需要创建引用变量，那么您可能不会以最直接的方式执行此操作。

请查看这篇 MacTech 文章了解更多详细信息AppleScript 参考文献的讨论。