在新版本的 Mathematica 中制作版本 5 旧文档的工作副本

Question

在新版本的 Mathematica 中，我们有 功能齐全的老式 Mathematica 帮助浏览器。但版本 5 的旧文档并未包含在新版本的 Mathematica 中。该旧版文档仅占用 209 МB 磁盘空间，如果能够在新版本的 Mathematica 中访问它将会非常有用。

将 Mathematica 5.2 和 Mathematica 7 或 8 安装在同一台计算机上，如何才能通过老式的帮助浏览器从新版本中访问旧文档？

我尝试将文档文件夹复制到

C:\Program Files\Wolfram Research\Mathematica\5.2\Documentation

旧版

C:\Documents and Settings\All Users\Application Data\Mathematica\Application\LegacyDocumenation

帮助浏览器中，现在旧版帮助浏览器中的“帮助浏览器”显示为插件。但它不能正常工作。

有关调整 Mathematica 5 中帮助浏览器外观的一些有用信息，请参见 此处。但我不知道如何将其应用于新版本的Mathematica。

Answer 1

解决方案

顺便说一句，我已经找到了将所有 Mathematica 5.2 文档添加到新版本 Mathematica 中旧版帮助浏览器中的方法。

关键是位于目录（Windows 下）中的“HelpBrowserSetup.tr”文件，

C:\Program Files\Wolfram Research\Mathematica\7.0\SystemFiles\FrontEnd\TextResources

应将其内容替换为：

@@resource HelpBrowserSetup
BrowserCategory["Help Browser", None, {
    HelpDirectoryListing[{"RefGuide"}, False],
    HelpDirectoryListing[{"AddOns"}, False],
    HelpDirectoryListing[{"MainBook"}, False],
    HelpDirectoryListing[{"OtherInformation"}, False],
    HelpDirectoryListing[{"GettingStarted"}, False],
    HelpDirectoryListing[{"Tour"}, False],
    HelpDirectoryListing[{"Demos"}, False],
    BrowserCategory["Master Index", None, {HelpMasterIndex[]}]
}]

然后，Mathematica$InstallationDirectory 中的“Documentation”文件夹em> 5.2 应复制到新版本Mathematica 的$InstallationDirectory 并替换（一个不重要的文件将被替换）。另一种可能性是将其复制到目录（在 Windows 下）

C:\Documents and Settings\All Users\Application Data\Mathematica

（可能 $UserBaseDirectory 也合适）。

现在启动 Mathematica 并评估

FrontEndTokenExecute["HelpDialog"]

旧版帮助浏览器将打开并包含 5.2 版中的所有文档！

编辑

我刚刚找到了更简单的解决方案。人们可以按如下方式修改“HelpBrowserSetup.tr”文件：（

@@resource HelpBrowserSetup
HelpDirectoryListing[SystemHelpPath, False, True, True]

或者简单地将该文件从版本 5.2 安装复制并替换到新版本的文件夹中）。

对于安装了 Mathematica 5.2 的用户来说，

您无需复制文档。您有两种可能性：

1.) 仅将“HelpBrowserSetup.tr”文件从版本 5.2 安装复制到新版本的文件夹。然后评估类似的内容

SetOptions[$FrontEnd, 
 SystemHelpPath -> 
  Union[SystemHelpPath /. 
    Options[$FrontEnd, 
     SystemHelpPath], {"C:/Program Files/Wolfram \
Research/Mathematica/5.2/"}]]

（其中“C:/Program Files/Wolfram Research/Mathematica/5.2/”是 Mathematica 5.2 的 $InstallationDirectory）。

，所有安装的版本 6 之前的附加组件将不会出现在旧版帮助浏览器中）：

@@resource HelpBrowserSetup
HelpDirectoryListing[{"C:/Program Files/Wolfram Research/Mathematica/5.2/"}, False, True, True]

然后评估

FrontEndTokenExecute["RebuildHelpIndex"]
FrontEndTokenExecute["HelpDialog"]

2.) 只需按如下方式修改“HelpBrowserSetup.tr”文件（但在这种情况下 将帮助浏览器项目添加到帮助菜单

为此，我们只需在 MenuSetup.tr 中的适当位置添加行 MenuItem["Help Browser...", "HelpDialog"],：

