使用 XSLT 2.0 的两阶段转换

Question

我正在尝试将 CSV 文件作为输入并将其转换为 XML。我是 XSLT 新手，我找到了一种将 CSV 转换为 XML 的方法（使用 Andrew Welch) 就像这样：

输入 CSV 文件：

car manufacturer,model,color,price,inventory
subaru,outback,blue,23195,54
subaru,forester,silver,20495,23

我的输出 XML 是：

<?xml version="1.0" encoding="UTF-8"?>
<rows>
   <row>
      <column name="car manufacturer">subaru</column>
      <column name="model">outback</column>
      <column name="color">blue</column>
      <column name="price">23195</column>
      <column name="inventory">54</column>
   </row>
   <row>
      <column name="car manufacturer">subaru</column>
      <column name="model">forester</column>
      <column name="color">silver</column>
      <column name="price">20495</column>
      <column name="inventory">23</column>
   </row>
</rows>

我想要的输出实际上类似于：

<stock>
   <model>
      <car>subaru outback</car>
      <color>blue</color>
      <price>23195</price>
      <inventory>54</inventory>
   </model>
   <model>
      <car>subaru forester</car>
      <color>silver</color>
      <price>20495</price>
      <inventory>23</inventory>
   </model>
</stock>

我读到的是，最好使用两个相变。 CSV 到 XML 是使用 XSLT 2.0 完成的，因此我认为也可以使用它来完成两阶段转换，而不使用节点集函数。

因此，第一阶段是将原始 CSV 文件作为输入，然后输出如上所示的中间 XML。然后获取该中间 XML，并将其传递到另一个转换以获得所需的输出。

任何人都可以帮助如何完成两相转变？我在将第一阶段的输出作为第二阶段的输入传递时遇到问题？

到目前为止我有这样的事情：

<xsl:import href="csv2xml.xsl"/>
<xsl:output method="xml" indent="yes" />

<xsl:variable name="intermediate">
    <xsl:apply-templates select="/" mode="csv2xml"/>
</xsl:variable>

<xsl:template match="rows" name="main">

 **[This is what I'm having trouble with]**

</xsl:template>

Answer 1

我不明白为什么这种转换需要两个阶段 - 除了可能允许您在其中一个阶段重用现有代码之外。

但是，当您确实需要两个阶段时，一般模型是：

<xsl:template match="/">
  <xsl:variable name="phase-1-result">
    <xsl:apply-templates select="/" mode="phase-1"/>
  </xsl:variable>
  <xsl:apply-templates select="$phase-1-result" mode="phase-2"/>
</xsl:template>

阶段 1 和阶段 2 的模板规则（及其 apply-templates 调用）分别处于阶段 1 或阶段 2 模式。

Answer 2

此 XSLT 2.0 样式表：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <xsl:variable name="vLines"
         select="tokenize(unparsed-text('test.txt'),'(
)?
')"/>
        <xsl:variable name="vHeaders"
         select="tokenize($vLines[1],',')"/>
        <stock>
            <xsl:for-each select="$vLines[position()!=1]">
                <model>
                    <xsl:variable name="vColumns" select="tokenize(.,',')"/>
                    <xsl:for-each select="$vColumns">
                        <xsl:variable name="vPosition" select="position()"/>
                        <xsl:variable name="vHeader"
                         select="$vHeaders[$vPosition]"/>
                        <xsl:choose>
                            <xsl:when test="$vHeader = 'car manufacturer'">
                                <column name="car">
                                    <xsl:value-of
                                     select="(.,$vColumns[
                                                   index-of($vHeaders,'model')
                                                ])"/>
                                </column>
                            </xsl:when>
                            <xsl:when test="$vHeader = 'model'"/>
                            <xsl:otherwise>
                                <column name="{$vHeader}">
                                    <xsl:value-of select="."/>
                                </column>
                            </xsl:otherwise>
                        </xsl:choose>
                    </xsl:for-each>
                </model>
            </xsl:for-each>
        </stock>
    </xsl:template>
</xsl:stylesheet>

输出：

<stock>
    <model>
        <column name="car">subaru outback</column>
        <column name="color">blue</column>
        <column name="price">23195</column>
        <column name="inventory">54</column>
    </model>
    <model>
        <column name="car">subaru forester</column>
        <column name="color">silver</column>
        <column name="price">20495</column>
        <column name="inventory">23</column>
    </model>
</stock>

注意：在 XSLT 3.0 中，您将能够将模板应用于一般项目。

编辑：正确的名称。

Answer 3

您可以在此处找到如何使用 XSLT 3.0 执行此操作的示例：

http:// www.stylusstudio.com/tutorials/intro-xslt-3.html

并参见“文本操作”。