XSLT 1.0 如何递增日期

Question

更新：无法使用任何 EXSLT 扩展。 另外，我在两个不同的地方使用日期，我只想更新其中之一，而不是两者。

我需要在 XSLT 转换中增加一个日期。我正在使用 XSLT 1.0。

在源 XML 中，我有一个这样的日期

<XML>
    <Date>4/22/2011 3:30:43 PM</Date>
</XML>

然后我需要在输出中添加 10 年。像这样

<Output>
   <Odate>4/22/2011 3:30:43 PM</Odate>
   <Cdate>4/22/2021 3:30:43 PM</Cdate>
</Output>

如何在 XSLT 1.0 中完成此操作。提前致谢。

Answer 1

以下不是一般的日期算术实现，但可能足以增加年份部分：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">

<xsl:param name="year-inc" select="10"/>

<xsl:template match="XML">
  <Output>
    <xsl:apply-templates/>
  </Output>
</xsl:template>

<xsl:template match="Date">
  <xsl:variable name="d0" select="substring-before(., '/')"/>
  <xsl:variable name="d1" select="substring-before(substring-after(., '/'), '/')"/>
  <xsl:variable name="d2" select="substring-after(substring-after(., '/'), '/')"/>
  <xsl:variable name="new-year" select="substring($d2, 1, 4) + $year-inc"/>
  <Cdate>
    <xsl:value-of select="concat($d0, '/', $d1, '/', $new-year, substring($d2, 5))"/>
  </Cdate>
</xsl:template>

</xsl:stylesheet>

Answer 2

取决于您想要变得多么挑剔，例如 2004 年 2 月 29 日之后 10 年后的日期是哪一天？有许多有用的 XSLT 1.0 日期处理例程，您可以在 www.exslt.org 下载，我认为它们包括一个解析日期模板，它将您的美国格式日期转换为标准 ISO 日期，日期算术模板将允许您向 ISO 格式日期添加持续时间，以及将其转换回美国格式的格式日期函数。

Answer 3

我在@Martin 的帮助下找到了它。我扩展了@Martin 的代码，并且仅在需要修改日期时才调用模板。

XSLT：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  <xsl:output method="xml" indent="yes"/>
  <xsl:param name="year-inc" select="10"/>

  <xsl:template match="XML">
    <Output>
      <Odate>
        <xsl:value-of select="Date"/>
      </Odate>
      <Cdate>
        <xsl:call-template name="increment"/>
      </Cdate>
    </Output>
  </xsl:template>

  <xsl:template name="increment">
    <xsl:variable name="d0" select="substring-before(Date, '/')"/>
    <xsl:variable name="d1" select="substring-before(substring-after(Date, '/'), '/')"/>
    <xsl:variable name="d2" select="substring-after(substring-after(Date, '/'), '/')"/>
    <xsl:variable name="new-year" select="substring($d2, 1, 4) + $year-inc"/>
    <xsl:value-of select="concat($d0, '/', $d1, '/', $new-year, substring($d2, 5))"/>
  </xsl:template>

</xsl:stylesheet>

输出：

<?xml version="1.0" encoding="utf-8"?>
<Output>
  <Odate>4/22/2011 3:30:43 PM</Odate>
  <Cdate>4/22/2021 3:30:43 PM</Cdate>
</Output>