如何使用 sed 打印除与范围结束模式匹配的行之外的一系列行？

Question

我想知道是否有一种 sed-only 方法可以打印一系列行，由要匹配的模式决定，除了与结束模式匹配的最后一行。

考虑以下示例。我有一个文件

line  1
line  2
line  3
ABC line  4
+ line  5
+ line  6
+ line  7
line  8
line  9
line 10
line 11
line 12

，我想获取以 ABC 开头的所有内容（包括）以及以 + 开头的所有行：

ABC line  4
+ line  5
+ line  6
+ line  7

我尝试过，

sed -n '/ABC/I,/^[^+]/ p' file

但这给出了太多行：

ABC line  4
+ line  5
+ line  6
+ line  7
line  8

省略最后一行的最简单方法是什么（仅sed）？

Answer 1

可能有更好的方法，但我可以想出这个 sed 1 liner：

sed -rn '/ABC/,/^[^+]/{/(ABC|^\+)/!d;p;}' file

另一个 sed 1 liner 是

sed -n '/ABC/,/^[^+]/{x;/^$/!p;}' file

One more sed 1 liner （可能更好）

sed -n '/ABC/I{h;:A;$!n;/^+/{H;$!bA};g;p;}' file

Answer 2

最简单的方法（如果有人可以通过一次调用 sed 来解决这个问题，我会学到一些新东西），是在末尾添加一个额外的 sed，即

sed -n '/ABC/I,/^[^+]/ p' file | sed '$d'
ABC line  4
+ line  5
+ line  6
+ line  7

作弊，我知道，但这就是 Unix 管道哲学的美妙之处。继续削减你的数据，直到你得到你想要的;-)

我希望这会有所帮助。

Answer 3

这可能对您有用：

 sed '/^ABC/{:a;n;/^\(ABC\|+\)/ba};d' file

编辑：允许相邻的 ABC 部分。

Answer 4

好吧，你已经选择了你的答案。但为什么不使用 /^(ABC|\+)/ ？或者我误解了你的要求？

如果您想在搜索 ABC 后找到那些 + 行，

awk '/ABC/{f=1;print} f &&/^\+/ { print }' file

这比制作神秘的 sed 表达式更容易理解。当找到 ABC 时，设置一个标志。当找到以 + 开头的行并设置标志时，打印该行。