AS3 键盘控制

Question

我有一个 as3 函数，可以用键盘控制影片剪辑：

包 {

import flash.display.MovieClip;
import flash.events.KeyboardEvent;
import flash.ui.Keyboard;
import flash.events.Event;

public class Main_Character_Two extends MovieClip
{
    var vx:int;
    var vy:int;

    public function Main_Character_Two()
    {
        init();
    }
    function init():void
    {
        //initialize variables
        vx = 0;
        vy = 0;

        //Add event listeners
        stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
        stage.addEventListener(KeyboardEvent.KEY_UP, onKeyUp);
        addEventListener(Event.ENTER_FRAME, onEnterFrame);
    }
    function onKeyDown(event:KeyboardEvent):void
    {
        if (event.keyCode == Keyboard.LEFT)
        {
            vx = -5;
        }
        else if (event.keyCode == Keyboard.RIGHT)
        {
            vx = 5;
        }
        else if (event.keyCode == Keyboard.UP)
        {
            vy = -5;
        }
        else if (event.keyCode == Keyboard.DOWN)
        {
            vy = 5;
        }
    }
    function onKeyUp(event:KeyboardEvent):void
    {
        if (event.keyCode == Keyboard.LEFT || event.keyCode == Keyboard.RIGHT)
        {
            vx = 0;
        }
        else if (event.keyCode == Keyboard.DOWN || event.keyCode == Keyboard.UP)
        {
            vy = 0;
        }
    }
    function onEnterFrame(event:Event):void
    {
        //Move the player
        player.x += vx;
        player.y += vy;
    }
}

}

这工作正常，但主要问题是，当您按下右键（并按住）然后按下左键时，角色将向左移动，但是当您释放左键时（仍然按住右键）向下）角色就停止了。在这种情况下，我怎样才能让角色开始再次向右移动（如果在释放左键后我仍然按住右键）

谢谢

Answer 1

您可以将“玩家”定位代码放入 Event.ENTER_FRAME 循环中，并使用 KeyboardEvent.KEY_DOWN 和 KeyboardEvent.KEY_UP 设置布尔值和位置循环中的播放器如下：

var leftIsPressed:Boolean = false;
var rightIsPressed:Boolean = false;
var upIsPressed:Boolean = false;
var downIsPressed:Boolean = false;
var speed:Number = 5;
var vx:Number = 0;
var vy:Number = 0;

stage.addEventListener(KeyboardEvent.KEY_DOWN, keyDownHandler);
stage.addEventListener(KeyboardEvent.KEY_UP, keyUpHandler);
stage.addEventListener(Event.ENTER_FRAME, enterFrameHandler);

function keyDownHandler(e:KeyboardEvent):void {
    switch(e.keyCode) {
        case Keyboard.LEFT : leftIsPressed = true; break;
        case Keyboard.RIGHT : rightIsPressed = true; break;
        case Keyboard.UP : upIsPressed = true; break;
        case Keyboard.DOWN : downIsPressed = true; break;
    }
}

function keyUpHandler(e:KeyboardEvent):void {
    switch(e.keyCode) {
        case Keyboard.LEFT : leftIsPressed = false; break;
        case Keyboard.RIGHT : rightIsPressed = false; break;
        case Keyboard.UP : upIsPressed = false; break;
        case Keyboard.DOWN : downIsPressed = false; break;
    }
}

function enterFrameHandler(e:Event):void {
    vx = -int(leftIsPressed)*speed + int(rightIsPressed)*speed;
    vy = -int(upIsPressed)*speed + int(downIsPressed)*speed;
    player.x += vx;
    player.y += vy;
}

[编辑]添加了更详细的示例。

当然，在这种情况下，如果左右键都被按下，这将导致 0 偏移。

Answer 2

您可以监听KeyboardEvent.KEY_UP来确定按键何时被释放，这样您就可以跟踪哪些按键被按住。

Answer 3

仅当按键从“向上”状态变为“向下”状态时，才会触发 KeyboardEvent.KEY_DOWN 事件，因此在您将手指从左键上抬起后，您的角色就会停止，因为没有触发导致角色移动的新 KEY_DOWN 事件。

您也许可以通过添加一个 KeyboardEvent.KEY_UP 事件来完成您的任务，该事件检查事件触发时是否按住了任何其他箭头键，但您可能会需要重构当前代码以避免重复。

Answer 4

要理解这种现象，需要对键盘输入所基于的事件模型有基本的了解。它在 AS3 中的工作方式与在 AS2 中的工作方式不同。

当您按下某个键时，会触发一个事件来调用某个函数 - 但仅在按下该键时触发一次。事件处理程序不检查按键是否被按下。 （尝试将 5 添加到对象的 x/y 值，而不是 onKeyDown 函数中的 vx；您会发现角色仅在按下某个键时移动，而不是在按住该键时移动。）

同样，当您释放某个键时，触发事件来调用函数 - 但仅在主动释放按键时触发一次。当钥匙放在那里时，不会触发任何事件。

在此基础上...您能找到当前问题的根源吗？

function onKeyUp(event:KeyboardEvent):void
{
    if (event.keyCode == Keyboard.LEFT || event.keyCode == Keyboard.RIGHT)
    {
        vx = 0;
    }
    else if (event.keyCode == Keyboard.DOWN || event.keyCode == Keyboard.UP)
    {
        vy = 0;
    }
}

如果你没找到，那就是这个街区。

    if (event.keyCode == Keyboard.LEFT || event.keyCode == Keyboard.RIGHT)
    {
        vx = 0;
    }

该语句告诉您的程序，如果按下左右键，则将速度设置为零。但是，由于 Flash 仅在您第一次按下按键时检查按键，因此按住某个键不会触发 onKeyDown 函数。因此，如果你同时按住左键和右键，然后放开其中一个，你就会将速度设置为零。

Corey 在这里提供了逻辑解决方案，还有一些其他原因导致您想要使用切换布尔值来检查键盘输入（主要原因是您不会得到任何重复延迟）。

我希望这个答案能让你明白一点——一点知识可以带来伟大的事情。祝你好运。