在我的 .vimrc 中，如何检查配色方案是否存在？

Question

在 .vimrc 中，是否可以仅加载存在的配色方案？

Answer 1

这是 nvim 的 LUA 解决方案：

local colorschemes = {
    'solarized',
    'desert',
}

for _, colorscheme in ipairs(colorschemes) do
    if pcall(vim.cmd.colorscheme, colorscheme) then
        break
    end
end

Answer 2

在 try-catch 中使用 :colorscheme 作为 Randy 已完成 如果您只想加载它（如果存在）并执行其他操作，则可能就足够了。如果您对 else 部分不感兴趣，可以使用简单的 :silent! colorcheme 就足够了。

否则， globpath() 是要走的路。然后，如果您确实愿意，可以检查使用 filereadable() 返回的每个路径。

" {rtp}/autoload/has.vim
function! has#colorscheme(name) abort
    let pat = 'colors/'.a:name.'.vim'
    return !empty(globpath(&rtp, pat))
endfunction

" .vimrc
if has#colorscheme('desert')
     ...

编辑： fileread($HOME.'/.vim/colors/'.name.'.vim') 可能看起来很简单，而且绝对有吸引力，但如果我们正在寻找的颜色方案，这还不够因为是在别处。通常，如果它已通过插件管理器安装在另一个目录中。在这种情况下，唯一可靠的方法是检查 vim 'runtimepath '（又名'rtp'）。因此globpath()。请注意，:colorscheme name 命令在 {rtp}/colors/{name}.vim 中搜索。

Answer 3

@eckes 答案的替代方法是尝试加载颜色方案并处理错误（如果不存在）：

try
    colorscheme mayormaynotexist
catch /^Vim\%((\a\+)\)\=:E185/
    " deal with it
endtry

Answer 4

您可以使用 fileread 函数检查颜色方案（例如 schemename）是否存在：在 ~/vimfiles/colors 下检查一次（Win32，对于 Unix，使用 ~/.vim/colors/），然后在 $VIMRUNTIME/colors/ 下：

if filereadable("/path/to/schemename.vim")
  colo schemename
endif

Answer 5

我的方法类似，

if filereadable( expand("$HOME/.vim/colors/railscast.vim") )
    colorscheme railscast
endif

这比硬编码整个路径更强大一点。

Answer 6

通常我会使用最喜欢的colorscheme，如果我最喜欢的颜色方案不可用，我会进行后备。嵌套的 try 将使这项工作有效：

try 
  colorscheme solarized
  catch
  try 
    colorscheme peachpuff
    catch
  endtry
endtry

如果两个 colorscheme 都不可用，则加载默认的（无论您的系统上发生什么情况）。如果一种或两种颜色方案不可用，则不会显示错误。将您喜欢的颜色方案放在第一位。

此外，不带参数的 catch 会捕获任何错误。如果您正在处理给出不同错误消息的不同区域设置，这会很方便。

Answer 7

这是我在 .vimrc 文件中的内容。

if filereadable( expand("$HOME/.vim/colors/sublimemonokai.vim") )
    colorscheme sublimemonokai "https://github.com/ErichDonGubler/vim-sublime-monokai

    " vim-sublime-monokai only support 256 colours in terminal. If you are using a terminal which support truecolor like iterm2, enable the GUI color
    set termguicolors

    " Otherwise, use below setting to activate the 256 color in terminal
    set t_Co=256
else
    echom "The sublimemonokai.vim were not found to be used as colorscheme. elflord will be set for the timebeing..."
    colorscheme elflord
endif

基本上它会检查机器上是否存在我喜欢的配色方案。如果是，它将选择它并应用它所需的所有设置。否则它会选择 vim 附带的合适的配色方案。

通过查看其他答案，我的答案与 @user427390 答案共享一部分，并且它有一个额外的 else 条件。

以下链接对我编写自己的 .vimrc 和 vim 相关文件的脚本有很大帮助：
http://learnvimscriptthehardway.stevelosh.com/