HelpMenu["&Help", 
{
    MenuItem["Documentation &Center", "OpenHelpLink"],
    MenuItem["Help Browser...", "HelpDialog"],

Answer 2

警告：我最近了解到，为新文档构建索引可能会在 Windows 计算机中产生不良影响。请阅读 Alexey 的评论以了解更多详细信息。据我所知，Mac OS X 中一切正常。一旦确定问题根源，我将提供更新。

在这里，我提出了一个功能，允许任何笔记本成为 Mathematica 8 中文档中心的一部分。您可以首先让 Mathematica 评估以下内容：

Clear[FormatDoc, AddDocs];
FormatDoc[dir_, last_, num_, appName_, pacFile_, index_] := 
 Module[{dirs, nbs, nb, str, comma = ",", title, tags}, 
  nbs = FileNames[dir <> "/*.nb"];
  dirs = FileNames[dir <> "/*"];
  Do[If[last && i == Length@nbs, comma = ""];
   str = FileNameDrop[nbs[[i]], {1, num}];
   title = StringDrop[FileNameTake[nbs[[i]]], -3];
   Print[Row[{Style["Adding: ", "MSG", Black], 
      Style[str, "MSG", Blue]}]];
   str = StringDrop[str, -3];
   WriteString[pacFile, 
    "\t\t\t\t\"" <> str <> "\"" <> comma <> "\n"];
   nb = NotebookOpen[nbs[[i]]];
   tags = 
    DeleteDuplicates@
     Flatten@Map[#[[2]] &, 
       Cases[NotebookGet[
         nb], (_Dummy | (CellTags -> _)), \[Infinity]]];
   SetOptions[nb, 
    DockedCells -> 
     FEPrivate`FrontEndResource["FEExpressions", "HelpViewerToolbar"],
     Saveable -> False, 
    WindowTitle -> 
     "Mathematica 5.2 | " <> FileNameDrop[str] <> " | " <> title, 
    TaggingRules -> {"ModificationHighlight" -> False, 
      "Metadata" -> {"context" -> appName <> "`", "keywords" -> tags, 
        "index" -> True, 
        "label" -> "Mathematica 5.2 | " <> FileNameDrop[str], 
        "language" -> "en", "paclet" -> appName, "status" -> "", 
        "summary" -> ToString@tags, "synonyms" -> {}, 
        "title" -> title, "windowtitle" -> title, "type" -> "Doc", 
        "uri" -> 
         StringReplace[FileNameJoin[{appName, str}], "\\" -> "/"]}, 
      "SearchTextTranslated" -> "", "LinkTrails" -> ""}];
   NotebookSave[nb];
   NotebookClose[nb];
   DocumentationSearch`AddDocumentationNotebook[index, nbs[[i]]];, {i,
     Length@nbs}];
  Do[If[DirectoryQ[dirs[[i]]], str = FileNameDrop[dirs[[i]], {1, num}];
    Print[
     Row[{Style["Adding from: ", "MSG", Black], 
       Style[str, "MSG", Gray]}]];
    FormatDoc[dirs[[i]], last, num, appName, pacFile, index];], {i, 
    Length@dirs}]]
AddDocs[appName_] := 
 Module[{appDir, appDocs, dirs, pacFile, index, indexDir, str, num}, 
  appDir = FileNameJoin[{$UserBaseDirectory, "Applications"}];
  appDocs = 
   FileNameJoin[{appDir, appName, "Documentation", "English"}];
  indexDir = FileNameJoin[{appDocs, "Index"}];
  dirs = FileNames[appDocs <> "/*"];
  If[Length@dirs == 0, 
   Print[Style["There are no documents to add... ", "MSG", Orange]];
   Return[]];
  Print[Row[{Style["Working in: ", "MSG", Black], 
     Style[appDocs, "MSG", Red]}]];
  num = Length@FileNameSplit[appDocs];
  index = 
   DocumentationSearch`NewDocumentationNotebookIndexer[indexDir];
  pacFile = OpenWrite[FileNameJoin[{appDir, appName, "PacletInfo.m"}]];
  WriteString[pacFile, "Paclet[
                Name -> \"" <> appName <> "\",
                Version -> \"5.2.0\",
                MathematicaVersion -> \"7+\",
                Extensions -> {
                    {
                        \"Kernel\",
                        \"Context\" -> {
                        }
                    },
                    {
                        \"Documentation\",
                        Language -> \"English\",
                        LinkBase -> \"" <> appName <> "\",
                        Resources -> {\n"];
  Do[If[DirectoryQ[dirs[[i]]], str = FileNameDrop[dirs[[i]], {1, num}];
    Print[
     Row[{Style["Adding from: ", "MSG", Black], 
       Style[str, "MSG", Gray]}]];
    FormatDoc[dirs[[i]], i == Length@dirs, num, appName, pacFile, 
     index];], {i, Length@dirs}];
  WriteString[pacFile, "\t\t\t}
                }
            }
          ]\n"];
  Close[pacFile];
  DocumentationSearch`CloseDocumentationNotebookIndexer[index];
  PacletManager`RestartPacletManager[];]

如何使用它：

在一个新文档或您评估函数的同一文档中，首先找出这个变量是什么：

$UserBaseDirectory

在我的例子中，因为我使用的是Mac OS XI，所以得到：

/Users/jmlopez/Library/Mathematica

找出你的变量是什么。在此目录中，您应该会看到文件夹 Applications。在 Applications 内创建用于放置 MMA5 文档的文件夹。我将我的文件夹命名为 MMA5，因为它很短，但您可以给它任何您想要的名称，对于 Alexey，我们可以将其称为 LegacyDocumentation。在此文件夹内传输 MMA5 安装目录中名为 Documentation 的文件夹的副本。

我们快完成了。现在调用函数AddDocs。该函数仅采用一个参数：我们希望添加其文档的应用程序的名称。就我而言，由于我将文件夹命名为 MMA5，因此我将按如下方式调用它：

AddDocs["MMA5"]

接下来您应该看到的是一系列笔记本出现和消失以及一系列正在打印的消息。以下是该消息序列的一部分：

由于 MMA5 的文档相当广泛，因此此过程将需要一段时间。我对这个函数做了一个计时，它说大约需要 40 秒（对我来说似乎更长）。

你完成了。 MMA5 的文档现在应该可以在文档中心找到。

试驾

假设您希望查找有关 DSolve 的一些信息。如果您搜索 DSolve，您会看到以下内容：

查找 MMA5 文档我们需要点击“搜索包含 DSolve 的所有页面”中的 DSolve 链接。现在我们得到这样的东西：

在上面的屏幕截图中，我用红色标记了允许我们访问的条目Mathematica 5 文档。我无法为文档中的每个文件编写一个很好的摘要，因此我只是让 Mathematica 编写位于笔记本中的 CellTags 。这就是您看到字符串列表的原因。

如果您单击第一个红色条目，这就是我们获得的

这样您就得到了遗留文档的工作副本致力于新版本的 Mathematica。我还没有在 MMA7 中测试过这个，但我感觉它会起作用。如果有人尝试这样做，请告诉我。

注意

如果您想将其应用于不同应用程序中的其他文档。您需要注意这一点：

    WindowTitle -> 
     "Mathematica 5.2 | " <> FileNameDrop[str] <> " | " <> title,
    TaggingRules -> {
      "ModificationHighlight" -> False,
      "Metadata" -> {
        "context" -> appName <> "`",
        "keywords" -> tags,
        "index" -> True,
        "label" -> "Mathematica 5.2 | " <> FileNameDrop[str],
        "language" -> "en",
        "paclet" -> appName,
        "status" -> "",
        "summary" -> ToString@tags,
        "synonyms" -> {},
        "title" -> title,
        "windowtitle" -> title,
        "type" -> "Doc",
        "uri" -> 
         StringReplace[FileNameJoin[{appName, str}], "\\" -> "/"]
        },

请注意，我在标签中硬编码了“Mathematica 5.2”。如果需要，您甚至可以将其更改为“LegacyDocumentation”。这只是一个标签。另一个重要的一点是
关键字。我已将 keywords 设置为变量 tags。笔记本中的每个单元格都可以选择添加CellTags。如果您要编写一些文档，则应该使用它们。我就利用这个让文档中心知道如何查找文档。这是我最近才学到的东西，我一定会在一个包中实现。

如果您想编写一个完整的应用程序及其文档，我建议您查看我的帖子 将笔记本集成到 MMA 文档中心。在这里您将找到更多信息，让您了解我在此处提供的功能如何工作。

最后，我想补充一点，我也在 Windows 机器中对此进行了测试，并且运行良好，这就是这行代码背后的原因：

StringReplace[FileNameJoin[{appName, str}], "\\ “-> "/"]

编辑：

我更改了该函数，以便它可以在 MMA7 中正确工作。结果 pacletInfo.m 文件需要包含行 MathematicaVersion ->; 7+，以便它可以在 MMA7 和 MMA8 中工作。

编辑2：

我在复制和粘贴该函数时犯了一个错误。现在应该修复了。如果您同时拥有 MMA7 和 MMA8，我建议仅在 MMA7 中运行一次。这样，MMA7 和 MMA8 都可以使用该文档。