这个Scheme列表迭代器如何使用call-with-current-continuation？

Question

我正在尝试阅读此代码：

(define list-iter
  (lambda (a-list)
    (define iter
      (lambda ()
        (call-with-current-continuation control-state)))
    (define control-state
      (lambda (return)
        (for-each
          (lambda (element)
            (set! return (call-with-current-continuation
                           (lambda (resume-here)
                             (set! control-state resume-here)
                             (return element)))))
          a-list)
        (return 'list-ended)))
    iter))

任何人都可以解释 call-with-current-continuation 在此示例中如何工作吗？

谢谢

Answer 1

call-with-concurrent-continuation（简称为call/cc）的本质是在程序执行期间获取检查点或延续的能力。然后，您可以通过像函数一样应用它们来返回到这些检查点。

下面是一个不使用延续的简单示例：

> (call/cc (lambda (k) (+ 2 3)))
5

如果不使用延续，则很难分辨出区别。以下是我们实际使用它的一些地方：

> (call/cc (lambda (k) (+ 2 (k 3))))
3
> (+ 4 (call/cc (lambda (k) (+ 2 3))))
9
> (+ 4 (call/cc (lambda (k) (+ 2 (k 3)))))
7

当调用延续时，控制流跳回由 call/cc 获取延续的位置。将 call/cc 表达式视为一个洞，由传递给 k 的任何内容填充。

list-iter 是 call/cc 的更复杂的使用，并且可能是一个很难开始使用它的地方。首先，这是一个示例用法：

> (define i (list-iter '(a b c)))
> (i)
a
> (i)
b
> (i)
c
> (i)
list-ended
> (i)
list-ended

这是所发生情况的草图：

1. list-iter 返回一个没有参数i 的过程。
2. 当i被调用时，我们立即获取一个延续并将其传递给control-state。当调用绑定到 return 的延续时，我们将立即返回到调用 i 的人。
3. 对于列表中的每个元素，我们获取一个新的延续，并用该新的延续覆盖 control-state 的定义，这意味着我们将在下次步骤 2 出现时从那里继续。
4. 在设置下一次的control-state之后，我们将列表的当前元素传递回return延续，产生列表的一个元素。
5. 当再次调用 i 时，重复步骤 2，直到 for-each 完成整个列表的工作。
6. 使用 'list-ending 调用 return 延续。由于 control-state 未更新，因此每次调用 i 时，它都会返回 'list-ending。

正如我所说，这是 call/cc 的相当复杂的使用，但我希望这足以完成这个示例。对于延续的更温和的介绍，我建议选择经验丰富的策划者 。

Answer 2

基本上，它采用函数 f 作为参数，并将 f 应用于程序的当前上下文/状态。

来自维基百科：
（定义（f返回）
（返回2）
3)

(display (f (lambda (x) x))) ;显示 3

(display (call-with-current-continuation f)) ;显示 2

因此，基本上，当在没有 current-continuation (cc) 的情况下调用 f 时，该函数将应用于 2，然后返回 3。当使用 current-continuation 时，该参数将应用于 2，这会强制程序跳转到当前延续被调用的位置，并因此返回 2。它可用于生成返回，或暂停执行流程。

如果您了解 C，请这样想：在 C 中，您可以获取指向函数的指针。你还有一个回报机制。假设返回值采用与函数采用相同类型的参数。假设您可以获取其地址并将该地址存储在变量中或将其作为参数传递，并允许函数为您返回。它可以用来模仿 throw/catch，或者作为协程的机制。

Answer 3

这本质上是：

(define (consume)
  (write (call/cc control)))

(define (control ret)
   (set! ret (call/cc (lambda (resume)
                        (set! control resume)
                        (ret 1))))
   (set! ret (call/cc (lambda (resume)
                        (set! control resume)
                        (ret 2))))
   (set! ret (call/cc (lambda (resume)
                        (set! control resume)
                        (ret 3)))))

(consume)
(consume)
(consume)

希望它更容易理解。