正则表达式查找字符串对

Question

我在 http://blog.armbruster-it.de/2010/07/getting-a-list-of-all-i18n-properties-used-in-a-grails-application/谢谢斯特凡！

描述：创建 groovy 代码和 gsp 模板中使用的所有 i18n 属性的列表

def properties = []

new File(".").eachFileRecurse {
    if (it.file) {
        switch (it) {
            case ~/.*\.groovy/:
                def matcher = it.text =~ /code:\s*["'](.*?)["']/
                matcher.each { properties << it[1] }
                break
            case ~/.*\.gsp/:
                def matcher = it.text =~ /code=["'](.*?)["']/
                matcher.each { properties << it[1] }
                break
        }
    }
}
println properties.sort().unique().join("\n")

我尝试通过以下方式扩展它。假设我们有一些消息属性，例如：

message(code: 'product.label', default: 'Product')

我们想要作为脚本的输出，例如：

product.label=Product

我尝试向正则表达式添加一些条件：

def matcher = it.text =~ /code=["'](.*?)["'] | default=\s*["'](.*?)["']/

并将其填充到属性中。但由于正则表达式找不到成对的“代码和默认”部分，因此这是行不通的。

知道如何更改正则表达式或整个脚本来执行此操作吗？

Answer 1

您的正则表达式不正确。对于以下消息方法调用：

message(code: 'product.label', default: 'Product')

它应该如下所示：

def properties = [:]
def txt = "message(code: 'product.label', default: 'Product')"
def matcher = txt =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
matcher.each{ properties[it[1]] = it[2] }
assert properties == ['product.label':'Product']

Answer 2

除了像 Bunting 那样提供更好的正则表达式之外，我还发现了一个非常有用的 Grails 插件： message-reports

Answer 3

解决这个问题的更好的正则表达式是：

/code=["'](.*?)["'].*default=\s*["'](.*?)["']/

输出格式可以是

properties << it[1]+"="+it[2]

结果

product.label=Product

Answer 4

我对这个脚本进行了一些研究，发现了一些需要注意的细节。我想查找带有和没有定义默认值的消息，并且我想找到非标记版本（即 ${g.message(code:"the.code", default:"the.default"}) 最好

不要遍历文件的内容，而是逐行解析它，这是因为如果一行中有代码，我将（在第二步中）查看它是否有但不想将整个文件解析两次，

def properties = [:]

new File(".").eachFileRecurse { file ->
    if (file.file) {
        switch (file) {
            case ~/.*\.groovy/:
                file.eachLine {line ->
                    // check if there is a message in the current line
                    def matcherNoDefault = line =~ /code:\s*["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }
                }
                break
            case ~/.*\.gsp/:
                file.eachLine {line ->
                    // check if there is a message in the current line (as a g.message(...) function)
                    def matcherNoDefault = line =~ /code:\s*["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code:\s*["'](.*?)["'].*default:\s*["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }

                    // check if there is a message in the current line (in tag form)
                    matcherNoDefault = line =~ /code=["'](.*?)["']/
                    // if there is one, check if it has a default
                    if (matcherNoDefault.getCount() > 0) {
                        def matcher = line =~ /code=["'](.*?)["'].*default=["'](.*?)["']/
                        if (matcher.getCount() > 0) {
                            matcher.each{ properties[it[1]] = it[2] }
                        } else {
                            matcherNoDefault.each{ properties[it[1]] = "NO_DEFAULT" }
                        }
                    }
                }
        }
    }
}
println properties.each {k, v ->
    println("${k}=${v}")
}

不能在一行中混合带有默认值的消息了。

这样我就