如何在 pro 文件中定义配置？

Question

如何在 pro 文件中定义配置？

默认情况下，我们有两个配置，调试和发布。我想添加 2 个其他配置，但不在 pro.user 中！在专业文件中。

Answer 1

你的问题有点不清楚。听起来也许您当前正在从命令行使用“调试”和“发布”进行构建，并且您想要添加与此类似的自己的构建变体。

如果是这样的话......其机制是addExclusiveBuilds。这是一个例子。如果您不习惯阅读 qmake 代码，我不建议您乱搞它。

TEMPLATE = app
SOURCES = main.cpp

# Adds two build variants.
# One of them builds the app with optimal compiler flags,
# the other one builds the app with support for collecting coverage data.
# For the first one, CONFIG will contain `optimized' and a Makefile.Optimized will be     generated.
# For the second, CONFIG will contain `coverage' and a Makefile.Coverage will be generated.
# There will also be a top-level Makefile which invokes both the sub-makefiles.
addExclusiveBuilds(optimized, Optimized, coverage, Coverage)

CONFIG(optimized, coverage|optimized) {
    message(I am in the optimized build variant)
    QMAKE_CXXFLAGS += -O3

    TARGET = myapp-optimized
}
else:CONFIG(coverage, coverage|optimized) {
    message(I am in the coverage build variant)
    QMAKE_CXXFLAGS += --coverage
    QMAKE_LFLAGS += --coverage

    TARGET = myapp-coverage
}
else {
    message(I am in the glue project which contains the build variants)

    # This will cause a `make' to build both optimized and coverage
    # variants by default.
    CONFIG += build_all
}

Answer 2

如果我明白你在说什么，你可以将你想要的内容添加到 CONFIG 变量中：

CONFIG += user_setting
...
user_setting: message( "compiling with user_setting" )

请参阅 qmake 手册，其中讨论了 CONFIG 变量，特别是在本节末尾附近。