如何从Scheme中的列表中删除非重复元素？

Question

给定一个列表，

(define ll '(a a a b c c c d e e e e))

我想删除所有非重复元素并只留下重复元素的一个副本，即删除后，结果将是

(a c e)

我的算法是：

• 遍历列表，将当前元素与下一个元素进行比较。

  • 如果它们相等，则cons当前元素与下一个递归调用的列表。例如，

    <前><代码>(aaabc)

    从左向右移动，遇到a和a。

    (cons a (remove-nondup (cddr lst)))
    

  • 否则，跳过当前和下一个元素。

    (删除-nondup (cddr lst))
    

我遇到的问题是

(define (remove-nondup lst)
  (if (>= (length lst) 2)
      (if (eq? (car lst) (cadr lst))
          (cons (car lst) (remove-nondup (cdr lst)))
          (remove-nondup (cddr lst)))
      lst))

，如果有超过 3 个连续元素，我将无法跟踪前一个-前一个元素。所以我想知道我应该使用另一个程序来删除所有重复项吗？或者我可以将它们放入一个程序中？

所以我当前的替代解决方案是，

(define (remove-dup lst)
  (if (>= (length lst) 2)
      (if (eq? (car lst) (cadr lst))
          (cons (car lst) (remove-dup (cddr lst)))
          (cons (car lst) (remove-dup (cdr lst))))
      lst))

(define (remove-nondup-helper lst)
  (if (>= (length lst) 2)
      (if (eq? (car lst) (cadr lst))
          (cons (car lst) (remove-nondup-helper (cdr lst)))
          (remove-nondup (cddr lst)))
      lst))

; call the helper function and remove-dup
(define (remove-nondup lst)
  (remove-dup (remove-nondup-helper lst)))

Answer 1

这是我的解决方案：首先，抓住 bagify（任何版本都可以）。然后：

(define (remove-singletons lst)
  (define (singleton? ass)
    (< (cdr ass) 2))
  (map car (remove singleton? (bagify lst))))

remove 来自 SRFI 1。如果您使用 Racket，请先运行 (require srfi/1)。或者，使用这个简单的定义：

(define remove #f)   ; Only needed in Racket's REPL
(define (remove pred lst)
  (cond ((null? lst) lst)
        ((pred (car lst)) (remove pred (cdr lst)))
        (else (cons (car lst) (remove pred (cdr lst))))))

Answer 2

这是一种仅使用标准库函数和尾部调用的方法，尽管它执行线性搜索以查看某个项目是否已被看到或放入结果中：

(define remove-nondup
  (λ (ls)
    (reverse
      (let loop ([ls ls] [found '()] [acc '()])
        (cond
          [(null? ls)
            acc]
          [(memq (car ls) found)
            (loop (cdr ls)
                  found
                  (if (memq (car ls) acc)
                      acc
                      (cons (car ls) acc)))]
          [else
            (loop (cdr ls)
                  (cons (car ls) found)
                  acc)])))))

(remove-nondup '(a a a b c c c d e e e e)) =>
  (a c e)
(remove-nondup '(a a a b c c c d e e e e f a a f)) =>
  (a c e f)

循环是一个“命名的let”：一种将辅助过程粘贴到过程中的便捷方法，而不会出现大量语法混乱。

如果您只想将连续重复项缩小为一个项目，并且仅在它们不连续出现两次时删除项目，那么这里有一种方法可以“记住”两个单元格前的项目，而无需搜索它，并且仅使用尾部调用：

(define remove-nonconsecdup
  (λ (ls)
    (reverse
      (letrec (
          [got1 (λ (ls prev acc)
                  (cond
                    [(null? ls)
                      acc]
                    [(eq? prev (car ls))
                      (got2 (cdr ls) (cons prev acc))]
                    [else
                      (got1 (cdr ls) (car ls) acc)]))]
          [got2 (λ (ls acc)
                  (cond
                    [(null? ls)
                      acc]
                    [(eq? (car acc) (car ls))
                      (got2 (cdr ls) acc)]
                    [else
                      (got1 (cdr ls) (car ls) acc)]))])
        (if (null? ls)
            '()
            (got1 (cdr ls) (car ls) '()))))))

(remove-nonconsecdup '(a a a b c c c d e e e e)) =>
  (a c e)
(remove-nonconsecdup '(a a a b c c c d e e e e f a a f)) =>
  (a c e a)

我不喜欢反转列表，但调用 reverse 很容易。如果由 reverse 完成的额外 cons'ing 是一个问题，您可以进行非尾部调用或将项目粘贴在列表的末尾，但这很难有效地完成（但使用非尾部调用很容易） -标准库宏）。