搜索与在 Vim 中使用快速修复列表替换

Question

到目前为止，我总是使用 EasyGrep 来替换多个文件中的文本。不幸的是，当项目变大时，它会变得相当慢。看起来快得惊人的一件事是 fugitive.vim 的 Ggrep，它只搜索我的版本控制文件。所有结果也存储在快速修复列表中。

如何使用 Ggrep 的结果对所有找到的文件进行简单替换？是否可以在快速修复列表中的所有文件上使用 %s/foo/bar/cg 或者是否有更好的方法？

Answer 1

更新：
Vim 现在有 cdo，请参阅 Sid 的回答。

原始答案：

Vim 有 bufdo , windo, tabdo 和 argdo，它允许您在所有打开的缓冲区、窗口或文件中执行相同的命令参数列表。我们真正需要的是像 quickfixdo 这样的东西，它将对快速修复列表中的每个文件调用一个命令。遗憾的是，Vim 缺乏该功能，但是 这是 Al 提供的解决方案，它提供了一个家庭滚动的解决方案。使用它，可以运行：

:QFDo %s/foo/bar/gc

这将对快速修复列表中的所有文件运行 foo/bar 替换。

bufdo、windo、tabdo 和 argdo 命令具有一些常见的行为。例如，如果当前文件不能被放弃，那么所有这些命令都将失败。我不确定上面引用的 QFDo 命令是否遵循相同的约定。

我已经改编了Al的解决方案创建一个名为 Qargs 的命令。运行此命令将使用快速修复列表中列出的所有文件填充参数列表：

command! -nargs=0 -bar Qargs execute 'args ' . QuickfixFilenames()
function! QuickfixFilenames()
  " Building a hash ensures we get each buffer only once
  let buffer_numbers = {}
  for quickfix_item in getqflist()
    let buffer_numbers[quickfix_item['bufnr']] = bufname(quickfix_item['bufnr'])
  endfor
  return join(values(buffer_numbers))
endfunction

使用此命令，您可以按照以下步骤进行项目范围的搜索和替换：

:Ggrep findme
:Qargs
:argdo %s/findme/replacement/gc
:argdo update

编辑：（提示Peter Rincker）

或者您可以将最后 3 个命令连接到一行中：

:Ggrep findme
:Qargs | argdo %s/findme/replacement/gc | update

Answer 2

现已添加 cdo 命令！ grep 后，您可以使用 cdo 对快速修复列表中的每个术语执行给定命令：

cdo %s/

//cg

（看看这个 git commit 和这个 vim 开发者 Google 群组讨论，了解有关 cdo< 的更多信息/code> 以及添加它背后的动机。）

Answer 3

nelstrom 的回答相当全面，体现了他对 vimdom 的辉煌贡献。它也有点超出了这里严格需要的范围；可以省略快速修复步骤，以便使用 shell 命令的结果填充 args：

:args `git grep -l findme`
:argdo %s/findme/replacement/gc
:argdo update

应该就是您所需要的。

编辑：正如 Domon 所说，如果尚未设置，则必须首先执行 :set hide ！

Answer 4

使用 quickfix-reflector.vim，您可以在快速修复窗口中编辑搜索结果。然后，write 命令会将更改保存到文件中。

:copen
:%s/foo/bar/cg
:write

Answer 5

外部 grep

（使用 grepprg，grepformat 就像 makeprg/errorformat 中的那样；如果 grepprg=='internal' 这与内部 grep 相同）

:grep fopen *.c
:copen
:cnext

内部 grep

:vimgrep /\<myVimregexp\>/ **/*.c
:copen
:cnext

等。

位置列表内部 grep

:lvimgrep /\<myVimregexp\>/ **/*.c
:lopen
:lnext

等。

奖励：执行外部 grep加载的缓冲区：

:silent bufdo grepadd fstream %
:copen
:cnext

等。

所有参数均外部：

:silent argdo grepadd fstream %
:copen
:cnext

Answer 6

有一个补丁可以将 cdo (Quickfix do) 命令添加到 vim，但尚未提取（截至 2015-03-25）：

https://groups.google.com/forum/#!topic/vim_dev/dfyt-G6SMec

你可能需要自己给 vim 打补丁才能得到这个修补：

brew install hg # install mercurial, e.g. with homebrew
hg clone https://vim.googlecode.com/hg/ vim
cd vim
# copy/download patch to . folder
patch -b -p1 < cdo.diff
./configure
make && make install