我如何正确使用 PChars 来改进这种优化？

Question

我的应用程序中有一个被大量调用的函数。它基本上是一个 csv 解析器，它“弹出”第一个值并将输入字符串更改为剩余的字符串。

function StripString(mask: string; var modifiedstring: string): string;
var
  index,len: integer;
  s: string;
begin
    Index := pos(Mask, ModifiedString);
    len := Length(ModifiedString);
    if index <> 0 then
    begin
        if Index <> 1 then
        begin
            s := LeftStr(ModifiedString, index - 1);
            ModifiedString := RightStr(ModifiedString, len-index);
        end else begin
            if Length(ModifiedString)>1 then
              ModifiedString := Copy(ModifiedString,2,len)
            else
              ModifiedString := '';
            s := '';
        end;
    end else begin
        s := ModifiedString;
        ModifiedString := '';
    end;
    result := s
end;

我想尝试使用 PChars 来优化这个例程。所以我想出了这个方法，但不幸的是我在结果输出中得到了奇怪的字符。我猜是因为指针不正确。

//faster method - uses PChars
function StripStringEx(mask: char; var modifiedstring: string): string;
var
  pSt,pCur,pEnd : Pchar;
begin
    pEnd := @modifiedString[Length(modifiedString)];
    pSt := @modifiedString[1];
    pCur := pSt;
    while pCur <= pEnd do
    begin
         if pCur^ = mask then break;
         inc(pCur);
    end;
    SetString(Result,pSt,pCur-pSt);
    SetString(ModifiedString,pCur+1,pEnd-pCur);
end;

有人“指出”:)我的方向正确吗？

Answer 1

即使您让指针版本正常工作，我也不明白为什么它会更快。

调用 Pos 比循环更快，因为 Pos 经过了合理优化。两个版本的分配模式是相同的，两个堆分配和一个堆释放。我会坚持使用有效的版本。

您可以摆脱局部变量 s 并直接分配给 Result 以跳过一些引用计数。

Answer 2

我认为由于 ModifiedString 上的 SetString，您会得到奇怪的结果。
SetString首先设置字符串的长度，然后将缓冲区中的内容复制到新创建的字符串中。但在您的情况下，缓冲区是目的地，并且缓冲区的长度刚刚进行了调整。

只需遵循 David 的建议，不要使用 PChars。

如果你愿意，你可以让它变得更短：

function StripString(const Mask: string; var ModifiedString: string): string;
var
  Index: Integer;
begin
  Index := Pos(Mask, ModifiedString);
  if Index <> 0 then
  begin
    Result := LeftStr(ModifiedString, Index - 1);
    Delete(ModifiedString, Index);
  end
  else
  begin
    Result := ModifiedString;
    ModifiedString := '';  
  end;
end;