如何动态生成 XML？

Question

我实际上之前以不同的形式问过这个问题。我确实得到了一个很好的答案，但我认为我需要更多的澄清，所以我再次以完整的形式询问它。

用户将编写如下脚本：

$ABC->Command(100, 100);
my $group  = "1";
my $id     = "1";
my $value1 = "Some Process A Happened";
$rep->getParameter($group, $id, $value1);
$ABC->Command(100, 100);
my $group  = "1";
my $id     = "2";
my $value1 = "Some Process B Happened";
$rep->getParameter($group, $id, $value1);
$ABC->Command(100, 100);
my $group  = "2";
my $id     = "1";
my $value1 = "Some Process A Happened";
$rep->getParameter($group, $id, $value1);
$ABC->Command(100, 100);
my $group  = "2";
my $id     = "1";
my $value1 = "Some Process Happened";
$rep->getParameter($group, $id, $value1);
$ABC->Command(100, 100);
my $group  = "3";
my $id     = "1";
my $value1 = "Some Process Happened";
$rep->getParameter($group, $id, $value1);
$ABC->SomeImage($image) $desc = "Some info";
$rep->getImage($image, $desc);
$rep->getResult("Pass")

这将必须生成如下 XML：

<?xml version="1.0" encoding="UTF-8" ?>
<TestResult xmlns="http://test.com/automate" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://test.com/automate">
    <Result>Pass</Result>
    <Comments>Executed Successfully</Comments>
    <Parameters>
        <ParameterGroup ID="Group1">
            <Parameter key="Key1">Some Value</Parameter>
            <Parameter key="Key2">Some Value</Parameter>
            <Parameter key="Key3">Some Value</Parameter>
        </ParameterGroup>
        <ParameterGroup ID="Group2">
            <Parameter key="Key1">Some Value</Parameter>
            <Parameter key="Key2">Some Value</Parameter>
            <Parameter key="Key3">Some Value</Parameter>
        </ParameterGroup>
        <ParameterGroup ID="Group3">
            <Parameter key="Key1">Some Value</Parameter>
            <Parameter key="Key2">Some Value</Parameter>
            <Parameter key="Key3">Some Value</Parameter>
        </ParameterGroup>
    </Parameters>
    <Images>
        <Image key="ImageTag1">info</Image>
        <Image key="ImageTag2">info</Image>
        <Image key="ImageTag3">info</Image>
    </Images>
</TestResult>

图像值和参数值将在不同时间点输入。但它们必须被收集并放置在 Images 元素内，与 Parameters 类似。我应该遵循什么方法？请提供一些代码示例。

---

编辑：

我有类似

$xml = {
    ParameterGroup => [
        {
            ID        => 'Group1',
            Parameter => {
                Key1  => {content => 'Some Value'},
                Key2  => {content => 'Some Value'},
                Key3  => {content => 'Some Value'},
            },
        },
        {
            ID        => 'Group2',
            Parameter => {
                Key1  => {content => 'Some Value'},
                Key2  => {content => 'Some Value'},
                Key3  => {content => 'Some Value'},
            },
        },
    ]
};
print XMLout(
    $xml,
    RootName => 'Parameters',
    KeyAttr  => 'value',
);

结构的东西，但这些是固定结构。我怎样才能使这种动态满足用户的要求？

Answer 1

请考虑对您的驱动程序代码进行以下一些小调整。

#! /usr/bin/env perl

use warnings;
use strict;

use TestResult;

my $tr = TestResult->new;

$tr->parameter(1, 1, "Some Process A Happened");
$tr->parameter(1, 2, "Some Process B Happened");
$tr->parameter(2, 1, "Some Process A Happened");
$tr->parameter(3, 1, "Some Process Happened");

$tr->image(1, "Some info");

$tr->result("Pass");
$tr->comments("Executed Successfully");

print $tr->as_xml;

XML 输出是

<?xml version="1.0" encoding="UTF-8" ?>
<TestResult xmlns="http://test.com/automate" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xsi:schemaLocation="http://test.com/automate">
  <Result>Pass</Result>
  <Comments>Executed Successfully</Comments>
  <Parameters>
    <ParameterGroup ID="Group1">
      <Parameter key="Key1">Some Process A Happened</Parameter>
      <Parameter key="Key2">Some Process B Happened</Parameter>
    </ParameterGroup>
    <ParameterGroup ID="Group2">
      <Parameter key="Key1">Some Process A Happened</Parameter>
    </ParameterGroup>
    <ParameterGroup ID="Group3">
      <Parameter key="Key1">Some Process Happened</Parameter>
    </ParameterGroup>
  </Parameters>
  <Images>
    <Image key="ImageTag1">Some info</Image>
  </Images>
