Winforms ProgressBar 需要时间来渲染

Question

我在使用 PorgressBar 时注意到了这一点。如果我将值设置为 x，则显示的值不会立即更新，需要花费少量时间来绘制它，因为条形图从当前值动画到新值。

在以下代码中很容易看出这一点：

Private Async Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Label1.Text = ""
    Dim progressHandler = New Progress(Of Integer)(Sub(value) ProgressBar1.Value = value)
    Dim progress = CType(progressHandler, IProgress(Of Integer))
    Await Task.Run(Sub()
                       For i = 1 To 100
                           progress.Report(i)
                           Thread.Sleep(10)
                       Next
                   End Sub)
    Label1.Text = "Value Now at 100%"
    Await Task.Delay(650) 'it takes this long for the bar to be rendered
    Label1.Text += " - Finished drawing"
End Sub

您会注意到运行此代码时，Value Now at 100% 出现在条形实际达到 100% 之前很长时间。

有什么方法可以检测栏何时完成渲染？

Answer 1

我刚刚尝试了一下，完全明白你的意思。不幸的是，在花了一些时间查看进度栏上的 DrawToBitmap 函数是否有帮助之后，我发现了不足。

下一步是创建一个自定义进度条，用于公开渲染完成时的事件。

有关如何创建自定义进度条的合理示例，请尝试此处：
http://msdn。 microsoft.com/en-us/library/system.windows.forms.progressbarrenderer(v=VS.100).aspx

快速扫描代码看起来您​​应该能够插入“OnRendered”事件或类似的调用“DrawHorizo​​ntalChunks”（或“DrawVerticalChunks”）。

可能不是您想要的答案，但至少为您提供了追求它时所需的控制权？

注意：我自己还没有尝试过，所以如果您花了一整天的时间发现得到了相同的结果，请不要向我发送仇恨邮件...

祝您好运！

编辑：

对我的回复不满意，似乎有点懒......下面使用我所描述的自定义进度栏。它有几个基本属性，用于设置最大/最小值、执行步骤以及直接设置值。我通过将睡眠间隔更改为不同的量来对此进行了测试，在所有情况下，表单在关闭之前都将进度条显示为已满。请注意新的 OnRendered 事件。

Imports System
Imports System.Drawing
Imports System.Windows.Forms
Imports System.Windows.Forms.VisualStyles

Public Class Form1
    Inherits Form
    Private WithEvents bar1 As ProgressBarWithRender = New ProgressBarWithRender()


    Public Sub New()
        InitializeComponent()
        Me.Size = New Size(500, 500)
        bar1.Location = New Point(100, 100)
        bar1.Width = 300
        bar1.Height = 50
        bar1.Maximum = 30
        bar1.Step = 1
        Controls.Add(bar1)
    End Sub

    Public Sub OnRendered(ByVal valueRendered As Integer) Handles bar1.OnRendered
        If valueRendered = bar1.Maximum Then
            ' We know everything has been drawn
            Me.Close()
        End If
    End Sub


    <STAThread()> _
    Public Shared Sub Main()
        ' The call to EnableVisualStyles below does not affect
        ' whether ProgressBarRenderer.IsSupported is true; as 
        ' long as visual styles are enabled by the operating system, 
        ' IsSupported is true.
        Application.EnableVisualStyles()
        Application.Run(New Form1())

    End Sub 'Main

    Private Sub Form1_Click(sender As Object, e As System.EventArgs) Handles Me.Click
        For i = 1 To 30
            bar1.PerformStep()
            Threading.Thread.Sleep(10)
        Next
    End Sub

End Class 'Form1

Public Class ProgressBarWithRender
    Inherits Control

    Public Delegate Sub RenderedEventArgs(ByVal valueRendered As Integer)
    Public Event OnRendered As RenderedEventArgs

    Private ProgressBarRectangles() As Rectangle

    Public Property [Step] As Integer

    Public Property InnerPadding As Integer = 3

    Private _Maximum As Integer
    Public Property Maximum As Integer
        Get
            Return _Maximum
        End Get
        Set(value As Integer)
            _Maximum = value
            CalculateTickSizes()
        End Set
    End Property

    Private _Minimum As Integer
    Public Property Minimum As Integer
        Get
            Return _Minimum
        End Get
        Set(value As Integer)
            _Minimum = value
            CalculateTickSizes()
        End Set
    End Property

    Private _Value As Integer
    Public Property Value As Integer
        Get
            Return _Value
        End Get
        Set(newValue As Integer)
            If newValue < Me.Value AndAlso newValue > 0 Then
                Throw New NotImplementedException("ProgressBarWithRender does not support decrementing the value")
            End If
            Me._Value = newValue
        End Set
    End Property

    Public Sub PerformStep()
        ' Ensure step doesn't exceed boundaries
        If Value + [Step] > Maximum Then
            Value = Maximum
        ElseIf Value + [Step] < Minimum Then
            Value = Minimum
        Else
            Value += [Step]
        End If

        ' We are limited by the Renderers Chunk Width, so we possibly can't draw every step if there is a high maximum
        Dim g As Graphics = Me.CreateGraphics
        ProgressBarRenderer.DrawHorizontalChunks(g, ProgressBarRectangles(Value - Minimum))
        RaiseEvent OnRendered(Value)

    End Sub

    Protected Overrides Sub OnPaint(e As System.Windows.Forms.PaintEventArgs)
        MyBase.OnPaint(e)
        If Not ProgressBarRenderer.IsSupported Then
            Throw New NotImplementedException("Progress Bar Rendering is not supported")
        End If
        ProgressBarRenderer.DrawHorizontalBar(e.Graphics, ClientRectangle)
    End Sub

    Private Sub CalculateTickSizes()
        ' Changing the Maximum will change the tick rectangle size
        ProgressBarRectangles = New Rectangle(Maximum) {}
        Dim chunkThickness As Integer = ProgressBarRenderer.ChunkThickness + (ProgressBarRenderer.ChunkSpaceThickness * 2)
        Dim tickThickness As Double = ((ClientRectangle.Width - (InnerPadding * 2)) - (ProgressBarRenderer.ChunkSpaceThickness * 2)) / (Maximum - Minimum)
        If tickThickness < chunkThickness Then
            Debug.Print("This will go wrong because we can't draw small enough chunks...")
        End If
        For i As Integer = 0 To Maximum
            Dim filledRectangle As Integer = CInt(tickThickness * i)
            ProgressBarRectangles(i) = New Rectangle(ClientRectangle.X + InnerPadding,
                                                     ClientRectangle.Y + InnerPadding,
                                                     filledRectangle,
                                                     ClientRectangle.Height - (InnerPadding * 2))
        Next
    End Sub

