记录到 Flex 中的本地文件

Question

我的应用程序前端是用 Flex 3 开发的。 对于日志记录，我们有时使用跟踪和记录器，但我们没有特定的方法将日志存储在用户计算机的本地文件中。

事实上，我从 Adob​​e livedocs 中了解到，flashplayer 会自行管理 flashlog.txt 文件中的所有日志。

还有其他方法可以维护日志副本吗？每次执行“注销”时，flashlog.txt 都会被清除。

Answer 1

您没有提到您的应用程序是桌面应用程序还是基于浏览器的应用程序。

对于桌面应用程序，您可以编写一个新类；

import mx.core.mx_internal; 
use namespace mx_internal;

public class LoggingFileTarget extends LineFormattedTarget {
        private const DEFAULT_LOG_PATH:String = "C:/mylogfile.txt";

        private var log:File;

        public function LoggingFileTarget(logFile:File = null) {
            if(logFile != null) {
                log = logFile;
            } else {
                log = new File(DEFAULT_LOG_PATH);
            }
        }

        public function get logURI():String {
            return log.url;
        }

        mx_internal override function internalLog(message:String):void {
            write(message);
        }           

        private function write(msg:String):void {               
            var fs:FileStream = new FileStream();
            try {
                fs.open(log, FileMode.APPEND);
                fs.writeUTFBytes(msg + "\n");
                fs.close();
            } catch(e:Error) {
                trace("FATAL:: Unable to write to log file.");
            }
        }

        public function clear():void {
            var fs:FileStream = new FileStream();
            fs.open(log, FileMode.WRITE);
            fs.writeUTFBytes("");
            fs.close();                     
        }
    }

对于基于浏览器的应用程序，您可以继续写入内存中的字符串或本地共享对象。使用共享的本地对象，不断附加到日志，然后通过网络调用进行整理。