使用 ListLinePlot 的赛车圈速图

Question

我正在尝试获取赛车运动单圈位置表并绘制类似于此的单圈图表 http://www.fia.com/en-GB/sport/championships/f1/2010/bahrain/Pages/lap_chart.aspx。

每行对应一圈，第一圈位于第一行。每行的车号按照通过起跑线/终点线的顺序列出 表格可能如下所示（4 辆车比赛，6 圈：

1 3 2 4
1 3 2 4
1 3 4 2
3 1 4 2
3 1 4 2
3 4 1 2

在上面的例子中，第一圈后的顺序是1、3、2、4，到6圈比赛结束时，3号车获胜，4号车第二，依此类推。

很容易错误地绘制此图，我这样做了：

ListLinePlot[Table[Position[data,x],{x,4}]]

这确实会产生一个圈数图，但它的第一个位置是底部和顶部的第四个位置，我真正需要的是 y 轴运行 4-3-2-1，所以第一个位置在顶部。

如何反转 y 轴，使其从 1（顶部）运行到 n（底部）？

Answer 1

只需使用象限 4 即可解决屏幕位置问题。

这也适用于DNF！ （未完成的驱动程序）。

第一个位置绘制在 y = -1 处，第二个位置绘制在 y = -2 处，依此类推。
请注意 {{lap_, y_} :>; 中的 y 是如何被 -y 替换的。下面的 {lap - 1, -y}}。

lap 减少了 1，因为我包含了起始位置的数据 (lap=zero)。

---

进行较小的重写，以处理不同数量的驾驶员和圈数，并重新格式化代码以提高易读性。 - Mr.Wizard

---

data = 
  {{1, 3, 2, 4},
   {1, 3, 2, 4},
   {1, 3, 4, 2},
   {3, 1, 4, 2},
   {3, 1, 4, 2},
   {3, 4, 1, 2}};

{p, n} = {Max@data, Length@data};

ticks = {#, #} &@Array[{-#, #} &, p];
ticks[[All, 1, 2]] = {"Pole", "Winner"};

PrependTo[data, Range@p];  (* add starting position *)

ListLinePlot[
 Replace[
   Array[data~Position~# &, p],
   {lap_, y_} :> {lap - 1, -y},
   {2}
 ],
 Frame -> True,
 FrameLabel ->
  {"Laps Completed",
   "Starting Positions",
   "Laps Completed",
   "Final Positions"},
 GridLines -> {Range[0, n + 1], None},
 FrameTicks -> {ticks, {All, All}},
 PlotRange -> {Automatic, {-.7, -.3 - p}},
 PlotStyle -> Thickness[.01]
]

这是一辆车（开始于杆位）在完成最后两圈之前就退出了。请注意，3 号车自动前进一位。

Answer 2

反转位置的顺序，然后重新标记刻度：

ListLinePlot[
 Table[Position[data, x] /. {xx_, yy_} :> {xx, 5 - yy}, {x, 4}],
 Ticks -> {Automatic, {{1, 4}, {2, 3}, {3, 2}, {4, 1}}}, 
 PlotStyle -> Thickness[.01]]

Answer 3

好的，有人提出了 BarChart 和 ScalingFunctions，那么我们开始吧......

BarChart[Ordering /@ data, ChartLayout -> "Overlapped", 
 Joined -> Automatic, BarSpacing -> 0, ChartElementFunction -> ({} &),
  ChartStyle -> 1, ScalingFunctions -> "Reverse", Axes -> False, 
 Frame -> {{True, False}, {True, False}}, PlotRange -> {All, All}, 
 BaseStyle -> Thickness[0.01]]

（但是 ListPlot 解决方案可能更简单。可惜它还不支持 ScalingFunctions。）

Answer 4

我将放弃这个“聪明”的实现，因为我喜欢它，但大卫的答案更加稳健。

laps = 
  {{1, 3, 2, 4},
   {1, 3, 2, 4},
   {1, 3, 4, 2},
   {3, 1, 4, 2},
   {3, 1, 4, 2},
   {3, 4, 1, 2}};

ListLinePlot[
  -Thread[Ordering /@ laps],
  AxesOrigin -> {1, 0}, PlotStyle -> Thick,
  Ticks -> {All, Array[{-#, #} &, 4]}
]

Answer 5

现在完全显示 y 轴怎么样：

data = {{1, 3, 2, 4},
   {1, 3, 2, 4},
   {1, 3, 4, 2},
   {3, 1, 4, 2},
   {3, 1, 4, 2},
   {3, 4, 1, 2}};

ListLinePlot[Table[Position[5 - data, x], {x, 4}], 
 Axes -> {True, False}]

Answer 6

ScalingFunctions 现在似乎可以与 ListLinePlot 一起使用，

data = {{1, 3, 2, 4}, {1, 3, 2, 4}, {1, 3, 4, 2}, {3, 1, 4, 2}, {3, 1,
     4, 2}, {3, 4, 1, 2}};
ListLinePlot[Table[Position[data, x], {x, 4}], 
 ScalingFunctions -> {Identity, "Reverse"}, AxesOrigin -> {1, -5}]

我不知道为什么 AxesOrigin y 坐标需要为负数。