xsl:value-of 作为 xsl:variable 子级的后果

Question

当 $world 是元素列表时，这三个块在副作用方面有什么区别？我看到第一个和第三个之间有不同的行为，但我无法理解它。

<xsl:variable name="hello" select="$world" />

<xsl:variable name="hello">
    <xsl:value-of select="$world" />
</xsl:variable>

<xsl:variable name="hello">
    <xsl:choose>
        <xsl:when test="$something=true()">
            <xsl:value-of select="$world" />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$world" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:variable>

编辑1：我想在 中处理 $hello 。对于上面的第三个块， 只有一项要处理，其中包含 $world 的连接内容。这是为什么？

Answer 1

第一个 xsl:variable 将具有与 $world 相同的值和类型。第二个是结果树片段，其中包含 $world 字符串值的单个文本节点。第三个也是具有单个文本节点的结果树片段。

我想您想要

  <xsl:variable name="hello" select="if (condition) then $world else $foo"/>

在 XSLT 2.0 中然后您的 for-each select="$hello" 可以按照您的需要工作，或者在 XSLT 1.0 加上您想要的 EXSLT common 中工作

<xsl:variable name="hello">
  <xsl:choose>
    <xsl:when test="condition">
      <xsl:copy-of select="$world"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:copy-of select="$foo"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:variable>

<xsl:for-each select="exsl:node-set($hello)/*">...</xsl:for-each>

Answer 2

虽然所有三个示例在 XSLT 1.0 和 XSLT 2.0 中都有效，但这两个规范中描述语义的方式非常不同；另外，当 $value 包含多个节点时， 的效果取决于样式表指定 version="1.0" 还是 version="2.0 ”。

需要记住的主要内容适用于这两个版本，包括 (a) xsl:value-of 通过将其选择的任何内容转换为字符串来创建文本节点，以及 (b) xsl:variable 包含包含的指令（并且没有“as”）属性）创建一棵以文档节点为根的新树。

Answer 3

我想在 a 中处理 $hello
。和
上方的块有
只有一项要处理的项目包含
$world 的连接内容。为什么是
那？

名为 $hello 的变量包含 $world 的字符串值。根据定义，这就是 在 XSLT 1.0 中的行为方式。

您还没有向我们展示 $world 是如何定义的，但是如果它包含单个元素或整个文档树，那么（再次）根据定义，它的字符串值是串联（按文档顺序）它的所有后代 - 文本节点。

这正是您所看到的。

情况会有所不同，如果不是：

<xsl:value-of select="$world" />

你使用：

<xsl:copy-of select="$world" />

这会复制根为该元素的整个子树（或根节点/）当$world包含一个完整的文档时）包含在$world中。

然而，在 XSLT 1.0 中，这会创建所谓的 RTF（结果树片段），并且根据定义，不能使用 RTF 作为 XPath (1.0) 表达式中的定位步骤。

必须首先使用供应商提供的扩展函数将其转换为常规树（文档节点），该扩展函数通常具有本地名称node-set，但位于特定于供应商的命名空间中。

一个典型的例子是：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 >
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:variable name="vWorld" select="/*"/>

 <xsl:template match="/">
  <xsl:variable name="vrtfHello">
    <xsl:copy-of select="$vWorld"/>
  </xsl:variable>

  <xsl:variable name="vHello" select=
   "ext:node-set($vrtfHello)/*"/>

  <xsl:copy-of select="$vHello/*[3]"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<nums>
  <num>01</num>
  <num>02</num>
  <num>03</num>
  <num>04</num>
  <num>05</num>
  <num>06</num>
  <num>07</num>
  <num>08</num>
  <num>09</num>
  <num>10</num>
</nums>

结果是（如预期）：

<num>03</num>

这里我们使用 < code>ext:node-set() 命名空间“http://exslt.org/common”中的扩展函数，由 EXSLT 供应商独立库指定。大多数 XSLT 1.0 处理器都支持 EXSLT，并且使用其 node-set() 扩展函数不会降低 XSLT 应用程序在所有此类 XSLT 处理器上的可移植性程度。