End Class

Answer 2

问题是您处于单线程程序中，并且线程需要时间来更新显示。

添加行

Application.DoEvents()

Before close the UpdateProgress sub.

并且您可以摆脱最后两次刷新。

Answer 3

这是我根据 Matt Wilko 的建议编写的代码：

Imports System.Net
Imports System.IO
Imports System.Text.RegularExpressions
Public Class Form1
Dim client As New WebClient
Public Sub New()

    ' This call is required by the Windows Form Designer.
    InitializeComponent()

    ' Add any initialization after the InitializeComponent() call.
    AddHandler client.DownloadStringCompleted, AddressOf client_DownloadStringCompleted
    AddHandler client.DownloadProgressChanged, AddressOf client_DownloadProgressChanged

End Sub
Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
    ProgressBar1.Value = 0
    ProgressBar1.Visible = True
    client.DownloadStringAsync(New Uri("http://somewebsite.com"), Nothing)
End Sub
Private Sub client_DownloadProgressChanged(ByVal sender As Object, ByVal e As System.Net.DownloadProgressChangedEventArgs)
    If ProgressBar1.Value < e.ProgressPercentage Then
        ProgressBar1.Value = e.ProgressPercentage
    End If
End Sub
Private Sub client_DownloadStringCompleted(ByVal sender As Object, ByVal e As System.Net.DownloadStringCompletedEventArgs)
    ProgressBar1.Value = 100
    Timer1.Enabled = True
End Sub

Private Sub Timer1_Tick(sender As System.Object, e As System.EventArgs) Handles Timer1.Tick
    Static waitToCloseProgressBar As Integer
    If ProgressBar1.Value = 100 Then
        If waitToCloseProgressBar > 6 Then
            Timer1.Enabled = False
            waitToCloseProgressBar = 0
            ProgressBar1.Visible = False
        Else
            waitToCloseProgressBar = waitToCloseProgressBar + 1
        End If
    End If
End Sub
End Class

Answer 4

我的进度条滞后效果很好，使用此函数设置值：

Private Sub SetProgressNoAnimation(ByVal value As Integer)
    ' To get around the progressive animation, we need to move the 
    ' progress bar backwards.
    If (value = progressBarCarga.Maximum) Then
        ' Special case as value can't be set greater than Maximum.
        progressBarCarga.Maximum = (value + 1)
        ' Temporarily Increase Maximum
        progressBarCarga.Value = (value + 1)
        ' Move past
        progressBarCarga.Maximum = value
        ' Reset maximum
    Else
        progressBarCarga.Value = (value + 1)
        ' Move past
    End If
    progressBarCarga.Value = value
    ' Move to correct value
End Sub

更多信息：

https://derekwill.com/2014/06/24/combating-the-lag-of-the-winforms-progressbar/

Answer 5

我有类似的问题。
我更愿意起诉标准进度条，以便在应用程序中拥有典型的设计。

确实，它需要时间来更新，并且由于 DoEvents 本身无法工作，因此我建议使用后台工作者来进行加载。当完成后仍然不起作用，那么要么添加一个doevents，要么一个小的延迟。但我想您的解决方案延迟 100 毫秒是最好的，因为它需要的更改最少并且仍然有效。只添加 10 毫秒的延迟怎么样？
另一种方法是：尝试progressBar.Invalidate（强制重新绘制），添加代码来绘制，检查绘制是否被执行，然后关闭表单。我猜 DoEvents 在绘画中不起作用，因为绘画需要完成。所以你可以启用一个间隔为 100 毫秒的计时器，它会关闭窗口。

关于 1/24 秒以内的一切对于人类来说是看不见的都是 bu..sh..
眼睛里有液体，甚至可以看到更短的东西。如果我们能够立即对某件事做出反应，那是有区别的，但由于信息被“燃烧”在眼睛表面，直到被神经“读取”，所以它不会丢失。甚至60Hz也存在问题，我相信大多数人都知道恼人的60Hz CRT问题。 LCD 闪烁不会那么强烈，但如果您需要高帧率，而 60 还不够，那么您仍然可以“看到”60 的问题，并且 100 或更高看起来更好。

Answer 6

我发现使用 PerformStep() 而不是设置值没有这种渲染延迟 - 但仍然必须调用 Application.DoEvents() 。

Answer 7

我通过插入得到了可接受的结果
frmMain.Refresh
为标准 ProgressBar 分配新值后。