XSL 模板优先级

Question

我有 2 个模板

<template match="vehicle_details[preceding-sibling::vehicle_type = '4x4']/*">
    ...
</xsl:template>
<xsl:template match="vehicle_details[descendant::color = 'red']/*" >
    ...
</xsl:template>

我的问题是：哪个模板将优先进行转换。有人可以给我有关 XSL 模板优先级的概述/资源吗？

提前致谢！

Answer 1

XSLT 规范第 5.5 节描述了完整的解决过程。

一般来说，以下规则按顺序适用（例如，由于导入优先级较低而从考虑中排除的模板将被永久删除，无论其优先级如何）：

1. 导入的模板的优先级低于主样式表中的模板
2. 其 < 中具有较高值的​​模板code>priority 属性具有更高的优先级
3. 没有 priority 属性的模板将被分配默认优先级。具有更具体模式的模板优先。
4. 如果前三个步骤考虑了多个模板，则这是一个错误，但 XSLT 处理器可以通过默认为文件中的最后一个模板来恢复。

在您的具体情况下，两个模板具有相同的优先级，因此上面的#4 适用。演示：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match=
             "vehicle_details[preceding-sibling::vehicle_type = '4x4']/*">
        template1
    </xsl:template>
    <xsl:template match="vehicle_details[descendant::color = 'red']/*">
        template2
    </xsl:template>
</xsl:stylesheet>

应用于此输入（两个模板都匹配）：

<root>
    <vehicle_type>4x4</vehicle_type>
    <vehicle_details>
        <color>red</color>
    </vehicle_details>
</root>

输出：

template2

但如果我们交换模板的顺序：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="vehicle_details[descendant::color = 'red']/*">
        template2
    </xsl:template>
    <xsl:template match=
             "vehicle_details[preceding-sibling::vehicle_type = '4x4']/*">
        template1
    </xsl:template>
</xsl:stylesheet>

那么输出为：

template1