如何将 xsl:import 与路径名中的变量一起使用？

Question

本质上我想在 XSL 中执行此操作：

<xsl:include href="_domains/{$domain}/templates/header.xsl" />

但我似乎无法在包含中使用变量（$domain）。关于解决方法有什么建议吗？

Answer 1

xsl:import 和 xsl:include 在编译时解析，不支持运行时扩展。

但如果您使用的是 XSLT 2.0，则可以将 条件包含 与 < code>use-when，如果您有一个可以在静态上下文中计算的表达式。

Answer 2

通过添加静态参数，现在可以有条件地包含在 XSLT 3.0 中。静态参数可以在 xsl:include 的 use-when 属性中使用。

现在我们可以使用 false() 的默认值声明参数，然后覆盖运行时所需的参数...

<xsl:param name="someparam" as="xs:boolean" select="false()" 
  static="yes" required="no"/>  
<xsl:include href="include_me.xsl" use-when="$someparam"/>

这是一个使用 Saxon-HE v9.7（也使用 Saxon-PE 9.5 进行了测试）。

XML 输入 (test.xml)

<doc>
    <foo/>
</doc>

主 XSLT 3.0 (test_main.xsl)

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
  xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>
  
  <xsl:param name="inc1" as="xs:boolean" select="false()" 
    static="yes" required="no"/>
  <xsl:param name="inc2" as="xs:boolean" select="false()" 
    static="yes" required="no"/>
  
  <xsl:include href="test_inc1.xsl" use-when="$inc1"/>
  <xsl:include href="test_inc2.xsl" use-when="$inc2"/>
  
  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

第一个可能包含的 XSLT 3.0 (test_inc1.xsl)

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="foo">
    <xsl:copy>INCLUDE FILE 1!!!</xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

第二个可能包括 XSLT 3.0 (test_inc2.xsl)

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="foo">
    <xsl:copy>INCLUDE FILE 2!!!</xsl:copy>
  </xsl:template>
  
</xsl:stylesheet>

命令行（将 inc2 设置为 true）

java -cp "saxon9he.jar" net.sf.saxon.Transform -s:"test.xml" -xsl:"test_main.xsl" inc2="true"

输出

<doc>
   <foo>INCLUDE FILE 2!!!</foo>
</doc>

---

这是另一个示例，使用上述文件（main.xsl 除外），这更像是原始问题，其中路径的一部分是变量。请注意 _href，它是 shadow 属性。

主要 XSLT 3.0

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="inc_number" as="xs:string" select="'1'" static="yes" required="no"/>

    <xsl:include _href="test_inc{$inc_number}.xsl"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>
    
</xsl:stylesheet>

Answer 3

正如 @lavinio 所解释的，在 XSLT 2.0 中 < code>use-when 属性可用于允许一定程度的“编译时”包含 xslt 指令，但这仅限于可以根据静态上下文中的值和这些动态上下文值确定：当前日期和时间以及隐式时区。

另一种方法是在运行时和启动转换之前加载 XSLT 样式表（作为 XML 文档），以动态设置任何所需 href 属性:include> 和/或 指令。

XPath Visualizer 使用此技术来动态更改 XSLT 样式表，然后评估用户指定的 XPath 表达式，并使用所有选定的可见节点（突出显示）格式化 XML 文档。

Answer 4

另一种解决方案是加载 XML 文件并通过一组规则对其进行转换（该文件甚至可以是简单的 XSLT 变体）。

<xsl:param name="domain">_default</xsl:param>

<xsl:variable name="header-template"
   select="document( concat('_domains/', $domain, '/templates/header.xml' ) )" />

<xsl:template name="header">
  <xsl:apply-templates mode="transform" select="$header-template"/>
</xsl:template>