</TestResult>

查看 $self->{_xml} 内容的转储可能有助于您的理解。

{
  'Comments' => { 'content' => 'Executed Successfully' },
  'Parameters' => {
    'ParameterGroup' => {
      'Group1' => {
        'Parameter' => {
          'Key2' => { 'content' => 'Some Process B Happened' },
          'Key1' => { 'content' => 'Some Process A Happened' }
        }
      },
      'Group3' => {
        'Parameter' => {
          'Key1' => { 'content' => 'Some Process Happened' }
        }
      },
      'Group2' => {
        'Parameter' => {
          'Key1' => { 'content' => 'Some Process A Happened' }
        }
      }
    }
  },
  'xmlns' => 'http://test.com/automate',
  'Result' => { 'content' => 'Pass' },
  'xmlns:xsi' => 'http://www.w3.org/2001/XMLSchema-instance',
  'xsi:schemaLocation' => 'http://test.com/automate',
  'Images' => {
    'ImageTag1' => { 'content' => 'Some info' }
  }
}

下面是帮助您实现这一目标的 TestResult 模块。请务必将其放入模块搜索路径中名为 TestResult.pm 的文件中。它以熟悉的样板开始。

package TestResult;

use strict;
use warnings;

use XML::Simple;

在编译时，我们专门针对您所需的 XML 格式设置了 XML::Simple 的子类，它将按适当的顺序输出元素。

BEGIN {
  @__PACKAGE__::XML::ISA = qw/ XML::Simple /;

  my %order = (
    TestResult => [qw/
      xmlns xmlns:xsi xsi:schemaLocation
      Result Comments Parameters Images
    /],
  );

  *__PACKAGE__::XML::sorted_keys = sub {
    my($self,$name,$h) = @_;
    return @{ $order{$name} } if $order{$name};
    sort keys %$h;
  };
}

每个实例都会携带输出文档的内容。硬编码的键值对成为 TestResult 元素的属性。

sub new {
  my($class) = @_;
  my $self = {
    _xml => {
      "xmlns"              => "http://test.com/automate",
      "xmlns:xsi"          => "http://www.w3.org/2001/XMLSchema-instance",
      "xsi:schemaLocation" => "http://test.com/automate",
    },
  };

  bless $self => $class;
}

comments 和 result 的实现很简单，因为它们生成的 XML 很简单。这些方法毫无意外地将位填充到适当的槽中。

sub comments {
  my($self,$comments) = @_;
  $self->{_xml}{Comments} = { content => $comments };
}

sub result {
  my($self,$result) = @_;
  $self->{_xml}{Result} = { content => $result };
}

我们必须小心 image 和 parameter 因为它们包含多个子项。盲目覆盖 $self->{_xml}{Images} 或 $self->{_xml}{Parameter} 会破坏已经积累的任何内容，因此相反，我们增量地添加新元素。

sub image {
  my($self,$image,$desc) = @_;

  my $imageid = "ImageTag" . $image;
  $self->{_xml}{Images}{$imageid} = { content => $desc };
}

sub parameter {
  my($self,$group,$key,$value) = @_;

  my $groupid = "Group" . $group;
  my $keyid   = "Key"   . $key;

  $self->{_xml}{Parameters}{ParameterGroup}{$groupid}{Parameter}{$keyid} =
    { content => $value };
}

最后，我们使用 TestResult::XML 对 XML 进行编码。 GroupTags 参数声明嵌套关系，例如， 包含。 （首先，我尝试对 和 之间以及 和，但 XML 输出与您想要的不同。）KeyAttr 参数告诉 XML::Simple 使用 Perl 哈希键作为 XML 属性。如果您曾经使用 XMLin 读取其他工具生成的 TestResults，则 + 前缀将获得更好的结果。

sub as_xml {
  my($self) = @_;

  my $serialize = __PACKAGE__::XML->new;

  $serialize->XMLout(
    $self->{_xml},
    GroupTags => {
      Images => "Image",
    },
    KeyAttr => {
      ParameterGroup => "+ID",
      Parameter      => "+key",
      Image          => "+key",
    },
    RootName => "TestResult",
    XMLDecl => '<?xml version="1.0" encoding="UTF-8" ?>',
  );
}

返回 true 值表示模块加载成功。

1;

Answer 2

XML::Simple 期望您将输出组装成 Perl 数据结构，然后将其转换为 XML；您在实际调用生成 XML、弄清楚数据结构应该是什么样子或用数据填充它时是否遇到困难？ （或者完全不同的东西？）

分解你的问题并一次一点点地解决它。